Bazen iç içe bir set tanımı kullanarak bir alan değerleri seti tanımlamanız gerekir. Örneğin, belirli bir ürünü satın almış olan tüm müşterileri, ürünü seçmeden seçmek isteyebilirsiniz.
Bu durumlarda, P() ve E() öğe seti işlevlerini kullanın. Bunlar sırasıyla bir alanda olabilecek değerleri ve alanın dışında tutulan değerleri döndürür. Köşeli parantezler içinde, söz konusu alanı ve kapsamı tanımlayan bir set ifadesini belirtebilirsiniz. Örneğin:
P({1<Year = {2021}>} Customer)
Bu, 2021'de işlem yapmış olan müşterilerin setini döndürür. Daha sonra bunu bir set değiştiricide kullanabilirsiniz. Örneğin:
Sum({<Customer = P({1<Year = {2021}>} Customer)>} Amount)
Bu set ifadesi bu müşterileri seçer, ancak seçimi 2021 ile sınırlamaz.
Bu fonksiyonlar diğer ifadelerde kullanılamaz.
Ek olarak, öğe seti fonksiyonlarının içinde yalnızca doğal setler kullanılabilir. Doğal kümeden kasıt, basit bir seçimle tanımlanabilen bir kayıt kümesidir.
Örneğin, {1-$} ile verilen set her zaman bir seçim yoluyla tanımlanamaz ve bu nedenle doğal bir set değildir. Bu fonksiyonları doğal olmayan setlerde kullanmak beklenmeyen sonuçlar döndürür.
Örnekler: Set fonksiyonları kullanan set değiştiriciler için grafik ifadeleri
Yükleme kodu
Aşağıdaki grafik ifadesi örneklerini oluşturmak için aşağıdaki verileri veri yükleme düzenleyicisinde satır içi yükleme olarak yükleyin.
MyTable:
Load
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date,
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date,
Country, Product, Amount
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1]; Satır içi yüklemeleri kullanma hakkında daha fazla bilgi için bkz. Satır içi yüklemeler.
Grafik ifadeleri
Aşağıdaki grafik ifadeleriyle Qlik Sense sayfasında bir tablo oluşturun.
| Ülke | $(=Sum(Tutar)) | Sum({<Country=P({<Year={2019}>} Ülke)>} Tutar) | Sum({<Product=P({<Year={2019}>} Ürün)>} Tutar) | Sum({<Country=E({<Product={Washer}>} Ülke)>} Tutar) |
|---|---|---|---|---|
| Toplamlar | 41 | 10 | 17 | 13 |
| Kanada | 14 | 0 | 6 | 0 |
| Çek Cumhuriyeti | 10 | 10 | 10 | 0 |
| Fransa | 4 | 0 | 1 | 0 |
| Almanya | 13 | 0 | 0 | 13 |
Açıklama
-
Boyutlar:
-
Country
-
-
Measures:
-
Sum(Amount)
Set ifadesi olmadan Amount toplamını al.
-
Sum({<Country=P({<Year={2019}>} Country)>} Amount)
2019 yılı ile ilişkili ülkeler için Amount değerini topla. Ancak hesaplama 2019 ile sınırlanmaz.
-
Sum({<Product=P({<Year={2019}>} Product)>} Amount)
2019 ile ilişkili ürünler için Amount değerini topla. Ancak hesaplama 2019 ile sınırlanmaz.
-
Sum({<Country=E({<Product={Washer}>} Country)>} Amount)
Washer ile ilişkili ülkeler için Amount değerini topla.
-
Set fonksiyonları kullanan set değiştiriciler
İfadeler hakkında daha fazla bilgi için bkz. Görselleştirmelerde ifadeleri kullanma.
| Örnekler | Sonuçlar |
|---|---|
| sum( {$<Customer = P({1<Product={'Shoe'}>} Customer)>} Sales ) |
Geçerli seçim için satışları döndürür, ancak yalnızca daha önce 'Shoe' ürününü satın almış müşterileri içerir. Burada P( ) unsur fonksiyonu, Product alanında 'Shoe' seçimiyle örtük olarak belirtilen olası müşterilerin listesini döndürür. |
| sum( {$<Customer = P({1<Product={'Shoe'}>})>} Sales ) |
Yukarıdaki ile aynı. Unsur fonksiyonundaki alan atlanırsa, fonksiyon, dış atamada belirtilen alanın olası değerlerini döndürür. |
| sum( {$<Customer = P({1<Product={'Shoe'}>} Supplier)>} Sales ) |
Geçerli seçim için satışları döndürür ancak yalnızca daha önce 'Shoe' ürününü tedarik etmiş müşterileri, başka bir deyişle aynı zamanda tedarikçi olan müşterileri içerir. Burada P( ) unsur fonksiyonu, Product alanında 'Shoe' seçimiyle örtük olarak belirtilen olası tedarikçilerin listesini döndürür. Bu durumda, tedarikçi listesi, Customer alanında bir seçim olarak kullanılır. |
| sum( {$<Customer = E({1<Product={'Shoe'}>})>} Sales ) |
Geçerli seçim için satışları döndürür, ancak yalnızca daha önce 'Shoe' ürününü hiç satın almamış müşterileri içerir. Burada E( ) unsur fonksiyonu, Product alanında 'Shoe' seçimiyle hariç tutulan, hariç tutulmuş müşterilerin listesini döndürür. |