# Set değiştiricileri

Set ifadeleri bir hesaplamanın kapsamını tanımlamak için kullanılır. Set ifadesinin orta kısmı bir seçim belirten set değiştiricidir. Bu, kullanıcı seçimini veya set tanımlayıcısındaki seçimi değiştirmek için kullanılır ve sonuç, hesaplama için yeni bir kapsam tanımlar.

Küme değiştiricisi bir veya daha fazla alan adından oluşur ve her birinin ardından o alanda yapılması gereken bir seçim yapılır. Değiştirici, köşeli parantezler arasına alınır: `< >`

Örneğin:

* `Sum ( {$<Year = {2015}>} Sales )`

* `Count ( {1<Country = {Germany}>} distinct OrderID )`

* `Sum ( {$<Year = {2015}, Country = {Germany}>} Sales )`

## Öğe setleri

Öğe seti, aşağıdakiler kullanılarak tanımlanabilir:

* Bir değer listesi

* Bir arama

* Başka bir alana başvuru

* Bir dizi fonksiyon

Öğe seti tanımı atlanırsa set değiştirici bu alandaki herhangi bir seçimi temizleyecektir. Örnek:

`Sum( {$<Year = >} Sales )`

## Örnekler: Öğe setlerine dayalı set değiştiriciler için grafik ifadeleri

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers.htm)

#### Örnekler - grafik ifadeleri

Yükleme kodu

Aşağıdaki grafik ifadesi örneklerini oluşturmak için aşağıdaki verileri veri yükleme düzenleyicisinde satır içi yükleme olarak yükleyin.

```
MyTable:
Load * Inline [
Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
Belgium, 2014, 182766.87
Belgium, 2015, 178042.33
Brazil, 2014, 174492.67
Brazil, 2015, 2104.22
Canada, 2014, 101801.33
Canada, 2015, 40288.25
Denmark, 2014, 45273.25
Denmark, 2015, 106938.41
Finland, 2014, 107565.55
Finland, 2015, 30583.44
France, 2014, 115644.26
France, 2015, 30696.98
Germany, 2014, 8775.18
Germany, 2015, 77185.68
];
```

Satır içi yüklemeleri kullanma hakkında daha fazla bilgi için bk. [Veri yüklemek için satır içi yüklemeler kullanma](https://help.qlik.com/tr-TR/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm).

Grafik ifadeleri

Aşağıdaki grafik ifadeleriyle Qlik Sense sayfasında bir tablo oluşturun.

Tablo - Öğe setlerini temel alan set değiştiriciler

| Ülke | Sum(Sales) | Sum({1&lt;Country={Belgium}&gt;} Sales) | Sum({1&lt;Country={"\*A\*"}&gt;} Sales) | Sum({1&lt;Country={"A\*"}&gt;} Sales) | Sum({1&lt;Year={$(=Max(Year))}&gt;} Sales) |
| --- | --- | --- | --- | --- | --- |
| Toplamlar | 1645397.3 | 360809.2 | 1284588.1 | 443238.88 | 788617.07 |
| Arjantin | 206332.92 | 0 | 206332.92 | 206332.92 | 140037.89 |
| Avusturya | 236905.96 | 0 | 236905.96 | 236905.96 | 182739.87 |
| Belçika | 360809.2 | 360809.2 | 0 | 0 | 178042.33 |
| Brezilya | 176596.89 | 0 | 176596.89 | 0 | 2104.22 |
| Kanada | 142089.58 | 0 | 142089.58 | 0 | 40288.25 |
| Danimarka | 152211.66 | 0 | 152211.66 | 0 | 106938.41 |
| Finlandiya | 138148.99 | 0 | 138148.99 | 0 | 30583.44 |
| Fransa | 146341.24 | 0 | 146341.24 | 0 | 30696.98 |
| Almanya | 85960.86 | 0 | 85960.86 | 0 | 77185.68 |

Açıklama

* Boyutlar:

  * `Country`

* Hesaplamalar:

  * `Sum(Sales)`

    Set ifadesi olmadan `Sales` toplamını al.

  * `Sum({1<Country={Belgium}>}Sales)`

    `Belgium` öğesini seç, sonra ilgili `Sales` toplamını al.

  * `Sum({1<Country={"*A*"}>}Sales)`

    `A` içeren tüm ülkeleri seç, sonra ilgili `Sales` toplamını al.

  * `Sum({1<Country={"A*"}>}Sales)`

    `A` ile başlayan tüm ülkeleri seç, sonra ilgili `Sales` toplamını al.

  * `Sum({1<Year={$(=Max(Year))}>}Sales)`

    `2015` olan `Max(Year)` değerini hesapla, sonra ilgili `Sales` toplamını al.

Öğe kümelerine dayalı set değiştiriciler

Öğe kümelerine dayalı set değiştiriciler

Öğe kümelerine dayalı set değiştiriciler ![Öğe kümelerine dayalı set değiştiriciler.](https://help.qlik.com/tr-TR/sense/May2025/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_set_modifiers_element_sets.png)

## Listelenen değerler

Öğe setine en yaygın örnek, küme parantezleri içine alınmış alan değerleri listesine dayalı olandır. Örneğin:

* `{$<Country = {Canada, Germany, Singapore}>}`

* `{$<Year = {2015, 2016}>}`

İç küme ayraçları öğe setini tanımlar. Bireysel değerler virgülle ayrılır.

## Alıntılar ve büyük/küçük harf duyarlılığı

Değerlerde boşluklar veya özel karakterler varsa değerlerin tırnak içine alınması gerekir. Tek tırnaklar, tek bir alan değeriyle gerçek, büyük/küçük harfe duyarlı bir eşleşmeyi belirtir. Çift tırnak, bir veya birkaç alan değeriyle büyük/küçük harfe duyarlı olmayan bir eşleşmeyi ifade eder. Örneğin:

* `<Country = {'New Zealand'}>`

  Yalnızca `New Zealand` ile eşleşir.

* `<Country = {"New Zealand"}>`

  `New Zealand`, `NEW ZEALAND` ve `new zealand` ile eşleşir.

Tarihler tırnak işareti içine alınmalı ve söz konusu alanın tarih biçimi kullanılmalıdır. Örneğin:

* `<ISO_Date = {'2021-12-31'}>`

* `<US_Date = {'12/31/2021'}>`

* `<UK_Date = {'31/12/2021'}>`

Çift tırnaklar; köşeli parantezlerle veya vurgu işaretleriyle değiştirilebilir.

## Aramalar

Öğe setleri aramalar yoluyla da oluşturulabilir. Örnek:

* `<Country = {"C*"}>`
* `<Ingredient = {"*garlic*"}>`
* `<Year = {">2015"}>`
* `<Date = {">12/31/2015"}>`

Metin aramalarında joker karakterler kullanılabilir: Yıldız işareti (`*`) herhangi bir sayıda karakteri, soru işareti (`?`) ise tek bir karakteri temsil eder. İlişkisel işleçler, sayısal aramaları tanımlamak için kullanılabilir.

Aramalar için her zaman çift tırnak kullanmalısınız. Aramalar büyük/küçük harf duyarlıdır.

Daha fazla bilgi için bk. [Set değiştiriciler içeren aramalar](https://help.qlik.com/tr-TR/sense/May2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-advanced-searches.htm).

## Dolar işareti genişletmeleri

Öğe setiniz içinde bir hesaplama kullanmak istiyorsanız dolar işareti genişletmeleri gerekir. Örneğin, yalnızca mümkün olan son yıla bakmak istiyorsanız şunları kullanabilirsiniz:

`<Year = {$(=Max(Year))}>`

Daha fazla bilgi için bk. [Dolar işareti genişletmeleri içeren set değiştiricileri](https://help.qlik.com/tr-TR/sense/May2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-dollar-sign-expansions.htm).

## Diğer alanlarda seçilen değerler

Değiştiriciler, başka bir alanın seçilen değerlerine dayalı olabilir. Örneğin:

`<OrderDate = DeliveryDate>`

Bu değiştirici, seçilen değerleri `DeliveryDate` öğesinden alır ve bunları `OrderDate` öğesine bir seçim olarak uygular. Birkaç yüzü aşacak kadar çok sayıda tekil değer mevcutsa bu işlem CPU'yu yoğun olarak kullanır ve bu işlemden kaçınılmalıdır.

## Öğe seti fonksiyonları

Öğe seti ayrıca `P()` set fonksiyonlarına (olası değerler) ve `E()`, hariç tutulan değerlere dayalı olabilir.

Örneğin, `Cap` ürününün satıldığı ülkeleri seçmek istiyorsanız şunları kullanabilirsiniz:

`<Country = P({1<Product={Cap}>} Country)>`

Benzer şekilde, `Cap` ürününün satılmadığı ülkeleri seçmek isterseniz şunları kullanabilirsiniz:

`<Country = E({1<Product={Cap}>} Country)>`

Daha fazla bilgi için bk. [Set fonksiyonları kullanan set değiştiriciler](https://help.qlik.com/tr-TR/sense/May2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-implicit-field-value-definitions.htm).

## Daha fazla bilgi

* [Set analizi](https://help.qlik.com/tr-TR/sense/May2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-analysis-expressions.htm)

* [Set tanımlayıcıları](https://help.qlik.com/tr-TR/sense/May2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-identifiers.htm)

* [Set işleçleri](https://help.qlik.com/tr-TR/sense/May2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-operators.htm)