# Below - diagramfunktion
Below() utvärderar ett uttryck på en rad under den aktuella raden inom ett kolumnsegment i en tabell. Vilken rad som den beräknas för beror på värdet för offset, om sådant finns, standardvärdet är raden direkt nedanför. För diagram som inte är tabeller utvärderar Below() för raden nedanför den aktuella kolumnen i diagrammets raka tabellmotsvarighet.
Syntax:
Below([TOTAL] expr [ , offset [,count ]])
Returnerad datatyp: dual
Argument
| Argument | Beskrivning |
| --- | --- |
| expr | Det uttryck eller fält som innehåller de data som ska mätas. |
| offset | Om en offset n större än 1 anges, flyttas utvärderingen av uttrycket n antal rader nedanför den aktuella raden.
Om startpunkt anges till 0 utvärderas uttrycket på den aktuella raden.
Anges ett negativt värde för startpunkten gör det att Below-funktionen fungerar likadant som Above-funktionen med motsvarande positivt värde för startpunkten. |
| count | Om en tredje parameter, count, anges till större än 1, returnerar funktionen ett intervall av count-värden: ett för varje count-tabellrad. Raderna räknas nedåt från den ursprungliga cellen. I denna form kan funktionen användas som argument i någon av de speciella intervallfunktionerna. [Intervallfunktioner](https://help.qlik.com/sv-SE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/RangeFunctionsInCharts.htm) |
| TOTAL | Om tabellen är endimensionell eller om kvalificeraren iTOTAL används som argument, motsvarar det aktuella kolumnsegmentet alltid hela kolumnen.
[Definiera aggregeringens omfattning](https://help.qlik.com/sv-SE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |
På kolumnsegmentets sista rad returneras värdet NULL, eftersom det inte finns någon rad nedanför denna.
Anteckning om informationEtt kolumnsegment definieras som en konsekutiv underuppsättning med celler som har samma värden för dimensionerna i den aktuella sorteringsordningen. Postöverskridande diagramfunktioner beräknas i kolumnsegmentet exklusive dimensionen längst till höger i motsvarande raka tabelldiagram. Om det enbart finns en dimension i diagrammet, eller om kvalificeraren TOTAL anges, utvärderas uttrycket över en hel tabell.
Anteckning om informationOm tabellen eller diagrammets tabellmotsvarighet har flera vertikala dimensioner, inbegriper det aktuella kolumnsegmentet endast rader som har samma värden som den aktuella raden i samtliga dimensionskolumner, utom den kolumn som visar den sista dimensionen i fältens inbördes sorteringsordning.
Begränsningar:
* Rekursiva anrop returnerar NULL.
* Sortering på y-värden i diagram, eller sortering efter uttryckskolumner i tabeller, är inte tillåtet när denna diagramfunktion används i något av diagrammets uttryck. Dessa sorteringsalternativ är därför automatiskt inaktiverade. När du använder den här diagramfunktion i en visualisering eller tabell kommer sorteringen av visualiseringen att återgå till den sorterade inmatningen av den här funktionen.
Exempel: diagramuttryck
| Exempel | Resultat |
| --- | --- |
| `Below( Sum(Sales) )` | Returnerar värdet på `Sales` för raden under den aktuella raden. |
## Exempel – grunderna i Below
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Diagramuttryck
Översikt
Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.
Laddningsskriptet innehåller:
* En datauppsättning som läses in i en datatabell som heter `Example`.
* Följande fält i datatabellen:
* `Year`
* `Sales`
Laddningsskript
```
Example:
LOAD * INLINE [
Year, Sales
2019, 1000
2020, 1500
2021, 1200
2022, 1800
2023, 1700
];
```
Resultat
Ladda data och öppna ett ark. Skapa en ny tabell och lägg till det här fältet som en dimension:
* `Year`
Skapa följande mått:
* `=Sum(Sales)`, för att få fram den årliga försäljningen.
* `=Below(Sum(Sales))`, för att få fram försäljningsvärdet för nästa år.
* `=Sum(Sales) - Below(Sum(Sales))`, för att beräkna variansen mellan värdet på `Sales` för innevarande år och värdet för nästa år.
* `=RangeSum(Below(Sales, 1, 2))`, för att visa en rullande tvåårig sammanställning av de kommande två årens försäljning.
* `=(Sales - Below(Sales)) / Below(Sales)`, för att ange förändringen i `Sales` som en kvot/procentandel. Om du vill visa värdet i procent väljer du Nummer > Enkel formatering > 12,34% under Nummerformatering.
Resultattabell
| Year | Sum(Sales) | Below(Sum(Sales)) | Sum(Sales) - Below(Sum(Sales)) | RangeSum(Below(Sales, 1, 2) | (Sales - Below(Sales)) / Below(Sales) |
| --- | --- | --- | --- | --- | --- |
| Totals | 7200 | - | - | 0 | - |
| 2019 | 1000 | 1500 | -500 | 2700 | -33.33% |
| 2020 | 1500 | 1200 | 300 | 3000 | 25.00% |
| 2021 | 1200 | 1800 | -600 | 3500 | -33.00% |
| 2022 | 1800 | 1700 | 100 | 1700 | 5.88% |
| 2023 | 1700 | - | - | 0 | - |
När du tittar på resultaten kan du jämföra `Sales`-värdena under den aktuella perioden med nästa period.
* Måttet `Sum(Sales) - Below(Sum(Sales))` ger förändringen i `Sales`-värdet vid en jämförelse av aktuell period med nästa.
* Måttet `RangeSum(Below(Sales, 1, 2))` ger summan av de två kommande `Sales` -värdena.
* Måtte `(Sales - Below(Sales)) / Below(Sales)` ger förändringen i `Sales` jämfört med nästa perioden i procent.
Anteckning om tipsFunktionen kan även användas i andra diagram, inte bara tabeller – exempelvis i stapeldiagram.
Gör följande:
Skapa ett stapeldiagram och lägg sedan till det här fältet som en dimension:
* `Year`
Skapa följande mått:
* `=Sum(Sales) - Below(Sum(Sales))`, för att ange variationen från år till år.
Stapeldiagram som visar resultaten för funktionen Below
Stapeldiagram som visar resultaten för funktionen Below
Stapeldiagram som visar resultaten för funktionen BelowBelow 
Om du använder funktionen `Below` i ett stapeldiagram får du en visuell jämförelse av variansen mellan försäljningen under den aktuella perioden och försäljningen under nästa period.
## Exempel – Below-scenario
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Diagramuttryck
Översikt
Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.
Laddningsskriptet innehåller:
* En datauppsättning som läses in i en datatabell som heter `Example`.
* Följande fält i datatabellen:
* `SalesYear`
* `SalesAmount`
Laddningsskript
```
Example:
LOAD * INLINE [
SalesYear, SalesAmount
2019, 500
2020, 800
2021, 400
2022, 700
2023, 600
];
```
Resultat
Ladda data och öppna ett ark. Skapa en ny tabell och lägg till det här fältet som en dimension:
* `SalesYear`
Skapa följande mått:
* `=Sum(SalesAmount)`, för att sammanställa försäljningen.
* `=RangeSum(Below(SalesAmount, 0, NoOfRows() - RowNo()))`, för att beräkna en löpande summa av `SalesAmount`-värdena.
Resultattabell
| SalesYear | Sum(SalesAmount) | RangeSum(Below(SalesAmount, 0, NoOfRows() - RowNo())) |
| --- | --- | --- |
| Totals | 3000 | 0 |
| 2019 | 500 | 2400 |
| 2020 | 800 | 1900 |
| 2021 | 400 | 1100 |
| 2022 | 700 | 700 |
| 2023 | 600 | 0 |
Resultaten visar hur du kan använda kombinationen av funktionerna `RangeSum` och `Below` för att skapa en kumulativ löpande total.
Anteckning om tipsFunktionen kan även användas i andra diagram, inte bara tabeller – exempelvis i stapeldiagram.
Gör följande:
Skapa ett stapeldiagram och lägg sedan till det här fältet som en dimension:
* `SalesYear`
Skapa följande mått:
* `=RangeSum(Below(SalesAmount, 0, NoOfRows() - RowNo()))`, för att ange det ackumulerade löpande försäljningsvärdet.
Stapeldiagram som visar det ackumulerade löpande försäljningsvärdet per år
Stapeldiagram som visar det ackumulerade löpande försäljningsvärdet per år
Stapeldiagram som visar det ackumulerade löpande försäljningsvärdet per år 
Genom att använda funktionen `Below` i kombination med `RangeSum` i ett stapeldiagram får man en visuell visning av de ackumulerade löpande försäljningsvärdena.
## Exempel – diagramuttryck som använder Below
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Diagramuttryck
Översikt
Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.
Laddningsskriptet innehåller:
* Två datatabeller som heter `Monthnames` och `Sales2013`.
Laddningsskript
```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];
Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');
```
Resultat
Ladda data och öppna ett ark. Skapa en ny tabell och lägg till det här fältet som en dimension:
* `Customer`
Skapa följande mått:
* `=Sum(Sales)`, för att beräkna summan av försäljningen.
* `=Below(Sum(Sales))`, för att visa summan av försäljningen under föregående rad.
* `=Sum(Sales)+Below(Sum(Sales))`, för att summera summan av försäljningsvärdet med summan av försäljningen för kundraden nedanför den aktuella raden.
* `=Sum(Sales)+Below(Sum(Sales), 3)`, för att summera `Sum(Sales)`-värdet för aktuell `Customer` till värdet för `Customer` som är tre rader längre ned.
* `=If(Sum(Sales)>Below(Sum(Sales)), 'Higher')`, att lägga till etiketten "`Higher`" till kunder vars `Sum(Sales)`-resultat är större än `Sum(Sales)` för kunden i raden nedanför.
Resultattabell
| Customer | Sum(Sales) | Below(Sum(Sales)) | Sum(Sales)+Below(Sum(Sales)) | Sum(Sales)+Below(Sum(Sales), 3) | If(Sum(Sales)>Below(Sum(Sales)), 'Higher') |
| --- | --- | --- | --- | --- | --- |
| Totals | 2566 | - | - | - | - |
| Astrida | 587 | 539 | 1126 | 1334 | Higher |
| Betacab | 539 | 683 | 1222 | - | - |
| Canutility | 683 | 757 | 1440 | - | - |
| Divadip | 757 | - | - | - | - |
Resultatet för uttryck som innehåller funktionerna `Above`, `Below`, `Top` och `Bottom` i diagram med flera dimensioner beror på i vilken ordning kolumndimensionerna sorteras av Qlik Sense. Qlik Sense evaluerar funktionerna baserat på de kolumnsegment som är resultatet från den dimension som kommer sist i sorteringsordningen. Sorteringsordningen för kolumner styrs från egenskapspanelen under Sortering. Den motsvarar inte nödvändigtvis den ordning i vilken kolumnerna visas i en tabell. Ett exempel på hur du använder sorteringsordning finns på [Exempel – Above-scenario baserat på sorteringsordning](https://help.qlik.com/sv-SE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm#Example).
Måttet `Below(Sum(Sales))` returnerar NULL för kunden `Divadip` eftersom det inte finns någon rad nedanför. Resultatet för raden `Canutility` visar värdet på `Sum(Sales)` för `Divadip`. Resultatet för `Betacab` visar värdet för `Sum(Sales)` för `Canutility`, och så vidare.
För måttet `Sum(Sales)+Below(Sum(Sales))` ger raden för `Astrida` resultatet av att lägga till värdena för `Sum(Sales)` för raderna `Betacab` + `Astrida` (`539+587`). Resultatet för raden `Betacab` visar resultatet då `Sum(Sales)`-värden har lagts till för `Canutility` + `Betacab` (`539+683`).
Måttet `Sum(Sales)+Below(Sum(Sales), 3)` har argumentet `offset`, angivet som `3` och har den effekten att värdet hämtas i raden tre rader nedanför den aktuella raden. Det lägger till `Sum(Sales)`-värdet för aktuell `Customer` på värdet från `Customer` tre rader längre ner. Värdena för de lägsta tre `Customer`-raderna är null.
Måttet `IF(Sum(Sales)>Below(Sum(Sales)), 'Higher')`, returnerar värdet `Higher` för kunden `Astrida` eftersom deras försäljningsresultat är högre än summan av försäljningen för kunden i raden nedanför `Betacab`.
Anteckning om tipsFunktionen kan även användas i andra diagram, inte bara tabeller – exempelvis i stapeldiagram.
Anteckning om tipsFör andra diagramtyper, ska du omvandla diagrammet till den raka tabellmotsvarigheten så att du enkelt kan tolka vilken rad funktionen är relaterad till.
## Exempel – Användning av funktionen Below med RangeAvg
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Diagramuttryck
Översikt
Funktionen Below kan användas som indata för intervallfunktionerna. I detta exempel används funktionen i en RangeAvg.
Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.
Laddningsskriptet innehåller:
* Två datatabeller som heter Monthnames och Sales2013.
Laddningsskript
```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];
Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');
```
Resultat
Ladda data och öppna ett ark. Skapa en ny tabell och lägg till det här fältet som en dimension:
* Customer
Skapa följande mått:
* =RangeAvg (Below(Sum(Sales),1,3))
Resultattabell
| Customer | RangeAvg (Below(Sum(Sales),1,3)) |
| --- | --- |
| Totals | - |
| Astrida | 660 |
| Betacab | 720 |
| Canutility | 757 |
| Divadip | - |
I argumenten för funktionen Below, är offset inställt på 1 och count är inställt på 3. Funktionen hittar resultatet för uttrycket Sum(Sales) på de tre raderna som är precis nedanför aktuell rad i kolumnsegmentet (där det finns en rad). De här tre värdena används som indata för funktionen RangeAvg som räknar ut medelvärdet för ett angivet talintervall.
## Mer information
* [Above - diagramfunktion](https://help.qlik.com/sv-SE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)
* [Bottom - diagramfunktion](https://help.qlik.com/sv-SE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
* [Top - diagramfunktion](https://help.qlik.com/sv-SE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/top.htm)
* [RangeAvg – Skript- och diagramfunktion](https://help.qlik.com/sv-SE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/rangeavg.htm)