# Mode - 圖表函數

Mode() 會在已彙總之資料中找到最常發生的值，即模式值。Mode() 函數可以處理文字值以及數值。

語法：

Mode({[SetExpression] [TOTAL [<fld {,fld}>]]} expr)

傳回的資料類型： 雙值

引數

| 引數 | 描述 |
| --- | --- |
| expr | 包含待測量之資料的運算式或欄位。 |
| SetExpression | 依預設，彙總函數將彙總選項所定義的一組可能記錄。集合分析運算式可定義一組替代的記錄。 |
| TOTAL | 如果單字 TOTAL 位於函數引數之前，則會在提供現行選項的所有可能值上進行計算，而不僅僅是關於目前維度值的那些選項，也就是說，它會忽略圖表維度。<br><br>透過使用 TOTAL [&lt;fld {.fld}&gt;] (其中 TOTAL 限定詞後面是做為圖表維度變數子集之一或更多欄位名稱的清單)，您可建立總可能值的子集。<br><br>[定義彙總範圍](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |

範例：圖表運算式

| 範例 | 結果 |
| --- | --- |
| `Mode(UnitSales)` | 傳回 `UnitSales` 中最常出現的值。<br><br>傳回 `NULL (-)`。沒有任何單一值會比其他值更常出現。 |
| `Mode(Customer)` | 傳回 `Customer` 中最常出現的值。<br><br>傳回 `NULL (-)`。沒有任何單一值會比其他值更常出現。 |
| `Mode(TOTAL UnitSales)` | `TOTAL` 限定詞會傳回 `Unitsales` 中最常出現的值，忽略圖表維度。 |
| `Mode({1} TOTAL UnitSales)` | 集合分析運算式 `{1}` 會定義要評估為 `ALL` 的記錄組合，與選取的任何選項無關。例如，如果選取了特定客戶，這仍將傳回整個資料集最常出現的 `UnitSales` 值。 |

## 範例 - Mode 基礎事項

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/mode.htm)

#### 圖表運算式

概述

開啟資料載入編輯器並將下面的載入指令碼新增至新的區段。

載入指令碼包含：

* 載入到稱為 `Example` 之資料表格的資料集。

* 資料表格中的欄位如下：

  * `Customer`

  * `UnitSales`

  * `UnitPrice`

載入指令碼

```
Example:
LOAD * inline [
Customer|UnitSales|UnitPrice
Astrida|4|16
Astrida|10|15
Astrida|9|9
Astrida|10|10
Betacab|5|10
Betacab|4|20
Betacab||25
Canutility|8|15
Canutility|4|19
] (delimiter is '|');
```

結果

載入資料並開啟工作表。建立新的表格並將此欄位新增為維度：

* `Customer`

建立下列量值：

* `=Mode(UnitSales)`，用來計算最常出現的 `UnitSales` 值。

* `=Mode(Customer)`，用來計算最常出現的 `Customer` 值。

* `=Mode(TOTAL UnitSales)`，用來計算整個資料集中最常出現的 `UnitSales` 值，忽略圖表維度。如果進行了選取，該值將會調整，以反映該選項。

* `=Mode({1} TOTAL UnitSales)`，用來計算最常出現的 `UnitSales` 值，忽略選項。如果進行了選取，則值保持不變。

Results table

| Customer | Mode(UnitSales) | Mode(Customer) | Mode(TOTAL UnitSales) | Mode({1} TOTAL UnitSales) |
| --- | --- | --- | --- | --- |
| Totals | 4 | Astrida | 4 | 4 |
| Astrida | 10 | Astrida | 4 | 4 |
| Betacab | - | Betacab | 4 | 4 |
| Canutility | - | Canutility | 4 | 4 |

在此範例中，請觀察以下事項：

* 在第一個量值 (`Mode(UnitSales)`) 中，客戶 `Astrida` 最常出現的值為 `10`。`Totals` 儲存格傳回 `4`，這是整個資料集中 `UnitSales` 最常出現的值。`Betacab` 和 `Canutility` 沒有最常出現之值的執行個體，因此結果會為這些客戶傳回 `NULL`。

* 在第二個量值 (`Mode(Customer)`) 中，結果傳回每個客戶名稱。不過，`Totals` 儲存格傳回 `Astrida`，因為這是整個資料集中最常出現的客戶值。

* 第三個量值 (`Mode(TOTAL UnitSales)`) 傳回值 4。如果沒有選取 `Customer`，則此欄中的所有儲存格將會顯示值 4。若您選取某個客戶，例如 `Betacab`，此欄將會傳回 `NULL`，因為 `Betacab` 沒有常出現的值。

* 無論 `Customer` 欄位中的選項是什麼，第四個量值 (`Mode({1} TOTAL UnitSales)`) 都會傳回 `4`，因為集合分析運算式 `{1}` 將要評估的記錄組合定義為 `ALL`。例如，如果您選取 `Betacab`，則此欄將繼續傳回值 `4`。

## 範例 - 判定銷售資料異常的 Mode 使用情境

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/mode.htm)

#### 圖表運算式

概述

資料集包含依月份劃分的銷售數據。該公司希望查看整個資料集中每種產品最常出現的銷售值。該公司也希望比較產品的銷售額與整個資料集，以識別資料中的任何非典型異常。

開啟資料載入編輯器並將下面的載入指令碼新增至新的區段。

載入指令碼包含：

* 載入到稱為 `Example` 之資料表格的資料集。

* 資料表格中的欄位如下：

  * `Date`

  * `Product`

  * `Category`

  * `Sales`

載入指令碼

```
Example:
Load * inline [
Date, Product, Category, Sales
2024-01-01, Apple, Fruit, 100
2024-01-15, Banana, Fruit, 80
2024-01-30, Carrot, Vegetable, 50
2024-02-05, Apple, Fruit, 100
2024-02-20, Banana, Fruit, 90
2024-02-28, Carrot, Vegetable, 60
2024-03-10, Apple, Fruit, 110
2024-03-22, Banana, Fruit, 80
2024-03-31, Carrot, Vegetable, 50
2024-04-10, Apple, Fruit, 125
2024-04-22, Banana, Fruit, 60
2024-04-31, Carrot, Vegetable, 80
];
```

結果

載入資料並開啟工作表。建立新的表格並將這些欄位新增為維度：

* `Category`

* `Product`

建立下列量值：

* `=Mode(Sales)`，用來計算每種產品最常出現的值。

* `=Mode(TOTAL Sales)`，用來計算整個資料集最常出現的值。

* `If(Mode(Sales) = Mode(TOTAL Sales), 'Typical', 'Atypical')`，用來計算與整個資料集的結果相比，每種產品最常出現的值是否為常態情況。

Results table

| Category | Product | Mode(Sales) | Mode(TOTAL Sales) | If(Mode(Sales) = Mode(TOTAL Sales), 'Typical', 'Atypical') |
| --- | --- | --- | --- | --- |
| Fruit | Apple | 100 | 80 | Atypical |
| Fruit | Banana | 80 | 80 | Typical |
| Vegetable | Carrot | 50 | 80 | Atypical |

`Mode` 函數的輸出依產品 `Mode(Sales)` 和所有產品 `Mode(TOTAL Sales)` 傳回最常出現的銷售值。然後會比較這兩個值，以判定哪些銷售結果是典型或非典型。

## 瞭解更多資訊

* [Avg - 圖表函數](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/StatisticalAggregationFunctionsinCharts/avg.htm)
* [Median - 圖表函數](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/StatisticalAggregationFunctionsinCharts/median.htm)
* [集合分析](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-analysis-expressions.htm)
* [定義彙總範圍](https://help.qlik.com/zh-TW/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm)