# Set-modifierare med set-operatorer

Set-operatorer används till att inkludera, utesluta eller genomskära olika elementuppsättningar. De kombinerar de olika metoderna för att definiera elementuppsättningar.

Operatorer är samma som de som används för set-identifierare.

Operatorer

| Operator | Beskrivning |
| --- | --- |
| `+` | Union. Denna binära operation returnerar en uppsättning som består av de poster eller element som tillhör någon av de två set-operanderna. |
| `-` | Exklusion. Denna binära operation returnerar en uppsättning som består av de poster eller element som enbart tillhör den första men inte den andra av de två set-operanderna. Den returnerar dessutom det komplementära setet när det används som en unär operator. |
| `*` | Intersektion. Denna binära operation returnerar en uppsättning som består av de poster eller element som tillhör båda set-operanderna. |
| `/` | Symmetrisk skillnad `(XOR)`. Denna binära operation returnerar en uppsättning som består av de poster eller element som tillhör endera men inte båda set-operanderna. |

Till exempel kan de följande två modifierarna definiera samma uppsättning med fältvärden:

* `<Year = {1997, "20*"}>`

* `<Year = {1997} + {"20*"}>`

Båda uttrycken väljer `1997` och åren som börjar med `20`. Med andra ord är det här unionen av de två villkoren.

Set-operatorer möjliggör även mer komplicerade definitioner. Exempel:

`<Year = {1997, "20*"} - {2000}>`

Det här uttrycket kommer att välja samma år som de ovan, men dessutom utesluta år `2000`.

Mer information finns i [Set-operatorer](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-operators.htm).

## Exempel: diagramuttryck för set-modifierare med set-operatorer

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-set-operators.htm)

#### Exempel – diagramuttryck

Laddningsskript

Ladda följande data som en inline-laddning i Skriptredigeraren för att skapa diagramuttrycksexemplen nedan.

```
MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1];	
```

Mer information om hur du använder inline-laddningar finns i [Använda inline-laddningar för att ladda data](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm).

Diagramuttryck

Skapa en tabell i ett Qlik Sense-ark med följande diagramuttryck.

Tabell – set-modifierare med set-operatorer

| Land | Sum(Amount) | Sum({&lt;Year={"&gt;2018"}-{2020}&gt;} Amount) | Sum({&lt;Country=-{Germany}&gt;} Amount) | Sum({&lt;Country={Germany}+P({&lt;Product={Nut}&gt;}Country)&gt;} Amount) |
| --- | --- | --- | --- | --- |
| Totalvärden | 41 | 9 | 28 | 17 |
| Kanada | 14 | 0 | 14 | 0 |
| Tjeckien | 10 | 9 | 10 | 0 |
| Frankrike | 4 | 0 | 4 | 4 |
| Tyskland | 13 | 0 | 0 | 13 |

Förklaring

* Dimensioner:

  * `Country`

* Mått:

  * `Sum(Amount)`

    Summa `Amount` utan set-uttryck.

  * `Sum({<Year={">2018"}-{2020}>}Amount)`

    Summan `Amount` för alla år efter `2018`, utom `2020`.

  * `Sum({<Country=-{Germany}>}Amount)`

    Summan `Amount` för alla länder utom `Germany`. Observera den unära exklusionsoperatorn.

  * `Sum({<Country={Germany}+P({<Product={Nut}>}Country)>}Amount)`

    Summan `Amount` för `Germany` och alla länder som är kopplade till produkten `Nut`.

Set-modifierare med set-operatorer

Set-modifierare med set-operatorer

Set-modifierare med set-operatorer ![Set-modifierare med set-operatorer.](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_set_operators.png)

Mer information om uttryck finns i [Använda uttryck i visualiseringar](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/use-expressions-in-visualizations.htm).

| Exempel | Resultat |
| --- | --- |
| sum( {$&lt;Product = Product + {OurProduct1} – {OurProduct2} &gt;} Sales ) | Returnerar försäljningen för det aktuella valet, men med produkten ”OurProduct1” tillagd i listan över valda produkter och ”OurProduct2” borttagen från densamma. |
| sum( {$&lt;Year = Year + ({“20\*”,1997} – {2000}) &gt;} Sales ) | Returnerar försäljningen för det aktuella valet, men med ytterligare val i fältet ”Year”: 1997 och alla som börjar på ”20” – dock inte 2000.<br><br>Observera att om 2000 är inkluderat i det aktuella valet kommer det fortfarande att inkluderas efter modifieringen. |
| sum( {$&lt;Year = (Year + {“20\*”,1997}) – {2000} &gt;} Sales ) | Returnerar nästan det samma som ovan, men här utesluts 2000, även om det från början ingår i det aktuella urvalet. Detta exempel visar vikten av att ibland använda parenteser för att definiera prioritetsordning. |
| sum( {$&lt;Year = {“\*”} – {2000}, Product = {“\*bearing\*”} &gt;} Sales ) | Returnerar försäljningen för det aktuella urvalet men med ett nytt urval i 'Year': alla år utom 2000; och endast för produkter som innehåller strängen 'bearing'. |