# Satır içi tablolardan veri yükleme
Satır içi tablo tanımlamak için bir komut dosyasına manuel olarak veri yazın.
Dosyalara ve veritabanlarına bağlanmak yerine, komut dosyasına manuel olarak veri yazarak satır içi tablolar oluştururuz. Komut dosyası metninin satır içi veri olarak yorumlandığını belirtmek için gerekli söz dizimini kullanın.
Temel bir satır içi yükleme bir tablo oluşturur ve veri alanlarını ve kayıtları ekler.
## Neden satır içi yükleme kullanmalısınız?
Satır içi yüklemeler birçok kullanım alanında faydalı olabilir:
* Harici kaynaklara bağlanma ihtiyacı duymadan verileri yönetme ve düzenleme.
* Veri modelindeki mevcut verileri tamamlama. Örneğin, çoğunlukla veritabanı kaynaklarından gelen bir veri modeline ilave bir tablo ekleyebilirsiniz.
* Sürekli harici kaynaklardan yüklenmesinden kaçınmak istediğiniz verileri ekleme. Veri kaynağının gelecekte değişebileceğine, ancak veri değerlerinin aynı kalacağına inanıyorsanız bu, zamandan tasarruf sağlayabilir.
* İçerikleri diğer dosyalardan kopyalama ve komut dosyasına yapıştırma kolaylığı. Örneğin, kelime işlemci belgelerinden .csv dosyaları veya tabloları.
* Hızlıca kopyalanıp yapıştırılabilen test komut dosyaları oluşturma.
## Temel söz dizimi örneği
Aşağıdaki komut dosyası basit bir satır içi yükleme içerir.
```
MyTable:
Load * Inline [Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
];
```
Aşağıdaki söz dizimi, yukarıdaki satır içi yüklemesi için kullanılır:
* Load \* Inline, QlikView için tüm alanları sonraki satır içi tablodan yüklemesi talimatını verir.
* MyTable:, tablonun adını tanımlar.
* Veriler köşeli paranteze alınır.
* Yükleme deyiminin birinci satırı, veri alanlarını tanımlar.
* Virgüller, veri alanlarını ve kayıtları ayırır.
* Noktalı virgül, yükleme deyimini kapatır.
## Söz dizimine genel bakış
### Tabloyu adlandırma
Satır içi tabloya, diğer yüklenen tablolara olduğu gibi bir ad ekleyebilirsiniz. Tablo adını tanımlamak isteğe bağlıdır.
Tablonun adından sonra iki nokta üst üste ekleyin.
### LOAD ve inline deyimleri
LOAD komut dosyası deyimini kullandığınızda bir satır içi tablo, inline cümlesiyle yüklenir. inline cümlesi, tabloda sonra gelen metnin düzenleyiciye manuel olarak girilen veriler içerdiğini belirtir. Aksini belirtmediğiniz sürece bir satır içi tablo, ayrılmış metin dosyası yapısına uyan txt biçimini kullanır.
LOAD deyimi hakkında daha fazla bilgi için bkz. [Load](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm).
### Başa ve sona koyulan simgeler ve veri girişi
inline cümlesi aracılığıyla girilen verilerin belirli karakterlerin içine alınması gerekir. Aşağıda, verilerin başına ve sonuna koyulması kabul edilen karakter kombinasyonları verilmiştir:
* Köşeli parantezler: `[` ve `]`
* Çift tırnak işaretleri: `"` ve `"`
* Tek tırnak işaretleri: `'` ve `'`
* Kesme işaretleri: `` ` `` ve `` ` ``
Başa ve sona eklemek için seçtiğiniz karakter, çakışan karakterler içeren satır içi verileri yüklemenize yardımcı olabilir. Örneğin, verileriniz köşeli parantezlere sahip kayıtlar içeriyorsa bunun yerine, başına ve sonuna tırnak işaretleri veya kesme işaretleri koyabilirsiniz.
Başa ve sona eklenen karakterlere alternatif örnekler için bkz. [Örnek - Verilerin başına ve sonuna eklenen alternatif karakterler](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDataEnc).
Alternatif bir tablo biçimi belirtmediğiniz sürece (varsayılan: txt) başa ve sona eklenen karakterlerin arasındaki metin, dosyanın bağlamıyla aynı şekilde yorumlanır. Bu nedenle, bir metin dosyasında yeni satır eklerken, bunu aynı zamanda inline cümlesinin metninde de yapmalı, yani komut dosyasını yazarken Enter tuşuna basmalısınız.
### Satır içi yüklemeyi sonlandırma
Satır içi yükleme deyiminin sonu bir noktalı virgülle ifade edilir.
### Veri dönüşümleri
Dönüşüm olmayan basit bir satır içi yüklemede sütun sayısı, birinci satıra göre tanımlanır. Aşağıdaki örneğe göre yüklenen tabloda üç sütun vardır: `Product_ID`, `Supplier_Name` ve `Product_Category`.
```
Products:
Load * Inline [
Product_ID, Supplier_Name, Product_Category
1, Paracel, Home Decor
2, PageWave, Electronics
3, Talarian, Software
4, Userland, Appliances
];
```
Ayrıca aynı satır içi tabloda dönüşümler gerçekleştirebilir ve yeni sütunlar oluşturabilirsiniz. Önceki yüklemeleri kullanabilirsiniz ve aynı tabloyu yüklemek için birden fazla LOAD deyimi kullanılabilir.
Spesifik örnekler için bkz. [Örnekler - Dönüşümler içeren satır içi yüklemeler](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExTransform).
### Bir satır içi yüklemede biçim belirtimini yapılandırma
Diğer yüklenen tablolarda olduğu gibi, satır içi tablonun biçim belirtimini biçim belirtimi öğelerini kullanarak değiştirebilirsiniz. Biçim belirtimi, parantez içinde eklenir. Verilerin başına ve sonuna eklenen karakterlerden sonra, ancak LOAD deyimini sonlandıran noktalı virgülden önce eklenmelidir. Ekleyebileceğiniz özelleştirmelerden bazıları şunları içerir:
* Virgül olan ayırıcıyı başka bir karakterle değiştirme. Örnekler için bkz. [Örnekler - Alternatif ayırıcılar](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDelimiter).
Bkz. [Delimiter](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/delimiter.htm)
* Tablo sütunu başlıklarını atlama. Örnek için bkz. [Örnek - Sütun başlıklarını atlama](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOmitLabels).
Bkz. [Labels](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/labels.htm)
* Başka bir veri biçimi (örneğin, sabit kayıt biçimi) kullanma. Örnek için bkz. [Örnek - Başka bir veri türünü yükleme](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExChangeFormat).
Bkz. [Table format](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/table-format.htm)
Bilgi notuSatır içi yüklemeleri için tüm Table format seçenekleri desteklenmez.
* Çok satırlı içeriklere izin verme. Örnek için bkz. [Örnek - Çok satırlı içerik](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExMultLine).
Bkz. [Quotes](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/quotes.htm)
Aynı tabloda birden fazla biçim belirtimi öğesi kullanmak için bunları virgülle ayırın. Örneğin:` (Delimiter is '|', no labels) `
Biçim belirtimi hakkında tüm ayrıntılar için bkz. [Biçimlendirme belirtim öğeleri](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm).
### İşleçler ve diğer cümleler
Ek olarak, satır içi yüklemesi bir LOAD deyimi olduğundan, LOAD deyimi için diğer bağımsız değişkenleri satır içi yüklemeyle birleştirebilirsiniz. Örneğin, belirli bir satırın içindeki metne bağlı olarak yüklenip yüklenmeyeceğini tanımlamak için where veya while cümlesini kullanın.
Benzer şekilde, metin içeriğinin dışında işleçler de kullanabilirsiniz. İşleçler ile satır içi verileri nasıl dönüştüreceğinizi özelleştirebilir ve belirli verilerin ne zaman yükleneceğini veya yüklenmeyeceğini tanımlayabilirsiniz.
Spesifik bir örnek için bkz. [Örnek - Dönüşümler ve cümleler için işleçler](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOpsAndClauses).
## Örnek - Verilerin başına ve sonuna eklenen alternatif karakterler
Bir satır içi yüklemenin başına ve sonuna köşeli parantezler, tırnak işaretleri veya kesme işaretleri yerleştirebilirsiniz. Bu bölümde bu bir örnekle açıklanmıştır. Daha fazla bilgi için bkz. [Başa ve sona koyulan simgeler ve veri girişi](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Enclosure).
#### Komut dosyası ve sonuçları
Genel bakış
Bu örnek, satır içi verilerin başına ve sonuna nasıl kesme işareti ekleyebileceğinizi gösterir. Örnekteki veriler köşeli parantez karakterleri içerir, bu da köşeli parantezlerin LOAD deyimi için uygun olmamasına neden olur.
Kod dosyası
```
DataTable:
Load * inline
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;
```
Sonuçlar
* `custom_property`
* `date`
* `amount`
Sonuçlar tablosu
| custom\_property | date | amount |
| --- | --- | --- |
| [11402] | 1/1/2024 | 92.99 |
| [11403] | 1/2/2024 | 102.34 |
| [11404] | 1/3/2024 | 50.26 |
| [11405] | 1/4/2024 | 153.69 |
| [11406] | 1/5/2024 | 75.62 |
## Örnekler - Alternatif ayırıcılar
Tablodaki sütun değerlerini ayırmak için virgülden farklı bir karakter kullanabilirsiniz. Daha fazla bilgi için bkz. [Bir satır içi yüklemede biçim belirtimini yapılandırma](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Komut dosyası ve sonuçları
Genel bakış
Tablodaki veriler virgül içerdiğinde ayırıcıyı değiştirmek kullanışlıdır; aksi takdirde tabloda bir sonraki sütuna geçişe işaret ederler.
Bu örnek şunları içerir:
* Yüklenecek dört tablo. Bunlar aşağıda verilmiştir:
* Table1: Sınırlayıcı, dikey sütundur (dikey çizgi). Phrase sütunundaki veriler virgül içerir.
* Table2: Sınırlayıcı, iki nokta üst üstedir.
* Table3: Sınırlayıcı, ters eğik çizgidir.
* Table4: Tablo, klavyedeki Tab tuşuna basarak ayrılır. Bu seçenek, bir tabloyu kelime işlemciden kopyalayıp komut dosyasına yapıştırırken kullanışlıdır.
Table1, alternatif bir ayırıcı kullanmaya yönelik pratik bir kullanım durumu gösterir. Diğer tablolarda daha fazla ayırıcı seçeneği gösterilir.
Kod dosyası
```
Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');
Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');
Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);
Table4:
LOAD * INLINE [
Num3 Chr3
1 A
2 B ] (Delimiter is '\t');
```
Sonuçlar
Sonuçlar tablosu: Table1Table1
| ID | Phrase |
| --- | --- |
| 1 | The transaction was complete, but the order has not yet shipped. |
| 2 | We need to confirm the following details: sales rep number, order status, and shipping priority. |
Sonuçlar tablosu: Table2Table2
| Num1 | Chr1 |
| --- | --- |
| 1 | A |
| 2 | B |
Sonuçlar tablosu: Table3Table3
| Num2 | Chr2 |
| --- | --- |
| 1 | A |
| 2 | B |
Sonuçlar tablosu: Table4Table4
| Num3 | Chr3 |
| --- | --- |
| 1 | A |
| 2 | B |
## Örnek - Sütun başlıklarını atlama
Biçim belirtimini bir satır içi tabloyu sütun başlıklarını tanımlamadan yükleyecek şekilde düzenleyin. Bu, labels belirtimiyle (no labels değerine ayarlayarak) yapılır. Daha fazla bilgi için bkz. [Bir satır içi yüklemede biçim belirtimini yapılandırma](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
Bir tabloyu sütun adlarını tanımlamadan yüklediğinizde sistem tarafından tanımlanan sütun adları otomatik olarak kullanılır.
#### Komut dosyası ve sonuçları
Genel bakış
Bu örnekte, bir satır içi tabloyu sütun adlarını tanımlamadan nasıl yükleyebileceğiniz gösterilmiştir.
Kod dosyası
```
Expenses:
Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);
```
Sonuçlar
Sonuçlar tablosu
| @1 | @2 | @3 |
| --- | --- | --- |
| 1 | Category1 | 40566.49 |
| 2 | Category2 | 3504.54 |
| 3 | Category3 | 593206.30 |
## Örnek - Başka bir veri türünü yükleme
Bu örnekte, bir satır içi tabloyu sabit kayıt biçiminde nasıl yükleyebileceğiniz gösterilmiştir. Bkz. [Bir satır içi yüklemede biçim belirtimini yapılandırma](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Komut dosyası ve sonuçları
Genel bakış
Bu örnek komut dosyası şunları içerir:
* DataTable tablosunu tanımlayan bir satır içi yükleme deyimi.
* Yüklenecek verilerin sabit kayıt biçiminde olduğunu belirtmek için fix kullanma (Table format belirtiminin parçası olarak).
Kod dosyası
```
DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a b c d
1 2 3 4
x y z w
] (fix, utf8, embedded labels);
```
Sonuçlar
Sonuçlar tablosu
| a | b | c | d |
| --- | --- | --- | --- |
| 1 | 2 | 3 | 4 |
| x | y | z | w |
## Örnek - Çok satırlı içerik
Bu örnekte, bir satır içi tabloya nasıl çok satırlı içerik girebileceğiniz gösterilmiştir. Bkz. [Bir satır içi yüklemede biçim belirtimini yapılandırma](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Komut dosyası ve sonuçları
Genel bakış
Bu örnek komut dosyası şunları içerir:
* T1 tablosunu tanımlamak için basit bir satır içi yükleme.
* Çok satırlı içeriği desteklemek için Quotes belirticisini kullanma (msq değeriyle).
* Fit ve inç cinsinden belirtilen uzunluk değerleri.
* Çift tırnak işareti sembolü ("), çok satırlı bir girişin sonunu belirtir. Bu örnekte aynı sembol, inç değerlerini göstermek için de kullanılmıştır. Bu, aynı LOAD deyiminde her ikisini de kullanmanız gerekiyorsa söz dizimini ve sonuçta oluşan davranışı göstermek için yapılır. Temelde art arda iki karakter ("") için " sembolü girmek, kodun, sembolün tek bir metin örneği olarak yorumlanacağını belirtir.
Kod dosyası
```
T1:
Load *, recno() as ID inline [
Length
"1' 2""
22' 10"""
14' 8" ] (msq);
```
Sonuçlar
Çok satırlı içeriği amaçlanan şekilde görüntülemek için Özellikler... yapılandırmasında grafik için Çok Satırlı Ayarları'nı düzenlemeniz gerekir.
Sonuçlar tablosu
| ID | Length |
| --- | --- |
| 1 | 1' 2"
22' 10" |
| 2 | 14' 8" |
Yukarıdaki tabloda, 1 değerinde bir ID çok satırlı içerik içeriyor.
## Örnekler - Dönüşümler içeren satır içi yüklemeler
Bu örnekler, veri modelinde yeni alanlar oluşturmak için alan yüklenen satır içi üzerinde nasıl hesaplamalar yapabileceğinizi gösterir.
Daha fazla bilgi için bkz. [Veri dönüşümleri](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Transform).
#### Örnek: Bir alanı basit şekilde yeniden adlandırma
Kod dosyası
```
ORDERS:
Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];
```
Sonuçlar
Sonuçlar tablosu
| Original | Updated |
| --- | --- |
| ProductA | ProductA |
| ProductB | ProductB |
| ProductC | ProductC |
#### Örnek: Bir kimlik alanını basit şekilde ekleme
Genel bakış
Bu örnekte, her bir kimlik değerini manuel olarak yazmadan her bir veri satırının kimliğini belirtmek için bir hesaplanan alanı nasıl tanımlayabileceğinizi gösterilmektedir.
Kod dosyası
```
ORDERS:
Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];
```
Sonuçlar
Sonuçlar tablosu
| ID | ProductName |
| --- | --- |
| 1 | A |
| 2 | B |
| 3 | C |
| 4 | D |
| 5 | E |
#### Örnek: Dönüşümleri işlemek için LOAD deyimlerini yapılandırma
Genel bakış
Bu örnekte, basit bir dönüşümün satır içi verilere uygulanabileceği birkaç yol gösterilmektedir. Bir dönüşümün orijinal alanın yerini alıp almayacağını veya hem orijinal hem yeni alanların yüklenip yüklenmeyeceğini tanımlamak için bir ya da birden fazla LOAD deyimi kullanabilir ve söz dizimini farklı şekillerde yapılandırabilirsiniz.
Özellikle aşağıdaki varyasyonlara ve bunların çıktıyı nasıl etkilediğine dikkat edin:
* Tablodaki LOAD deyimi sayısı.
* \* sembolünün varlığı veya yokluğu (tüm sonraki alanları yükler).
* Virgüllerin varlığı veya yokluğu (, sembolü).
Bu örnek komut dosyası şunları içerir:
* Tümü aynı verilere referans veren dört tablo. Alan adları farklıdır.
* DerivedYears1: Bir satır içi sütunu ve satır içi sütunun dönüşümünü içeren bir sütunu yüklemek için iki LOAD deyimi kullanır.
* DerivedYears2: İki LOAD deyimi kullanır. Komut dosyası bir satır içi sütun yükler, ardından orijinal sütundan dönüştürülen bir hesaplanan alanı yükler. İkinci LOAD deyimiyle orijinal sütun, tabloya yüklenmez ve bu sayede yeni alanın etkili bir şekilde orijinal alanın yerini almasını sağlar.
* DerivedYears3: Hem orijinal satır içi sütunu hem dönüştürülen bir sütunu yüklemek için tek bir LOAD deyimi kullanır.
* DerivedYears4: Bir satır içi alanını ve o orijinal alanın bir dönüşümünü tanımlamak için tek bir LOAD deyimi kullanır. Yalnızca dönüştürülen alan tabloya yüklenir.
Kod dosyası
```
DerivedYears1:
Load *,
Year(initial_date1) as derived_year1
;
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears2:
Load
Year(initial_date2) as derived_year2
;
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears3:
Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears4:
Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
```
Sonuçlar
Sonuçlar tablosu: DerivedYears1DerivedYears1
| initial\_date1 | derived\_year1 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Sonuçlar tablosu: DerivedYears2DerivedYears2
| derived\_year2 |
| --- |
| 2022 |
| 2023 |
| 2024 |
Sonuçlar tablosu: DerivedYears3DerivedYears3
| initial\_date3 | derived\_year3 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Sonuçlar tablosu: DerivedYears4DerivedYears4
| derived\_year4 |
| --- |
| 2022 |
| 2023 |
| 2024 |
#### Örnek: Alan içeriğini değiştirme
Genel bakış
Büyük bir metin dosyasından komut dosyası düzenleyiciye bilgi yapıştırdığınızı, ancak veri kümesindeki kayıtlar üzerinde ilave işleme gerçekleştirmek istediğinizi varsayalım. Örneğin, belirli karakterleri ve ön ekleri kaldırmak ve her bir sözcüğün baş harfini büyük yapmak istiyorsunuz.
Bu örnek komut dosyası şunları içerir:
* Bir alanın metin içeriğini değiştirmek üzere içinde bir dönüşüm tanımı olan bir satır içi tablo Transformations. Dönüştürülen metin bundan sonra eklenir.
* İki LOAD deyimi. Örnekteki yapılandırmayla yalnızca türetilen alan ProductName\_Trimmed tabloya yüklenir.
Kod dosyası
```
Transformations:
Load
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;
Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product: {snack food}
Product: {electronics and video games}
];
```
Sonuçlar
Sonuçlar tablosu
| ProductName\_Trimmed |
| --- |
| Soft Drinks And Other Beverages |
| Snack Food |
| Electronics And Video Games |
## Örnek - Dönüşümler ve cümleler için işleçler
LOAD deyiminde dönüşümleri ve belirli cümleleri tanımlamak için işleçleri kullanabilirsiniz. Daha fazla bilgi için bkz. [İşleçler ve diğer cümleler](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#OpsAndClauses).
[İşleçler](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/Operators/operators.htm)
#### Komut dosyası ve sonuçları
Genel bakış
Bu örnek komut dosyası şunları içerir:
* Purchases tablosunu tanımlamak için basit bir satır içi yükleme.
* OrderSize olan bir hesaplanan alanın eklenmesi. Bu alan, satır içi veri kümesinden amount alanının bir dönüşümüdür. Alışverişleri, 2000,00 USD tutarını aşıp aşmadığına göre küçük veya büyük olarak kategorize eder.
* amount 0,05 USD tutarından az olduğunda kayıtların yüklenmesini engelleyen bir where cümlesi.
Kod dosyası
```
Purchases:
Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,
* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;
```
Sonuçlar
Sonuçlar tablosu
| ID | amount | OrderSize |
| --- | --- | --- |
| 1 | 2660.39 | Large Purchase |
| 2 | 100.01 | Small Purchase |
| 3 | 500.42 | Small Purchase |
| 4 | 5023.99 | Large Purchase |
| 6 | 2002.39 | Large Purchase |
| 7 | 31034.53 | Large Purchase |
| 8 | 1643.58 | Small Purchase |
| 9 | 3993.65 | Large Purchase |
| 10 | 614.34 | Small Purchase |
| 11 | 675.93 | Small Purchase |
Yukarıdaki tabloda, 5 olan bir ID içeren işlem tabloya yüklenmedi. Bunun nedeni, amount değerinin 0,05 USD tutarından az olması.
## Örnek - Bir satır içi tabloda null değerler oluşturma
Bu örnekte, satır içi verilerinizde null değerler oluşturmak için NullInterpret değişkenini nasıl kullanabileceğiniz gösterilmektedir.
[NullInterpret](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ValueHandlingVariables/NullInterpret.htm)
#### Komut dosyası ve sonuçları
Genel bakış
Bu örnek komut dosyası şunları içerir:
* T2 tablosunu tanımlamak için basit bir satır içi yükleme.
* İki tek tırnak işareti olarak tanımlanan NullInterpret değişkeni. Komut dosyası yüklendiğinde bu değeri içeren kayıtlar, null değerler olarak işlenir.
Kod dosyası
```
set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];
```
Sonuçlar
Sonuçlar tablosu
| Test |
| --- |
| x |
Yukarıdaki tabloda birinci kayıt bir null değerdir. Bu nedenle görselleştirmeye dahil edilmez. Ek boyutlar içeren tablolardaki null değerler bir - sembolüyle belirtilecektir.
## Daha fazla örnek
Ek örnekler için bkz. [Load](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm).
## Daha fazla bilgi
* [Load](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm)
* [Biçimlendirme belirtim öğeleri](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm)
* [Satır İçi Veri Sihirbazı](https://help.qlik.com/tr-TR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Inline_Data_Wizard.htm)