# 集合修飾詞

集合運算式用來定義計算範圍。集合運算式的中央部分是指定選項的集合修飾詞。這用來修改使用者選項，或集合識別碼中的選項，而結果會定義新的計算範圍。

集合修飾詞的組成為一個或多個欄位名稱、各個欄位的後面都加上要對該欄位做出的選項。修飾詞括在角括號內：`< >`

例如︰

* `Sum ( {$<Year = {2015}>} Sales )`

* `Count ( {1<Country = {Germany}>} distinct OrderID )`

* `Sum ( {$<Year = {2015}, Country = {Germany}>} Sales )`

## 元素集

可以使用下列內容定義元素集：

* 值清單

* 搜尋

* 另一個欄位參考

* 集合函數

若省略元素集定義，集合修飾詞將會清除此欄位中的任何選項。例如︰

`Sum( {$<Year = >} Sales )`

## 範例：根據元素集用於集合修飾詞的圖表運算式

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers.htm)

#### 範例 - 圖表運算式

載入指令碼

在資料載入編輯器中載入下列資料作為內嵌載入，以建立以下的圖表運算式範例。

```
MyTable:
Load * Inline [
Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
Belgium, 2014, 182766.87
Belgium, 2015, 178042.33
Brazil, 2014, 174492.67
Brazil, 2015, 2104.22
Canada, 2014, 101801.33
Canada, 2015, 40288.25
Denmark, 2014, 45273.25
Denmark, 2015, 106938.41
Finland, 2014, 107565.55
Finland, 2015, 30583.44
France, 2014, 115644.26
France, 2015, 30696.98
Germany, 2014, 8775.18
Germany, 2015, 77185.68
];
```

如需更多關於使用內嵌載入的資訊，請參閱 [使用內嵌載入以載入資料](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm)。

圖表運算式

透過下列圖表運算式在 Qlik Sense 工作表中建立表格。

表格 - 以元素集為基礎的集合修飾詞

| 國家/地區 | Sum(Sales) | 總和({1&lt;國家={比利時}&gt;} 銷售額) | 總和({1&lt;國家={"\*A\*"}&gt;} 銷售額) | 總和({1&lt;國家={"A\*"}&gt;} 銷售額) | Sum({1&lt;Year={$(=Max(Year))}&gt;} Sales) |
| --- | --- | --- | --- | --- | --- |
| 總計 | 1645397.3 | 360809.2 | 1284588.1 | 443238.88 | 788617.07 |
| 阿根廷 | 206332.92 | 0 | 206332.92 | 206332.92 | 140037.89 |
| 奧地利 | 236905.96 | 0 | 236905.96 | 236905.96 | 182739.87 |
| 比利時 | 360809.2 | 360809.2 | 0 | 0 | 178042.33 |
| 巴西 | 176596.89 | 0 | 176596.89 | 0 | 2104.22 |
| 加拿大 | 142089.58 | 0 | 142089.58 | 0 | 40288.25 |
| 丹麥 | 152211.66 | 0 | 152211.66 | 0 | 106938.41 |
| 芬蘭 | 138148.99 | 0 | 138148.99 | 0 | 30583.44 |
| 法國 | 146341.24 | 0 | 146341.24 | 0 | 30696.98 |
| 德國 | 85960.86 | 0 | 85960.86 | 0 | 77185.68 |

解釋

* 維度：

  * `Country`

* 量值：

  * `Sum(Sales)`

    不含集合運算式的 `Sales` 總和。

  * `Sum({1<Country={Belgium}>}Sales)`

    選取 `Belgium`，然後選取對應 `Sales` 的總和。

  * `Sum({1<Country={"*A*"}>}Sales)`

    選取具有 `A` 的所有國家，然後選取對應 `Sales` 的總和。

  * `Sum({1<Country={"A*"}>}Sales)`

    選取以 `A` 開頭的所有國家，然後選取對應 `Sales` 的總和。

  * `Sum({1<Year={$(=Max(Year))}>}Sales)`

    計算 `Max(Year)`，這是 `2015`，然後選取對應 `Sales` 的總和。

以元素集合為基礎的集合修飾詞

以元素集合為基礎的集合修飾詞

以元素集合為基礎的集合修飾詞 ![以元素集合為基礎的集合修飾詞。](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_set_modifiers_element_sets.png)

## 列出的值

元素集的常見情況是會以括在大括弧內的欄位值清單為基礎。例如︰

* `{$<Country = {Canada, Germany, Singapore}>}`

* `{$<Year = {2015, 2016}>}`

大括弧內部定義元素集。各個值以逗號分隔。

## 引號和區分大小寫

若值包含空白或特殊字元，則值需要加上引號。單引號將是常值、區分大小寫並符合單一欄位值。雙引號暗示區分大小寫並符合一個或數個欄位值。例如︰

* `<Country = {'New Zealand'}>`

  僅符合 `New Zealand`。

* `<Country = {"New Zealand"}>`

  符合 `New Zealand`、`NEW ZEALAND` 和 `new zealand`。

日期必須括在引號內，並使用有問題的欄位的日期格式。例如︰

* `<ISO_Date = {'2021-12-31'}>`

* `<US_Date = {'12/31/2021'}>`

* `<UK_Date = {'31/12/2021'}>`

方括弧或重音符號可以替代雙引號。

## 搜尋

也可以透過搜尋建立元素集。例如︰

* `<Country = {"C*"}>`
* `<Ingredient = {"*garlic*"}>`
* `<Year = {">2015"}>`
* `<Date = {">12/31/2015"}>`

萬用字元可用於文字搜尋：星號 (`*`) 表示任何數量的字元，而問號 (`?`) 表示單一字元。關係運算子可用來定義數字搜尋。

您應永遠使用雙引號進行搜尋。搜尋不區分大小寫。

如需詳細資訊，請參閱[含搜尋的集合修飾詞](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-advanced-searches.htm)。

## 貨幣擴充

若您想要在元素集內部使用計算，則需要貨幣擴充。例如，若您只想要查看可用的上一年，可以使用：

`<Year = {$(=Max(Year))}>`

如需詳細資訊，請參閱[含貨幣符號展開的集合修飾詞](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-dollar-sign-expansions.htm)。

## 其他欄位中已選取的值

修飾詞能夠以另一個欄位的選取值為基礎。例如︰

`<OrderDate = DeliveryDate>`

此修飾詞會取用 `DeliveryDate` 的選取值，然後將其套用為 `OrderDate` 的選項。如果有許多相異值 (超過幾百個)，則此運算會需要大量的 CPU，應避免使用。

## 元素集函數

元素集也可以根據集合功能 `P()` (可能值) 和 `E()` (排除值)。

例如，若您想要選取銷售產品 `Cap` 的國家，可以使用：

`<Country = P({1<Product={Cap}>} Country)>`

同樣地，若您想要挑選出尚未銷售產品 `Cap` 的國家，可以使用：

`<Country = E({1<Product={Cap}>} Country)>`

如需詳細資訊，請參閱[使用集合函數的集合修飾詞](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-implicit-field-value-definitions.htm)。

## 瞭解更多資訊

* [集合分析](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-analysis-expressions.htm)

* [集合識別碼](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-identifiers.htm)

* [集合運算子](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-operators.htm)