# Below - grafik fonksiyonu
Below(), tablodaki bir sütun segmenti dahilinde geçerli satırın altındaki bir satırda ifadeyi değerlendirir. Hesaplandığı satır offset değerine göre değişir (varsa) ve varsayılan ayar doğrudan altındaki satırdır. Tablolar dışındaki grafikler için Below(), grafiğin düz tablo eşdeğerinde geçerli sütunun altındaki satır için değerlendirme yapar.
Söz Dizimi:
Below([TOTAL] expr [ , offset [,count ]])
Dönüş verileri türü: dual
Bağımsız Değişkenler
| Bağımsız Değişken | Açıklama |
| --- | --- |
| expr | Hesaplanacak verileri içeren ifade veya alan. |
| offset | 1'den büyük bir offset n belirtildiğinde, ifadenin değerlendirmesi geçerli satırdan n satır daha aşağı taşınır.
Offset 0 olarak belirtildiğinde, ifade geçerli satır üzerinde değerlendirilir.
Negatif offset sayısı belirtilmesi, Below fonksiyonunun karşılık gelen pozitif offset sayısı ile Above fonksiyonu gibi çalışmasını sağlar. |
| count | 1'den büyük üçüncü bir count parametre belirtildiğinde, fonksiyon ilk hücreden aşağı doğru sayarak her count tablo satırı için bir adet olmak üzere bir count değerleri aralığı döndürür. Bu biçimde, fonksiyon herhangi bir özel aralık fonksiyonuna yönelik bir bağımsız değişken olarak kullanılabilir. [Aralık fonksiyonları](https://help.qlik.com/tr-TR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/RangeFunctionsInCharts.htm) |
| TOTAL | Tablo tek boyutluysa veya TOTAL niteleyicisi bir bağımsız değişken olarak kullanılıyorsa, geçerli sütun segmenti her zaman sütunun tamamına eşittir.
[Toplama kapsamını tanımlama](https://help.qlik.com/tr-TR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |
Bir sütun segmentinin son satırında, bunun altında bir satır olmadığından, NULL değeri döndürülür.
Bilgi notuSütun segmenti, geçerli sıralama düzeninde boyutlar için aynı değerlere sahip olan ardışık hücreler kümesi olarak tanımlanır. Kayıtlar arası grafik fonksiyonları, eşdeğer düz tablo grafiğinde en sağdaki boyut hariç tutularak sütun segmentinde hesaplanır. Grafikte yalnızca bir boyut varsa veya TOTAL niteleyicisi belirtilirse, ifade tüm tablo genelinde değerlendirilir.
Bilgi notuTablo veya tablo eşdeğeri birden çok dikey boyuta sahipse, geçerli sütun segmenti, alanlar arası sıralama düzenindeki son boyutu gösteren sütun haricinde tüm boyut sütunlarında geçerli satır olarak yalnızca aynı değerlere sahip satırları içerir.
Sınırlamalar:
* Yinelemeli çağrılar NULL sonucunu döndürür.
* Grafiğin ifadelerinden herhangi birinde bu grafik fonksiyonu kullanıldığında grafiklerde y değerlerine veya tablolarda ifade sütunlarına göre sıralamaya izin verilmez. Bu nedenle, söz konusu sıralama alternatifleri otomatik olarak devre dışı bırakılır. Bir görselleştirmede veya tabloda bu grafik fonksiyonunu kullandığınızda, görselleştirmenin sıralaması bu fonksiyonun sıralanmış girdisine geri döner.
Örnek: Grafik ifadeleri
| Örnek | Sonuç |
| --- | --- |
| `Below( Sum(Sales) )` | Geçerli satırın altındaki satır için `Sales` değerini döndürür. |
## Örnek - Below temel bilgileri
[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Grafik ifadesi
Genel bakış
Veri yükleme düzenleyicisini açın ve aşağıdaki komut dosyasını yeni bir bölüme ekleyin.
Komut dosyası şunları içerir:
* `Example` adlı veri tablosuna yüklenen bir veri kümesi.
* Veri tablosundaki şu alanlar:
* `Year`
* `Sales`
Komut dosyası
```
Example:
LOAD * INLINE [
Year, Sales
2019, 1000
2020, 1500
2021, 1200
2022, 1800
2023, 1700
];
```
Sonuçlar
Verileri yükleyin ve bir sayfa açın. Yeni bir tablo oluşturun ve şu alanı boyut olarak ekleyin:
* `Year`
Aşağıdaki hesaplamaları oluşturun:
* `=Sum(Sales)`, yıllık satışları bulmak için.
* `=Below(Sum(Sales))`, bir sonraki yılın satış değerini bulmak için.
* `=Sum(Sales) - Below(Sum(Sales))`, cari yılın `Sales` değeri ile bir sonraki yılın değeri arasındaki farkı hesaplamak için.
* `=RangeSum(Below(Sales, 1, 2))`, sonraki iki yıllık satışların iki yıllık toplamını göstermek için.
* `=(Sales - Below(Sales)) / Below(Sales)`, `Sales` içindeki değişikliği bir oran/yüzde olarak döndürmek için. Bu değeri yüzde olarak göstermek için Sayı biçimlendirme altında, Sayı > Basit Biçimlendirme > %12,34 öğesini seçin.
Sonuçlar tablosu
| Year | Sum(Sales) | Below(Sum(Sales)) | Sum(Sales) - Below(Sum(Sales)) | RangeSum(Below(Sales, 1, 2) | (Sales - Below(Sales)) / Below(Sales) |
| --- | --- | --- | --- | --- | --- |
| Totals | 7200 | - | - | 0 | - |
| 2019 | 1000 | 1500 | -500 | 2700 | -33.33% |
| 2020 | 1500 | 1200 | 300 | 3000 | 25.00% |
| 2021 | 1200 | 1800 | -600 | 3500 | -33.00% |
| 2022 | 1800 | 1700 | 100 | 1700 | 5.88% |
| 2023 | 1700 | - | - | 0 | - |
Sonuçlara bakarak, geçerli dönemdeki `Sales` değerlerini bir sonraki dönemle karşılaştırabilirsiniz.
* `Sum(Sales) - Below(Sum(Sales))` hesaplaması, geçerli dönemi sonraki dönemle karşılaştırarak `Sales` değerlerindeki farkı döndürür.
* `RangeSum(Below(Sales, 1, 2))` hesaplaması, sonraki iki `Sales` değerinin toplamını döndürür.
* `(Sales - Below(Sales)) / Below(Sales)` hesaplaması, sonraki döneme kıyasla `Sales` değerindeki değişikliği yüzde olarak döndürür.
İpucu notuBu fonksiyon tablolar dışında grafiklerde de (örneğin, sütun grafiklerinde) kullanılabilir.
Aşağıdakileri yapın:
Bir sütun grafik oluşturun ve bu alanı boyut olarak ekleyin:
* `Year`
Şu hesaplamayı oluşturun:
* `=Sum(Sales) - Below(Sum(Sales))`, yıldan yıla değişimi döndürmek için.
Below fonksiyonu için sonuçları gösteren sütun grafik
Below fonksiyonu için sonuçları gösteren sütun grafik
BelowBelow fonksiyonu için sonuçları gösteren sütun grafik 
Bir sütun grafikte `Below` fonksiyonunun kullanılması, cari dönem ile sonraki dönem satışları arasındaki farkın görsel olarak karşılaştırılmasını sağlar.
## Örnek - Below senaryosu
[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Grafik ifadesi
Genel bakış
Veri yükleme düzenleyicisini açın ve aşağıdaki komut dosyasını yeni bir bölüme ekleyin.
Komut dosyası şunları içerir:
* `Example` adlı veri tablosuna yüklenen bir veri kümesi.
* Veri tablosundaki şu alanlar:
* `SalesYear`
* `SalesAmount`
Komut dosyası
```
Example:
LOAD * INLINE [
SalesYear, SalesAmount
2019, 500
2020, 800
2021, 400
2022, 700
2023, 600
];
```
Sonuçlar
Verileri yükleyin ve bir sayfa açın. Yeni bir tablo oluşturun ve şu alanı boyut olarak ekleyin:
* `SalesYear`
Aşağıdaki hesaplamaları oluşturun:
* `=Sum(SalesAmount)`, satışları toplamak için.
* `=RangeSum(Below(SalesAmount, 0, NoOfRows() - RowNo()))`, `SalesAmount` değerlerinin özet bir toplamını hesaplamak için.
Sonuçlar tablosu
| SalesYear | Sum(SalesAmount) | RangeSum(Below(SalesAmount, 0, NoOfRows() - RowNo())) |
| --- | --- | --- |
| Totals | 3000 | 0 |
| 2019 | 500 | 2400 |
| 2020 | 800 | 1900 |
| 2021 | 400 | 1100 |
| 2022 | 700 | 700 |
| 2023 | 600 | 0 |
Sonuçlar, kümülatif bir özet toplamını oluşturmak için `RangeSum` fonksiyonu ile `Below` fonksiyonunun bir kombinasyonunu nasıl kullanabileceğinizi göstermektedir.
İpucu notuBu fonksiyon tablolar dışında grafiklerde de (örneğin, sütun grafiklerinde) kullanılabilir.
Aşağıdakileri yapın:
Bir sütun grafik oluşturun ve bu alanı boyut olarak ekleyin:
* `SalesYear`
Şu hesaplamayı oluşturun:
* `=RangeSum(Below(SalesAmount, 0, NoOfRows() - RowNo()))`, kümülatif özet satış değerini döndürmek için.
Yıllara göre kümülatif özet satış değerini gösteren sütun grafik
Yıllara göre kümülatif özet satış değerini gösteren sütun grafik
Yıllara göre kümülatif özet satış değerini gösteren sütun grafik 
`Below` fonksiyonunun bir çubuk grafikte `RangeSum` ile birlikte kullanılması, kümülatif özet satış değerlerinin görsel olarak görüntülenmesini sağlar.
## Örnek - Below kullanan grafik ifadesi
[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Grafik ifadesi
Genel bakış
Veri yükleme düzenleyicisini açın ve aşağıdaki komut dosyasını yeni bir bölüme ekleyin.
Komut dosyası şunları içerir:
* `Monthnames` ve `Sales2013` adlı iki veri tablosu.
Komut dosyası
```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];
Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');
```
Sonuçlar
Verileri yükleyin ve bir sayfa açın. Yeni bir tablo oluşturun ve şu alanı boyut olarak ekleyin:
* `Customer`
Aşağıdaki hesaplamaları oluşturun:
* `=Sum(Sales)`, satışların toplamını hesaplamak için.
* `=Below(Sum(Sales))`, bir önceki satırdaki satışların toplamını göstermek için.
* `=Sum(Sales)+Below(Sum(Sales))`, satış değerinin toplamını, geçerli satırın altındaki müşteri satırının satış değerinin toplamıyla toplamak için kullanılır.
* `=Sum(Sales)+Below(Sum(Sales), 3)`, geçerli `Customer` öğesinin `Sum(Sales)` değerini üç satır aşağıdaki `Customer` değeriyle toplamak için.
* `=If(Sum(Sales)>Below(Sum(Sales)), 'Higher')`, `Sum(Sales)` sonuçları aşağıdaki satırda bulunan müşterinin `Sum(Sales)` değerinden büyük olan müşterilere "`Higher`" etiketini eklemek için.
Sonuçlar tablosu
| Customer | Sum(Sales) | Below(Sum(Sales)) | Sum(Sales)+Below(Sum(Sales)) | Sum(Sales)+Below(Sum(Sales), 3) | If(Sum(Sales)>Below(Sum(Sales)), 'Higher') |
| --- | --- | --- | --- | --- | --- |
| Totals | 2566 | - | - | - | - |
| Astrida | 587 | 539 | 1126 | 1334 | Higher |
| Betacab | 539 | 683 | 1222 | - | - |
| Canutility | 683 | 757 | 1440 | - | - |
| Divadip | 757 | - | - | - | - |
Birden fazla boyutu olan grafikler için `Above`, `Below`, `Top` ve `Bottom` fonksiyonlarını içeren ifadelerin sonuçları, sütun boyutlarının Qlik Sense tarafından sıralanma düzenine göre değişir. Qlik Sense, en son sıralanan boyuttan kaynaklanan sütun segmentlerini temel alarak fonksiyonları değerlendirir. Sütun sıralama düzeni, Sıralama altındaki özellikler panelinde kontrol edilir ve sütunların tabloda göründüğü düzen olmayabilir. Sıralama düzeninin kullanımını gösteren bir örnek için bkz. [Örnek - Sıralama düzenine dayalı Above senaryosu](https://help.qlik.com/tr-TR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm#Example).
`Below(Sum(Sales))` hesaplaması, altında başka satır olmaması nedeniyle, `Divadip` müşterisi için NULL döndürür. `Canutility` satırı sonucu, `Divadip` için `Sum(Sales)` değerini gösterir. `Betacab` sonucu, `Canutility` için `Sum(Sales)` değerini gösterir ve bu böyle devam eder.
`Sum(Sales)+Below(Sum(Sales))` hesaplaması için `Astrida` satırı, `Betacab` + `Astrida` (`539+587`) satırları için `Sum(Sales)` değerlerinin eklenmesinin sonucunu döndürür. `Betacab` satırının sonucu, `Canutility` + `Betacab` için `Sum(Sales)` değerlerinin toplamından (`539+683`) elde edilen sonucu gösterir.
`Sum(Sales)+Below(Sum(Sales), 3)` hesaplaması, `offset` bağımsız değişkenine ( `3`olarak ayarlı) sahiptir ve satırdaki değeri geçerli satırdan üç satır aşağı taşıma etkisini oluşturur. Geçerli `Customer` öğesine ilişkin `Sum(Sales)` değerini üç satır aşağıdaki `Customer` öğesinden elde edilen değere ekler. En alt üç `Customer` satırı için döndürülen değerler null olur.
`IF(Sum(Sales)>Below(Sum(Sales)), 'Higher')` hesaplaması, `Astrida` müşterisi için `Higher` değerini döndürür çünkü bu müşterinin satış sonuçlarının aşağıdaki satırda yer alan `Betacab` müşterisinin satışlarının toplamından daha yüksektir.
İpucu notuBu fonksiyon tablolar dışında grafiklerde de (örneğin, sütun grafiklerinde) kullanılabilir.
İpucu notuDiğer grafik türleri için grafiği düz tablo eşdeğerine dönüştürerek fonksiyonun ilişkili olduğu satırı kolayca yorumlayabilirsiniz.
## Örnek - Below fonksiyonunu RangeAvg ile kullanma
[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Grafik ifadesi
Genel bakış
Below fonksiyonu, aralık fonksiyonları için giriş olarak kullanılabilir. Bu örnek, fonksiyonu bir RangeAvg içinde kullanır.
Veri yükleme düzenleyicisini açın ve aşağıdaki komut dosyasını yeni bir bölüme ekleyin.
Komut dosyası şunları içerir:
* Monthnames ve Sales2013 adlı iki veri tablosu.
Komut dosyası
```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];
Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');
```
Sonuçlar
Verileri yükleyin ve bir sayfa açın. Yeni bir tablo oluşturun ve şu alanı boyut olarak ekleyin:
* Customer
Şu hesaplamayı oluşturun:
* =RangeAvg (Below(Sum(Sales),1,3))
Sonuçlar tablosu
| Customer | RangeAvg (Below(Sum(Sales),1,3)) |
| --- | --- |
| Totals | - |
| Astrida | 660 |
| Betacab | 720 |
| Canutility | 757 |
| Divadip | - |
Below fonksiyonuna ait bağımsız değişkenlerde offset, 1 ve count, 3 olarak ayarlanır. Fonksiyon, sütun segmentinde geçerli satırın hemen altındaki üç satırda (satır varsa) Sum(Sales) ifadesinin sonuçlarını bulur. Bu üç değer, sağlanan sayı aralığındaki değerlerin ortalamasını bulan RangeAvg fonksiyonu için giriş olarak kullanılır.
## Daha fazla bilgi
* [Above - grafik fonksiyonu](https://help.qlik.com/tr-TR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)
* [Bottom - grafik fonksiyonu](https://help.qlik.com/tr-TR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
* [Top - grafik fonksiyonu](https://help.qlik.com/tr-TR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/top.htm)
* [RangeAvg Komut dosyası ve grafik fonksiyonu](https://help.qlik.com/tr-TR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/rangeavg.htm)