# Bottom - diagramfunktion
Bottom() utvärderar ett uttryck på den sista (nedersta) raden i ett kolumnsegment i en tabell. Vilken rad som den beräknas för beror på värdet för offset, om sådant finns, standardvärdet är raden nederst. För diagram som inte är tabeller görs utvärderingen på den sista raden i den aktuella kolumnen i diagrammets raka tabellmotsvarighet.
Syntax:
Bottom([TOTAL] expr [ , offset [,count ]])
Returnerad datatyp: dual
Argument
| Argument | Beskrivning |
| --- | --- |
| expr | Det uttryck eller fält som innehåller de data som ska mätas. |
| offset | Om en offsetn större än 1 anges flyttas utvärderingen av uttrycket upp n antal rader ovanför den nedersta raden.
Anges ett negativt värde för startpunkten gör det att Bottom-funktionen fungerar likadant som Top-funktionen med motsvarande positivt värde för startpunkten. |
| count | Om en tredje parameter, count, anges till större än 1, returnerar funktionen inte bara ett värde, utan ett intervall av count-värden: ett för var och en av de sista count-raderna i det aktuella kolumnsegmentet. I denna form kan funktionen användas som argument i någon av de speciella intervallfunktionerna. [Intervallfunktioner](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/RangeFunctionsInCharts.htm) |
| TOTAL | Om tabellen är endimensionell eller om kvalificeraren iTOTAL används som argument, motsvarar det aktuella kolumnsegmentet alltid hela kolumnen.
[Definiera aggregeringens omfattning](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |
Anteckning om informationEtt kolumnsegment definieras som en konsekutiv underuppsättning med celler som har samma värden för dimensionerna i den aktuella sorteringsordningen. Postöverskridande diagramfunktioner beräknas i kolumnsegmentet exklusive dimensionen längst till höger i motsvarande raka tabelldiagram. Om det enbart finns en dimension i diagrammet, eller om kvalificeraren TOTAL anges, utvärderas uttrycket över en hel tabell.
Anteckning om informationOm tabellen eller diagrammets tabellmotsvarighet har flera vertikala dimensioner, inbegriper det aktuella kolumnsegmentet endast rader som har samma värden som den aktuella raden i samtliga dimensionskolumner, utom den kolumn som visar den sista dimensionen i fältens inbördes sorteringsordning.
Begränsningar:
* Rekursiva anrop returnerar NULL.
* Sortering på y-värden i diagram, eller sortering efter uttryckskolumner i tabeller, är inte tillåtet när denna diagramfunktion används i något av diagrammets uttryck. Dessa sorteringsalternativ är därför automatiskt inaktiverade. När du använder den här diagramfunktion i en visualisering eller tabell kommer sorteringen av visualiseringen att återgå till den sorterade inmatningen av den här funktionen.
Exempel: diagramuttryck
| Exempel | Resultat |
| --- | --- |
| `Bottom( Sum(Sales) )` | Returnerar värdet på `Sales` för den sista (nedre) raden i ett kolumnsegment i en tabell. |
## Exempel – grunderna i Bottom
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
#### Diagramuttryck
Översikt
Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.
Laddningsskriptet innehåller:
* En datauppsättning som läses in i en datatabell som heter `Example`.
* Följande fält i datatabellen:
* `Year`
* `Sales`
Laddningsskript
```
Example:
LOAD * INLINE [
Year, Sales
2019, 1000
2020, 1500
2021, 1200
2022, 1800
2023, 1700
];
```
Resultat
Ladda data och öppna ett ark. Skapa en ny tabell och lägg till det här fältet som en dimension:
* `Year`
Skapa följande mått:
* `=Sum(Sales)`, för att få fram den årliga försäljningen.
* `=Bottom(Sum(Sales))`, för att få fram försäljningsvärdet för förra året.
* `=Sum(Sales) - Bottom(Sum(Sales))`, för att beräkna variansen mellan värdet på `Sales` för innevarande år och värdet för förra året.
* `=Sum(Sales)+Bottom(Sum(Sales), 3)`, för att beräkna försäljningsvärdet för innevarande år och värdet för det tredje senaste året.
* `=(Sales - Bottom(Sales)) / Bottom(Sales)`, för att ange förändringen i `Sales` som en kvot/procentandel jämfört med förra året. Om du vill visa värdet i procent väljer du Nummer > Enkel formatering > 12,34% under Nummerformatering.
Sortera tabellen efter dimensionen `Year` i stigande ordning.
Resultattabell
| Year | Sum(Sales) | Bottom(Sum(Sales)) | Sum(Sales) - Bottom(Sum(Sales)) | Sum(Sales)+Bottom(Sum(Sales), 3) | (Sales - Bottom(Sales)) / Bottom(Sales) |
| --- | --- | --- | --- | --- | --- |
| Totals | 7200 | 1700 | 5500 | 8400 | - |
| 2019 | 1000 | 1700 | -700 | 2200 | -41.18% |
| 2020 | 1500 | 1700 | -200 | 2700 | -11.76% |
| 2021 | 1200 | 1700 | -500 | 2400 | -29.41% |
| 2022 | 1800 | 1700 | 100 | 3000 | 5.88% |
| 2023 | 1700 | 1700 | 0 | 2900 | 0.00% |
När du tittar på resultaten kan du jämföra `Sales`-värdena under den aktuella perioden med den sista eller senaste perioden.
* Måttet `Sum(Sales) - Bottom(Sum(Sales))` ger förändringen i `Sales`-värdet vid en jämförelse av aktuell period med den senaste.
* Måttet `Sum(Sales)+Bottom(Sum(Sales), 3)` visar summan av `Sales` för den aktuella raden och den tredje senaste perioden.
* Måtte `(Sales - Bottom(Sales)) / Bottom(Sales)` ger förändringen i `Sales` jämfört med den senaste perioden i procent.
Anteckning om tipsFunktionen kan även användas i andra diagram, inte bara tabeller – exempelvis i stapeldiagram.
Gör följande:
Skapa ett stapeldiagram och lägg sedan till det här fältet som en dimension:
* `Year`
Skapa följande mått:
* `=Sum(Sales) - Bottom(Sum(Sales))`för att returnera variansen i försäljning mellan den aktuella perioden och den senaste perioden.
Stapeldiagram som visar resultaten för funktionen Bottom
Stapeldiagram som visar resultaten för funktionen Bottom
Stapeldiagram som visar resultaten för funktionen BottomBottom 
Om du använder funktionen `Bottom` i ett stapeldiagram får du en visuell jämförelse av variansen mellan försäljningen under den aktuella perioden och försäljningen under den senaste perioden.
## Exempel – Bottom-scenario
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
#### Diagramuttryck
Översikt
Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.
Laddningsskriptet innehåller:
* En datauppsättning som läses in i en datatabell som heter `Example`.
* Följande fält i datatabellen:
* `OrderID`
* `Product`
* `SalesValue`
* `OrderDate`
Laddningsskript
```
Example:
LOAD * INLINE [
OrderID, Product, SalesValue, OrderDate
1, "Product A", 500, '2023-01-10'
2, "Product B", 300, '2023-01-15'
3, "Product C", 450, '2023-02-01'
4, "Product D", 700, '2023-02-20'
5, "Product E", 350, '2023-03-05'
];
```
Resultat
Ladda data och öppna ett ark. Skapa en ny tabell och lägg till det här fältet som en dimension:
* `Product`
Skapa följande mått:
* `=RangeAvg (Bottom(Sum(SalesValue),1,3))`, för att returnera genomsnittet av de 3 senaste raderna.
* `=Sum(SalesValue) - RangeAvg (Bottom(Sum(SalesValue),1,3))`, för att beräkna variansen mellan den aktuella raden och genomsnittet av de 3 senaste raderna.
* `=Sum(SalesValue)`, för att beräkna totalt `SalesValue` för den aktuella raden.
Resultattabell
| Product | RangeAvg (Bottom(Sum(SalesValue),1,3)) | Sum(SalesValue) - RangeAvg (Bottom(Sum(SalesValue),1,3)) | Sum(SalesValue) |
| --- | --- | --- | --- |
| Totals | 500 | 1800 | 2300 |
| 2019 | 500 | 0 | 500 |
| 2020 | 500 | -200 | 300 |
| 2021 | 500 | -50 | 450 |
| 2022 | 500 | 200 | 700 |
| 2023 | 500 | -150 | 350 |
Resultaten visar hur du kan använda kombinationen av funktionerna `RangeSum` och `Bottom` för att analysera och jämföra försäljningsvärden.
## Exempel – diagramuttryck som använder Bottom
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
#### Diagramuttryck
Översikt
Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.
Laddningsskriptet innehåller:
* Två datatabeller som heter `Monthnames` och `Sales2013`.
Laddningsskript
```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];
Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');
```
Resultat
Ladda data och öppna ett ark. Skapa en ny tabell och lägg till det här fältet som en dimension:
* `Customer`
Skapa följande mått:
* `=Sum(Sales)`, för att beräkna summan av försäljningen.
* `=Bottom(Sum(Sales))`, för att visa summan av försäljningen för `Customer` på nedersta raden.
* `=Sum(Sales)+Bottom(Sum(Sales))`, för att lägga till `Sum(Sales)`-värdet av aktuell `Customer` med `Customer` i den nedersta raden.
* `=Sum(Sales)+Bottom(Sum(Sales), 3)`, för att lägga till `Sum(Sales)`-värdet av aktuell `Customer` med `Customer` i tredje raden nedifrån.
Resultattabell
| Customer | Sum(Sales) | Bottom(Sum(Sales)) | Sum(Sales)+Bottom(Sum(Sales)) | Sum(Sales)+Bottom(Sum(Sales), 3) |
| --- | --- | --- | --- | --- |
| Totals | 2566 | 757 | 3323 | 3105 |
| Astrida | 587 | 757 | 1344 | 1126 |
| Betacab | 539 | 757 | 1296 | 1078 |
| Canutilty | 683 | 757 | 1440 | 1222 |
| Divadip | 757 | 757 | 1514 | 1296 |
Måttet `Bottom(Sum(Sales))` returnerar `757` för alla rader eftersom det är värdet för den nedersta raden: `Divadip`.
För måttet `Sum(Sales)+Bottom(Sum(Sales))`, ger raden `Astrida` `1344`, vilket är resultatet av att lägga till `Sum(Sales)`-värdet för `Astrida` och `Divadip`, som är `Customer` i nedersta raden.
För måttet `Sum(Sales)+Bottom(Sum(Sales), 3)` är argumentet `offset` inställt på `3`. Uttrycket lägger till värdet `Sum(Sales)` för den aktuella raden och den tredje raden nedifrån, `Betacab`. Till exempel returneras värdet `1126` för kunden `Astrida`. Detta är resultatet av att lägga till värdet `Sum(Sales)` för `Astrida` och värdet `SumSales` för `Betacab` (`587`+`539`).
## Mer information
* [Top - diagramfunktion](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/top.htm)