集合修饰符和高级搜索

加载脚本

将以下数据作为数据加载编辑中的内联加载载入，以创建以下图表表达式示例。

MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1];	

有关使用内联加载的详细信息，请参见内联加载。

示例 1：带有文本搜索的图表表达式

使用以下图表表达式在 Qlik Sense 工作表中创建表。

解释

• 维度：

  • Country

• 度量：

  • Sum(Amount)

    没有集合表达式的总和 Amount。

  • Sum({<Country={"C*"}>}Amount)

    总和 Amount，针对以 C 开头的所有国家，例如 Canada 以及 Czech Republic。

  • Sum({<Country={"*^R*"}>}Amount)

    总和 Amount，针对以 R 开头的所有国家，例如 Czech Republic。

  • Sum({<Product={"*bolt*"}>}Amount)

    总和 Amount，针对包含字符串 bolt 的所有产品，例如 Bolt 以及 Anchor bolt。

有关表达式的更多信息，请参阅在可视化中使用表达式。

示例 2：带有数字搜索的图表表达式

使用以下图表表达式在 Qlik Sense 工作表中创建表。

解释

• 维度：

  • Country

• 度量：

  • Sum(Amount)

    没有集合表达式的总和 Amount。

  • Sum({<Year={">2019"}>}Amount)

    总和 Amount，针对 2019 之后的所有年份。

  • Sum({<ISO_Date={">=2019-07-01"}>}Amount)

    总和 Amount，针对 2019-07-01 或之后的所有日期。搜索中日期的格式必须与字段的格式匹配。

  • Sum({<US_Date={">=4/1/2018<=12/31/2018"}>}Amount)

    总和 Amount，适用于从 4/1/2018 到 12/31/2018 的所有日期，包括开始和结束日期。搜索中日期的格式必须与字段的格式匹配。

示例 3：带有表达式搜索的图表表达式

使用以下图表表达式在 Qlik Sense 工作表中创建表。

解释

• 维度：

  • Country

• 度量：

  • Sum(Amount)

    没有集合表达式的总和 Amount。

  • Sum({<Country={"=Sum(Amount)>10"}>}Amount)

    总和 Amount ，针对 Amount 的聚合总和大于 10 的所有国家。

  • Sum({<Country={"=Count(distinct Product)=1"}>}Amount)

    总和 Amount，针对准确地与一个不同的产品关联的所有国家。

  • Sum({<Product={"=Count(Amount)>3"}>}Amount)

    总和 Amount，针对数据中有三个以上交易的所有国家。