# Only - grafik fonksiyonu

Only() , toplanmış verilerde yalnızca bir olası sonuç varsa bir değer döndürür. Örneğin, birim fiyatın =9 olduğu tek bir ürün arandığında, birden fazla ürünün birim fiyatı 9 ise NULL döndürülür.

Söz Dizimi:

Only([{SetExpression}] [TOTAL [<fld {,fld}>]] expr)

Dönüş verileri türü: dual

Bağımsız Değişkenler

| Bağımsız Değişken | Açıklama |
| --- | --- |
| expr | Hesaplanacak verileri içeren ifade veya alan. |
| SetExpression | Toplama işlevi, varsayılan olarak, seçim tarafından tanımlanmış olası kayıtlar kümesi üzerinden toplanır. Bir set analizi ifadesi ile alternatif bir kayıt kümesi tanımlanabilir. |
| TOTAL | TOTAL sözcüğü, fonksiyon bağımsız değişkenlerinden önce gelirse, hesaplama yalnızca geçerli boyutsal değere ait olanlar için değil, geçerli seçimlerde verilen tüm olası değerler üzerinden yapılır; yani grafik boyutlarını göz ardı eder.<br><br>TOTAL niteleyicisinden sonra grafik boyut değişkenlerinin bir alt kümesi olarak bir veya daha çok alan adının geldiği TOTAL [&lt;fld {.fld}&gt;] niteleyicisini kullanarak toplam olası değerlerin bir alt kümesini oluşturursunuz.<br><br>[Toplama kapsamını tanımlama](https://help.qlik.com/tr-TR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |

İpucu notuÖrnek verilerde birden fazla olası değer varsa NULL sonucu istediğiniz durumlarda Only() fonksiyonunu kullanın.

Örnek: Grafik ifadesi

| Örnek | Sonuç |
| --- | --- |
| `Only(Category)` | Bağlam içinde benzersiz olduğu sürece `Category` görüntüler. |

## Örnek - Only temel bilgileri

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/only.htm)

#### Grafik ifadesi

Genel bakış

Veri yükleme düzenleyicisini açın ve aşağıdaki komut dosyasını yeni bir bölüme ekleyin.

Komut dosyası şunları içerir:

* `Example` adlı veri tablosuna yüklenen bir veri kümesi.

* Veri tablosundaki şu alanlar:

  * `Customer`

  * `Product`

  * `UnitSales`

  * `UnitPrice`

Komut dosyası

```
Example:
LOAD * inline [
Customer|Product|UnitSales|UnitPrice
Astrida|AA|4|16
Astrida|AA|10|15
Astrida|BB|9|9
Betacab|BB|5|10
Betacab|CC|2|20
Betacab|DD||25
Canutility|AA|8|15
Canutility|CC||19
] (delimiter is '|');
```

Sonuçlar

Verileri yükleyin ve bir sayfa açın. Aşağıdaki hesaplamalarla yeni bir tablo oluşturun:

* `=Only({<UnitPrice={9}>} Product)`, `UnitPrice` `9` bulunan tek `Product` değerini hesaplamak için.

* `=Only({<Product={DD}>} Customer)`, `DD` adlı bir `Product` satan tek `Customer` hesaplamak için.

* `=Only({<UnitPrice={20}>} UnitSales)`, `UnitPrice` değerinin `20` olduğu `UnitSales` sayısını hesaplamak için.

* `=Only({<UnitPrice={15}>} UnitSales)`, `UnitPrice = 15` olan `UnitSales` değerini hesaplamak için.

Results table

| Only({&lt;UnitPrice={9}&gt;} Product) | Only({&lt;Product={DD}&gt;} Customer) | Only({&lt;UnitPrice={20}&gt;} UnitSales) | Only({&lt;UnitPrice={15}&gt;} UnitSales) |
| --- | --- | --- | --- |
| BB | Betacab | 2 | - |

Bu örnekte aşağıdakileri gözlemleyin:

* İlk sütun `BB` değerini döndürür çünkü bu, `UnitPrice` `9` bulunan tek `Product` değeridir.

* İkinci sütun `Betacab` döndürür çünkü `DD` adında bir `Product` satan tek `Customer` budur.

* Üçüncü sütun `2` değerini döndürür çünkü bu, `UnitPrice = 20` olan tek `UnitSales` değeridir.

* Dördüncü sütun `NULL` döndürür çünkü `UnitPrice = 15` olan tek bir sonuç yoktur. Bu veri kümesinde, `UnitPrice =15` olan iki `UnitSales` değeri vardır.

## Örnek - Only senaryosu

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/only.htm)

#### Grafik ifadesi

Genel bakış

Bir veri kümesi, döneme göre ürün satışlarını içerir. Şirket, bir ürünün tek bir mağazada mı yoksa birden fazla mağazada mı satıldığını belirlemek istiyor.

Veri yükleme düzenleyicisini açın ve aşağıdaki komut dosyasını yeni bir bölüme ekleyin.

Komut dosyası şunları içerir:

* `Example` adlı veri tablosuna yüklenen bir veri kümesi.

* Veri tablosundaki şu alanlar:

  * `Date`

  * `RecordID`

  * `StoreProduct`

  * `Sales`

Komut dosyası

```
Example:
Load * inline [
Date, RecordID, StoreProduct, Sales, Store
2024-01-01, 1, Apple, 100, A
2024-01-15, 2, Banana, 80, B
2024-01-30, 3, Carrot, 50, C
2024-02-05, 4, Apple, 120, A
2024-02-20, 5, Banana, 90, B
2024-02-28, 6, Carrot, 60, D
2024-03-10, 7, Apple, 110, A
2024-03-22, 8, Banana, 85, B
2024-03-31, 9, Carrot, 55, C
];
```

Sonuçlar

Verileri yükleyin ve bir sayfa açın. Yeni bir tablo oluşturun ve şu alanı boyut olarak ekleyin:

* `StoreProduct`

Aşağıdaki hesaplamaları oluşturun:

* `=Only(Store)`, ürünün satıldığı benzersiz mağazayı hesaplamak için.

* `=If(IsNull(Only(Store)), 'Multiple Stores', 'Single Store')`, ürünün tek bir mağazada mı yoksa birden fazla mağazada mı satıldığını hesaplamak için.

* `=Sum(Sales)`, toplam ürün satışlarını hesaplamak için.

Results table

| StoreProduct | Only(Store) | If(IsNull(Only(Store)), 'Multiple Stores', 'Single Store') | Sum(Sales) |
| --- | --- | --- | --- |
| Apple | A | Single Store | 330 |
| Banana | B | Single Store | 255 |
| Carrot | - | Multiple Stores | 165 |

Sonuçlar, `Apples` ve `Bananas` ürünlerinin yalnızca tek bir mağazada, `Carrots` ürününün ise birden fazla mağazada satıldığını göstermektedir.

## Örnek - Tek aylık bir kayıt tablosu oluşturmak için gelişmiş senaryo

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/only.htm)

#### Grafik ifadesi

Genel bakış

Bu örnekte, tek bir aya ait kayıtların satır satır tablosunu göstermek için `Only` fonksiyonu kullanılmaktadır. Bunu başarmak için, istenen kayıt kümesinin kapsamını belirlemek üzere küme analizi kullanılır. Küme analizi en az bir hesaplama gerektirir, ancak aslında kayıt kümesini toplamamız gerekmediğinden, küme analizi kapsamını barındırmak için `Only` toplama fonksiyonunu etkin bir şekilde kullanabiliriz.

Veri yükleme düzenleyicisini açın ve aşağıdaki komut dosyasını yeni bir bölüme ekleyin.

Komut dosyası şunları içerir:

* `Example` adlı veri tablosuna yüklenen bir veri kümesi.

* `MonthStart` fonksiyonunu kullanarak ayın gününü kesmek ve her ayın 1'inin tarih temsilini döndürerek `MonthYear` alanını `Date` alanından türeten önceki bir yükleme deyimi. Bu sonuç, görüntüleme biçimini `MMM YY`, örneğin `Jan 24` olarak ayarlamak için `Date` fonksiyonuna verilir.

* Veri tablosundaki şu alanlar:

  * `Date`

  * `RecordID`

  * `StoreProduct`

  * `Sales`

  * `Store`

Komut dosyası

```
Example:
Load
*,
date(MonthStart (Date),'MMM YY') AS MonthYear
inline [
Date, RecordID, StoreProduct, Sales, Store
2024-01-01, 1, Apple, 100, A
2024-01-15, 2, Banana, 80, B
2024-01-30, 3, Carrot, 50, C
2024-02-05, 4, Apple, 120, A
2024-02-20, 5, Banana, 90, B
2024-02-28, 6, Carrot, 60, D
2024-03-10, 7, Apple, 110, A
2024-03-22, 8, Banana, 85, B
2024-03-31, 9, Carrot, 55, C
];
```

Sonuçlar

Verileri yükleyin ve bir sayfa açın. Yeni bir tablo oluşturun ve şu alanları boyut olarak ekleyin:

* `MonthYear`

* `RecordID`

* `Date`

* `StoreProduct`

* `Store`

Aşağıdaki hesaplamaları oluşturun:

* `=Only({$<MonthYear={'$(=MaxString(MonthYear))'}>} Sales)`, `Sales` değerini değerlendirmek ve tablodaki mevcut seçimlere göre yalnızca `MonthYear` adresinin mevcut en son (en yeni) `MonthYear` adresi olduğu durumları döndürmek için. Dolar işareti ($) açılımı, en son `MonthYear` değerinin metin temsilini döndüren `MaxString` fonksiyonunu ( `$(=MaxString(MonthYear))`) kullanarak satır içi bir hesaplama gerçekleştirir.

Bilgi notuSayısal gösterime dayalı olarak `MonthYear` filtrelemesi yapmaya çalışmak, örneğin ` Max  ` fonksiyonu kullanmak, `Max(MonthYear)`, herhangi bir sonuç vermeyecektir. Küme analizi, herhangi bir ikili veri türünün yalnızca metin temsiline dayalı filtre seçimleri uygular; `Date` gibi sayısal ve metin temsiline sahip bir veri türü.

Results table

| MonthYear | RecordID | Date | StoreProduct | Only({$&lt;MonthYear={‘$(=MaxString(MonthYear))’}&gt;} Sales) |
| --- | --- | --- | --- | --- |
| Mar 24 | 7 | 2024-03-10 | Apple | 110 |
| Mar 24 | 8 | 2024-03-22 | Banana | 85 |
| Mar 24 | 9 | 2024-03-31 | Carrot | 55 |

`Only` fonksiyonunun çıktısı, verilerde mevcut olan en son veya en yeni `MonthYear` için satış değerini sunmak üzere varsayılan olarak bir kayıt tablosu üretir. `MonthYear` sütunundan `Feb 24` gibi daha önceki bir ayı seçerseniz o ay için en son satış değeri görünecektir.

## Daha fazla bilgi

* [Set analizi](https://help.qlik.com/tr-TR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-analysis-expressions.htm)
* [Toplama kapsamını tanımlama](https://help.qlik.com/tr-TR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm)