if — funkcja skryptu i funkcja wykresu

Funkcja if zwraca wartość w zależności od tego, czy warunek określony w ramach tej funkcji uwzględnia wartości True czy False.

Składnia:

if(condition , then [, else])

Argumenty
Argument	Opis
condition	Wyrażenie, które jest interpretowane logicznie.
then	Wyrażenie, które może być dowolnego typu. Jeśli wyrażeniecondition ma wartość True, wówczas funkcja if zwraca wartość wyrażenia then.
else	Wyrażenie, które może być dowolnego typu. Jeśli wyrażeniecondition ma wartość False, wówczas funkcja if zwraca wartość wyrażenia else. Ten parametr jest opcjonalny. Jeśli warunek condition jest False, zwracana jest wartość NULL, jeśli nie określono else.

Niektóre przykłady w tym temacie wykorzystują ładowania wbudowane. Więcej informacji zawiera temat Używanie wbudowanych ładowań do ładowania danych.

Przykład
Przykład	Wynik
if( Amount>= 0, 'OK', 'Alarm' )	To wyrażenie sprawdza, czy ilość jest liczbą dodatnią (0 lub większą), i zwraca wówczas OK. Jeśli ilość jest liczbą mniejszą od 0, zwracane jest Alarm.

Przykład — skrypt ładowania używający if

Skrypt ładowania

Funkcja If może być używana w skrypcie ładowania z innymi metodami i obiektami, w tym również ze zmiennymi. Jeśli na przykład ustawisz zmienną threshold (próg) i chcesz uwzględnić pole w modelu danych na podstawie tego progu, możesz zrobić to tak:

Utwórz nową kartę w edytorze ładowania danych, a następnie załaduj następujące dane jako ładowanie wbudowane. Utwórz tabelę poniżej w Qlik Sense, aby zobaczyć wyniki.

Transactions:
Load * Inline [
transaction_id, transaction_date, transaction_amount, transaction_quantity, customer_id, size, color_code
3750, 20180830, 23.56, 2, 2038593, L, Red
3751, 20180907, 556.31, 6, 203521, m, orange
3752, 20180916, 5.75, 1, 5646471, S, blue
3753, 20180922, 125.00, 7, 3036491, l, Black
3754, 20180922, 484.21, 13, 049681, xs, Red
3756, 20180922, 59.18, 2, 2038593, M, Blue
3757, 20180923, 177.42, 21, 203521, XL, Black
];
 
set threshold = 100;
					
/* Create new table called Transaction_Buckets 
Compare transaction_amount field from Transaction table to threshold of 100.
Output results into a new field called Compared to Threshold							
 */					
 
Transaction_Buckets:
Load
   transaction_id,
   If(transaction_amount > $(threshold),'Greater than $(threshold)','Less than $(threshold)') as [Compared to Threshold]
Resident Transactions;

Wyniki

Tabela programu Qlik Sense przedstawiająca wynik użycia funkcji if w skrypcie ładowania.
transaction_id	W porównaniu do progu
3750	Mniej niż 100
3751	Więcej niż 100
3752	Mniej niż 100
3753	Więcej niż 100
3754	Więcej niż 100
3756	Mniej niż 100
3757	Więcej niż 100

Przykłady — wyrażenia wykresu używające if

Wyrażenie wykresu 1

Skrypt ładowania

Utwórz nową kartę w edytorze ładowania danych, a następnie załaduj następujące dane jako ładowanie wbudowane. Po załadowaniu danych utwórz poniższe przykłady wyrażeń wykresu w tabeli Qlik Sense.

MyTable:
LOAD * inline [Date, Location, Incidents
1/3/2016, Beijing, 0
1/3/2016, Boston, 12
1/3/2016, Stockholm, 3
1/3/2016, Toronto, 0
1/4/2016, Beijing, 0
1/4/2016, Boston, 8];

Tabela aplikacji Qlik Sense z przykładami funkcji if w wyrażeniu wykresu.
Data	Lokalizacja	Incidents	if(Incidents>=10, 'Critical', 'Ok' )	if(Incidents>=10, 'Critical', If( Incidents>=1 and Incidents<10, 'Warning', 'Ok'))
1/3/2016	Beijing	0	OK	OK
1/3/2016	Boston	12	Critical	Critical
1/3/2016	Stockholm	3	OK	Ostrzeżenie
1/3/2016	Toronto	0	OK	OK
1/4/2016	Beijing	0	OK	OK
1/4/2016	Boston	8	OK	Ostrzeżenie

Wyrażenie wykresu 2

W nowej aplikacji dodaj następujący skrypt w nowej karcie w edytorze ładowania danych, a następnie załaduj dane. Następnie możesz utworzyć tabelę z poniższymi wyrażeniami wykresu.

SET FirstWeekDay=0;
Load 
Date(MakeDate(2022)+RecNo()-1) as Date
Autogenerate 14;

Tabela aplikacji Qlik Sense z przykładem funkcji if w wyrażeniu wykresu.
Data	WeekDay(Date)	If(WeekDay(Date)>=5,'WeekEnd','Normal Day')
1/1/2022	Sat	WeekEnd
1/2/2022	Sun	WeekEnd
1/3/2022	Pon	Normal Day
1/4/2022	Wto	Normal Day
1/5/2022	Śro	Normal Day
1/6/2022	Czw	Normal Day
1/7/2022	Pią	Normal Day
1/8/2022	Sat	WeekEnd
1/9/2022	Sun	WeekEnd
1/10/2022	Mon	Normal Day
1/11/2022	Tue	Normal Day
1/12/2022	Wed	Normal Day
1/13/2022	Thu	Normal Day
1/14/2022	Fri	Normal Day

Czy ta strona była pomocna?

Jeżeli natkniesz się na problemy z tą stroną lub jej zawartością — literówkę, brakujący krok lub błąd techniczny — daj nam znać!

Przekaż tu opinię