# 含搜尋的集合修飾詞

您可以使用集合修飾詞透過搜尋建立元素集。

例如︰

* `<Country = {"C*"}>`
* `<Year = {">2015"}>`
* `<Ingredient = {"*garlic*"}>`

應永遠以雙引號、方括號或重音符號括起搜尋。您可以混用常值字串 (單引號) 和搜尋 (雙引號) 以使用清單。例如︰

`<Product = {'Nut', "*Bolt", Washer}>`

## 文字搜尋

萬用字元和其他符號可用於文字搜尋：

* 星號 (\*) 將代表任何字元數量。

* 問號 (?) 將代表單一字元。

* 抑揚符號 (^) 將標記一個字的開頭。

例如︰

* `<Country = {"C*", "*land"}>`

  比對所有以 `C` 開頭或以 `land` 結尾的國家。

* `<Country = {"*^z*"}>`

  這將比對含有以 `z` 開頭之字的所有國家，例如 `New Zealand`。

## 數值搜尋

您可以使用這些關係運算子進行數值搜尋：`>`、`>=`、`<`、`<=`

數值搜尋永遠以這些運算子之一開頭。例如︰

* `<Year = {">2015"}>`

  比對 2016 和後續年份。

* `<Date = {">=1/1/2015<1/1/2016"}>`

  在 2015 年期間比對所有日期。記下描述兩個日期之間時間範圍的語法。日期格式需要符合問題中欄位的日期格式。

## 運算式搜尋

您可以使用運算式搜尋以進行更進階的搜尋。然後將針對搜尋欄位中的每個欄位值評估彙總。將選取搜尋運算式傳回 true 的所有值。

運算式搜尋通常以等號開頭：`=`

例如︰

`<Customer = {"=Sum(Sales)>1000"}>`

這將會傳回銷售值大於 1000 的所有客戶。`Sum(Sales)` 在目前選項上計算。這表示，若您在另一個欄位中有選項，例如 `Product` 欄位，則您只會取得滿足所選產品銷售條件的客戶。

若您希望條件獨立於選項，需要在搜尋字串內部使用集合分析。例如︰

`<Customer = {"=Sum({1} Sales)>1000"}>`

等號之後的運算式將會解譯為布林值。這表示，若這對其他內容進行評估，則任何非零數字將會解譯為 true，而零和字串將會解譯為 false。

## 引號

若搜尋字串包含空白或特殊字元，請使用引號。單引號暗示常值、區分大小寫並符合單一欄位值。雙引號暗示區分大小寫的搜尋，這可能符合多個欄位值。

例如︰

* `<Country = {'New Zealand'}>`

  僅符合 `New Zealand`。

* `<Country = {"New Zealand"}>`

  符合 `New Zealand`、`NEW ZEALAND` 和 `new zealand`

方括弧或重音符號可以替代雙引號。

如需詳細資訊，請參閱[在選項或視覺化中搜尋](https://help.qlik.com/zh-TW/cloud-services/Subsystems/Hub/Content/Sense_Hub/Selections/SelectionsToolbar/search-selections.htm)。

資訊備註在先前版本的 Qlik Sense 中，沒有區分單引號和雙引號，所有引號內的字串都視為搜尋。為維持向下相容性，透過舊版 Qlik Sense 建立的應用程式將會依照先前版本的方式繼續運作。透過 Qlik Sense November 2017 或更高版本建立的應用程式將會顧及兩種引號類型之間的差異。

## 範例：含搜尋的集合修飾詞的圖表運算式

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-advanced-searches.htm)

#### 範例 - 圖表運算式

載入指令碼

在資料載入編輯器中載入下列資料作為內嵌載入，以建立以下的圖表運算式範例。

```
MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1];	
```

如需更多關於使用內嵌載入的資訊，請參閱 [使用內嵌載入以載入資料](https://help.qlik.com/zh-TW/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm)。

範例 1：含文字搜尋的圖表運算式

透過下列圖表運算式在 Qlik Sense 工作表中建立表格。

表格 - 含文字搜尋的集合修飾詞

| 國家/地區 | Sum (Amount) | Sum({&lt;Country={"C\*"}&gt;} Amount) | Sum({&lt;Country={"\*^R\*"}&gt;} Amount) | Sum({&lt;Product={"\*bolt\*"}&gt;} Amount) |
| --- | --- | --- | --- | --- |
| 總計 | 41 | 24 | 10 | 26 |
| 加拿大 | 14 | 14 | 0 | 8 |
| 捷克 | 10 | 10 | 10 | 4 |
| 法國 | 4 | 0 | 0 | 1 |
| 德國 | 13 | 0 | 0 | 13 |

解釋

* 維度：

  * `Country`

* 量值：

  * `Sum(Amount)`

    不含集合運算式的 `Amount` 總和。

  * `Sum({<Country={"C*"}>}Amount)`

    以 `C` 開頭的所有國家的總和 `Amount`，例如 `Canada` 和 `Czech Republic`。

  * `Sum({<Country={"*^R*"}>}Amount)`

    有個字以 `R` 開頭的所有國家的總和 `Amount`，例如 `Czech Republic`。

  * `Sum({<Product={"*bolt*"}>}Amount)`

    包含字串 `bolt` 的所有產品的總和 `Amount`，例如 `Bolt` 和 `Anchor bolt`。

含文字搜尋的集合修飾詞

含文字搜尋的集合修飾詞

含文字搜尋的集合修飾詞 ![含文字搜尋的圖表運算式。](https://help.qlik.com/zh-TW/cloud-services/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_text_search.png)

如需關於運算式的詳細資訊，請參閱[在視覺化中使用運算式](https://help.qlik.com/zh-TW/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/use-expressions-in-visualizations.htm)。

範例 2：含數值搜尋的圖表運算式

透過下列圖表運算式在 Qlik Sense 工作表中建立表格。

表格 - 含數值搜尋的集合修飾詞

| 國家/地區 | Sum (Amount) | Sum({&lt;Year={"&gt;2019"}&gt;} Amount) | Sum({&lt;ISO\_Date={"&gt;=2019-07-01"}&gt;} Amount) | Sum({&lt;US\_Date={"&gt;=4/1/2018&lt;=12/31/2018"}&gt;} Amount) |
| --- | --- | --- | --- | --- |
| 總計 | 41 | 10 | 16 | 16 |
| 加拿大 | 14 | 8 | 8 | 0 |
| 捷克 | 10 | 0 | 6 | 1 |
| 法國 | 4 | 2 | 2 | 2 |
| 德國 | 13 | 0 | 0 | 13 |

解釋

* 維度：

  * `Country`

* 量值：

  * `Sum(Amount)`

    不含集合運算式的 `Amount` 總和。

  * `Sum({<Year={">2019"}>}Amount)`

    `2019` 之後所有年份的總和 `Amount`。

  * `Sum({<ISO_Date={">=2019-07-01"}>}Amount)`

    `2019-07-01` 當日或之後所有日期的總和 `Amount`。搜尋中的日期格式必須符合欄位格式。

  * `Sum({<US_Date={">=4/1/2018<=12/31/2018"}>}Amount)`

    從 `4/1/2018` 至 `12/31/2018` 所有日期的總和 `Amount`，包括開始和結束日期。搜尋中的日期格式必須符合欄位格式。

含數值搜尋的集合修飾詞

含數值搜尋的集合修飾詞

含數值搜尋的集合修飾詞 ![含數值搜尋的圖表運算式。](https://help.qlik.com/zh-TW/cloud-services/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_numeric_search.png)

範例 3：含運算式搜尋的圖表運算式

透過下列圖表運算式在 Qlik Sense 工作表中建立表格。

Table - Set modifiers with expression searches

| Country | Sum (Amount) | Sum({&lt;Country={"=Sum(Amount)&gt;10"}&gt;} Amount) | Sum({&lt;Country={"=Count(distinct Product)=1"}&gt;} Amount) | Sum({&lt;Product={"=Count(Amount)&gt;3"}&gt;} Amount) |
| --- | --- | --- | --- | --- |
| Totals | 41 | 27 | 13 | 22 |
| Canada | 14 | 14 | 0 | 8 |
| Czech Republic | 10 | 0 | 0 | 0 |
| France | 4 | 0 | 0 | 1 |
| Germany | 13 | 13 | 13 | 13 |

解釋

* 維度：

  * `Country`

* 量值：

  * `Sum(Amount)`

    不含集合運算式的 `Amount` 總和。

  * `Sum({<Country={"=Sum(Amount)>10"}>}Amount)`

    `Amount` 彙總總和大於 `10` 的所有國家的總和 `Amount`。

  * `Sum({<Country={"=Count(distinct Product)=1"}>}Amount)`

    與確切一個相異產品相關的所有國家的總和 `Amount`。

  * `Sum({<Product={"=Count(Amount)>3"}>}Amount)`

    在資料中有超過三筆交易的所有國家的總和 `Amount`。

含運算式搜尋的集合修飾詞

含運算式搜尋的集合修飾詞

含運算式搜尋的集合修飾詞 ![含運算式搜尋的圖表運算式。](https://help.qlik.com/zh-TW/cloud-services/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_expression_search.png)

| 範例 | 結果 |
| --- | --- |
| sum( {$–1&lt;Product = {“\*Internal\*”, “\*Domestic\*”}&gt;} Sales ) | 會傳回目前選項的銷售額，但排除與產品名稱中含字串「Internal」或「Domestic」之產品相關的交易。 |
| sum( {$&lt;Customer = {“=Sum({1&lt;Year = {2007}&gt;} Sales ) &gt; 1000000”}&gt;} Sales ) | 會傳回目前選項的銷售額，但包含「Customer」欄位中新的選項：僅針對在 2007 年期間總銷售額超過 1000000 的客戶。 |