# Min - diagramfunktion
Min() finner det lägsta värdet för aggregerade data. Genom att ange en rank n återfinns det n:te lägsta värdet.
Anteckning om tipsTitta gärna på FirstSortedValue och RangeMin, som har liknande funktionalitet som Min-funktionen.
Syntax:
Min({[SetExpression] [TOTAL [<fld {,fld}>]]} expr [,rank])
Returnerad datatyp: numeriska
Argument
| Argument | Beskrivning |
| --- | --- |
| expr | Det uttryck eller fält som innehåller de data som ska mätas. |
| rank | Standardvärdet för rank är 1, vilket motsvarar det lägsta värdet. Om du anger rank som 2, returneras det näst lägsta värdet. Om rank är 3, returneras det tredje lägsta värdet och så vidare. |
| SetExpression | Som standard kommer aggregeringsfunktionen att aggregera över den uppsättning möjliga poster som definierats av urvalet. En alternativ uppsättning poster kan definieras med ett uttryck för set-analys. |
| TOTAL | Om ordet TOTAL står före funktionsargumenten görs beräkningen över alla valbara värden givet de aktuella valen, och inte bara sådana som rör det aktuella dimensionsvärdet, det vill säga att diagramdimensionerna ignoreras. Genom att använda TOTAL [<fld {.fld}>], där kvalificeraren TOTAL följs av en lista med ett eller flera fältnamn som en delmängd av diagramdimensionens variabler, skapar du en delmängd av de totala möjliga värdena.
[Definiera aggregeringens omfattning](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |
Exempel: diagramuttryck
| Exempel | Resultat |
| --- | --- |
| `Min(UnitSales)` | Returnerar det lägsta null-värdet i fältet `UnitSales`. |
| `Min(UnitSales*UnitPrice)` Värdet för en order beräknas utifrån multiplicering av antal sålda enheter i (`UnitSales`) med priset per enhet. | Returnerar det lägsta nullvärdet som blir resultatet av att beräkna alla möjliga värden av (`UnitSales`)\*(`UnitPrice`). |
| `Min(UnitSales, 2)` | Returnerar det näst lägsta värdet i `UnitSales` (efter NULL-värdena). |
| `Min(TOTAL UnitSales)` | `TOTAL`-kvalificeraren innebär att det lägsta möjliga värdet hittas, oavsett diagramdimensionerna. För ett diagram med `Customer` som dimension säkerställer kvalificeraren `TOTAL` det minsta värdet över den fullständiga datauppsättningen returneras, i stället för minsta `UnitSales` för varje kund. |
| `Min({1} TOTAL UnitSales)` | Det fasta analysuttrycket `{1}` definierar den uppsättning poster som ska utvärderas som `ALL`, oavsett vilket urval som har gjorts. Om t.ex. en specifik kund väljs kommer den fortfarande att returnera minimi av `UnitSales` över hela datauppsättningen. |
## Exempel – grunderna i Min
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/min.htm)
#### Diagramuttryck
Översikt
Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.
Laddningsskriptet innehåller:
* En datauppsättning som läses in i en datatabell som heter `Example`.
* Följande fält i datatabellen:
* `Customer`
* `UnitSales`
* `UnitPrice`
Laddningsskript
```
Example:
LOAD * inline [
Customer|UnitSales|UnitPrice
Astrida|4|16
Astrida|10|15
Astrida|9|9
Betacab|5|10
Betacab|2|20
Betacab||25
Canutility|8|15
Canutility||19
] (delimiter is '|');
```
Resultat
Ladda data och öppna ett ark. Skapa en ny tabell och lägg till det här fältet som en dimension:
* `Customer`
Skapa följande mått:
* `=Min(UnitSales)`, för att beräkna det minimala värdet för `UnitSales`.
* `=Min(UnitSales*UnitPrice)`, för att beräkna det minimala värdet efter att ha multiplicerat `UnitSales` med `UnitPrice` rad för rad.
* `=Min(UnitSales, 2)`, för att beräkna det näst lägsta värdet.
* `=Min(TOTAL UnitSales)`, för att beräkna den lägsta summan oavsett diagramdimension.
* `=Min({1} TOTAL UnitSales)`, för att beräkna den lägsta summan som ignorerar alla val.
Results table
| Customer | Min(UnitSales) | Min(UnitSales\*UnitPrice) | Min(UnitSales, 2) | Min(TOTAL UnitSales) | Min({1} TOTAL UnitSales) |
| --- | --- | --- | --- | --- | --- |
| Totals | 2 | 40 | 4 | 2 | 2 |
| Astrida | 4 | 64 | 9 | 2 | 2 |
| Betacab | 2 | 40 | 5 | 2 | 2 |
| Canutility | 8 | 120 | - | 2 | 2 |
I detta exempel ska du observera följande:
* I det första mätvärdet (`Min(UnitSales)`) är det lägsta värdet för `UnitSales` för kunden `Astrida` `4` . Cellen `Totals` i den här kolumnen ger `2` eftersom det här värdet är det lägsta `UnitSales`-värdet i hela datauppsättningen.
* I det andra mätvärdet (`Min(UnitSales*UnitPrice)`) returneras `64` för `Astrida`. Detta är det lägsta värdet för den kunden när `UnitSales` multipliceras med `UnitPrice`. Cellen `Totals` för den här kolumnen returnerar `40` eftersom det även är det lägsta beräknade värdet i hela datauppsättningen.
* I det tredje mätvärdet (`Min(UnitSales, 2)`) är det näst lägsta värdet för `UnitSales` för kunden `Astrida` `9` . Värdet `4` returneras i raden `Totals`, eftersom det är det näst lägsta `UnitSales`-värdet för alla kunder.
* Det fjärde mätvärdet (`Min(TOTAL UnitSales)`) returnerar värdet `2`. Detta är det lägsta möjliga icke-null-värdet oberoende av kundens dimension, därför returnerar alla rader samma värde. Om du däremot väljer kunden `Betacab` kommer tabellen endast att returnera värden för den kunden, i det här fallet `2` eftersom det är lägst `UnitSales` bland alla produkter för `Betacab`.
* Det femte mätvärdet `Min({1} TOTAL UnitSales)`, returnerar `2` oavsett vilket värde som valts i fältet `Customer` eftersom åtgärden beräknar den lägsta totalsumman. Om du t.ex. väljer `Betacab` kommer denna kolumn att fortsätta att returnera värdet `2`.
## Exempel – Min-scenario som beräknar lägsta försäljning per månad
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/min.htm)
#### Diagramuttryck
Översikt
En datauppsättning innehåller försäljningssiffror för produkter per månad. En försäljningschef vill identifiera det lägsta försäljningsvärdet för varje produkt och den månad då detta inträffade.
Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.
Laddningsskriptet innehåller:
* En datauppsättning som läses in i en datatabell som heter `Example`.
* Följande fält i datatabellen:
* `Product`
* `Sales`
* `Month`
Laddningsskript
```
Example:
Load * inline [
Product,Sales,Month
A, 500, 2024-01-01
A, 700, 2024-02-01
A, 600, 2024-03-01
B, 300, 2024-01-01
B, 800, 2024-02-01
B, 450, 2024-03-01
C, 550, 2024-01-01
C, 620, 2024-02-01
C, 710, 2024-03-01
];
```
Resultat
Ladda data och öppna ett ark. Skapa en ny tabell och lägg till dessa fält som dimensioner:
* `Product`
* `Month`
Skapa följande mått:
* `=If(Sales = Min(TOTAL Sales), Sales)`, för att beräkna den minimala försäljningen för varje produkt. I egenskapspanelen väljer du Tillägg > Datahantering. Rensa kryssrutan Inkludera nollvärden.
Results table
| Product | Month | If(Sales = Min(TOTAL <Product> Sales), Sales) |
| --- | --- | --- |
| A | 2024-01-01 | 500 |
| B | 2024-01-01 | 300 |
| C | 2024-01-01 | 550 |
Resultatet av mätningen ger det minimala försäljningsvärdet för varje produkt och den månad då detta värde uppnåddes. Till exempel hade ` Product B ` den lägsta försäljningen (`300`) i `2024-01-01`.
## Mer information
* [FirstSortedValue - diagramfunktion](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/firstsortedvalue.htm)
* [RangeMin Skript- och diagramfunktion](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/rangemin.htm)
* [Set-analys](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-analysis-expressions.htm)
* [Definiera aggregeringens omfattning](https://help.qlik.com/sv-SE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm)