# Använda inline-laddningar för att ladda data

Skriv in data manuellt i ett skript för att definiera en inline-tabell, som kan laddas till en app. Du kan arbeta med inline-laddningar i Skriptredigeraren.

Du skapar inline-tabeller genom att skriva in data manuellt i skriptet snarare än genom att koppla till filer och databaser. Använd den nödvändiga syntaxen för att ange att skripttexten ska tolkas som inline-data. Data som lagts till med inline-laddningar kommer att finnas i appen om appen exporteras. Inline-tabeller är läsbara och redigerbara i laddningsskriptet.

En grundläggande inline-laddning skapar en tabell och infogar datafälten och posterna.

Inline-laddning i Skriptredigeraren

Inline-laddning i Skriptredigeraren

Inline-laddning i Skriptredigeraren ![Inline-laddning i Skriptredigeraren.](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Resources/Images/ui_gen_inline_load_client-managed-rev.png)

## Grundläggande syntaxexempel

Följande skript innehåller en enkel inline-laddning.

```
MyTable:
Load * Inline [
Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
];
```

Följande syntax används för inline load ovan:

* Load \* Inline instruerar Qlik Sense att ladda alla fält från följande inline-tabell.

* MyTable: definierar namnet på tabellen. Listan över tabeller i appen kan nås via Datamodellvyn och andra områden.

* Hakparenteser omger data.

* Datafält definieras på LOAD-satsens första rad.

* Kommaseparerade datafält och poster.

* Ett semikolon avslutar load-satsen.

## Ladda en inline-tabell

Gör följande:

1. I en app öppnar du Skriptredigeraren.

2. I en ny rad definierar du tabellen med den syntax som krävs.

   [Grundläggande syntaxexempel](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#BasicSyntax)

3. När du är klar klickar du på Ladda data.

## Varför använda inline-laddningar?

Inline-laddningar kan vara användbara i ett antal olika användningsfall:

* Administrera och redigera data utan att behöva ansluta till externa källor.

* Komplettera befintliga data i datamodellen. Du kan exempelvis lägga till en extra tabell i en datamodell som huvudsakligen kommer från databaskällor.

* Lägga till data som du vill undvika att ladda kontinuerligt från externa källor. Detta kan spara tid om du vet att datakällan kan ändras i framtiden, men datavärdena förblir identiska.

* Enkel användning för att kopiera och klistra in innehåll i skriptet från andra filer. Exempelvis .csv-filer eller tabeller från ordbehandlingsdokument.

* Skapa testskript som inte kan kopieras och klistras in snabbt.

## Översikt över syntax

### Ge tabellen ett namn

Du kan lägga till ett namn i inline-tabellen på samma sätt som för andra laddade tabeller. Det är valfritt att definiera tabellnamnet.

Efter namnet på tabellen infogar du ett kolon.

### LOAD- och inline-satser

En inline-tabell laddas med inline-satsen när du använder LOAD-skriptsatsen. inline-satsen anger att den efterföljande texten i tabellen innehåller data som skrivs in i redigeraren manuellt. Om du inte anger något annat använder en inline-tabell txt-formatet, som följer strukturen för en avgränsad textfil.

Mer information om att använda LOAD -satser finns i [Ladda](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/Load.htm).

### Omslutningar och datainmatning

Data som matas in med en inline-sats måste inledas och avslutas med specifika tecken. Här följer godkända teckenkombinationer för att omsluta data:

* Hakparenteser: `[` och `]`

* Dubbla citattecken: `"` och `"`

* Enkla citattecken: `'` och `'`

* Backticks: `` ` `` och `` ` ``

Det tecken som du väljer för omslutning kan vara till hjälp med att ladda inline-data som innehåller tecken som står i konflikt med varandra. Om dina data exempelvis innehåller poster med hakparenteser kan du omsluta dem med citattecken eller backticks i stället.

Ett exempel på alternativa omslutningar finns i [Exempel - Alternativa dataomslutningar](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#ExDataEnc).

Såvida du inte anger ett alternativt tabellformat (txt är standard) tolkas text mellan omslutningarna på samma sätt som innehållet i en fil. Precis som du infogar en ny rad i en textfil bör du göra det även i texten i en inline-sats. Klicka på vanligt sätt på returtangenten när du skriver skriptet.

### Avsluta inline-laddningen

Slutet på inline-load-satsen anges med ett semikolon.

### Dataomvandlingar

I en enkel inline-laddning utan omvandlingar definieras antalet kolumner av den första raden. Det finns tre kolumner i tabellen som laddas med följande exempel: `Product_ID`, `Supplier_Name` och `Product_Category`.

```
Products:

Load * Inline [
Product_ID, Supplier_Name, Product_Category
1, Paracel, Home Decor
2, PageWave, Electronics
3, Talarian, Software
4, Userland, Appliances
];
```

Du kan också utföra omvandlingar och skapa nya kolumner i samma inline-tabell. Du kan använda föregående loads och fler än en LOAD-sats kan användas för att ladda samma tabell.

Specifika exempel finns i [Exempel - Inline-laddningar med omvandlingar](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#ExTransform):

### Konfigurera formatspecifikationen i en inline-laddning

I likhet med andra laddade tabeller kan du modifiera formatspecifikationen i inline-tabellen med element för formatspecifikation. Formatspecifikationen läggs till i parenteser. Den ska läggas till efter dataomslutningarna, men före semikolonet som avslutar LOAD-satsen. Bland de anpassningar du kan lägga till finns:

* Ändra avgränsaren från ett komma till ett annat tecken. Se [Exempel - Alternativa avgränsare](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#ExDelimiter) för exempel.

  Se: [Delimiter is](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptSpecifiers/delimiter.htm)

* Utelämna kolumnrubriker. Exempel finns i [Exempel - Utelämna kolumnrubriker](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#ExOmitLabels).

  Se: [Labels](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptSpecifiers/labels.htm)

* Använda ett annat dataformat (exempelvis fast postformat). Exempel finns i [Exempel - Ladda en annan datatyp](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#ExChangeFormat).

  Se: [Table format](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptSpecifiers/table-format.htm)

  Anteckning om informationDet finns inte stöd för alla alternativ iTable format för inline-laddningar.

* Tillåta innehåll med flera rader. Exempel finns i [Exempel - Innehåll på flera rader](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#ExMultLine).

  Se: [Quotes](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptSpecifiers/quotes.htm)

För att använda flera formatspecifikationer i samma tabell separerar du dem med kommatecken. Exempel:`  (Delimiter is '|', no labels) `

Den fullständiga informationen om formatspecifikationen finns i [Formatspecificerare](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptSpecifiers/format-specification-items.htm).

### Operatorer och andra satser

Eftersom en inline-laddning är en LOAD-sats kan du dessutom kombinera andra argument för LOAD-satsen i inline-laddningen. Använd till exempel where- eller while-satsen för att definiera om en viss rad ska laddas eller inte, baserat på texten i den.

På samma sätt kan du också använda operatorer utanför själva textinnehållet. Med operatorer kan du anpassa hur du omvandlar inline-data och också definiera när vissa data ska laddas eller inte.

Ett specifikt exempel finns i [Exempel: Operatorer för omvandlingar och satser](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#ExOpsAndClauses).

## Exempel - Alternativa dataomslutningar

Du kan använda hakparenteser, citattecken eller backticks för att omsluta en inline-laddning. I det här avsnittet beskrivs detta med ett exempel. Mer information finns i [Omslutningar och datainmatning](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#Enclosure).

#### Laddningsskript och resultat

I det här exemplet beskrivs hur du kan använda backticks för att omsluta inline-data. Data i exemplet innehåller hakparentestecken, vilket gör hakparentestecken inkompatibla som omslutningar för LOAD-satsen.

Översikt

Öppna Skriptredigeraren och lägg till följande laddningsskript till ett nytt delavsnitt.

Laddningsskript

```
DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;
```

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till dessa fält som dimensioner:

* `custom_property`

* `date`

* `amount`

Resultattabell

| custom\_property | date | amount |
| --- | --- | --- |
| [11402] | 1/1/2024 | 92.99 |
| [11403] | 1/2/2024 | 102.34 |
| [11404] | 1/3/2024 | 50.26 |
| [11405] | 1/4/2024 | 153.69 |
| [11406] | 1/5/2024 | 75.62 |

## Exempel - Alternativa avgränsare

Du kan använda ett annat tecken än ett komma för att avgränsa kolumnvärden i tabellen. Mer information finns i [Konfigurera formatspecifikationen i en inline-laddning](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#FormatSpec).

#### Laddningsskript och resultat

Översikt

Att byta ut avgränsarna är användbart när data i tabellen innehåller komman, vilket annars signalerar bytet till nästa kolumn i tabellen.

Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.

Laddningsskriptet innehåller:

* Fyra tabeller ska laddas. De är följande:

  * Table1: ett vertikalt streck (pipe) är avgränsare. Data i Phrase-kolumnen innehåller komman.

  * Table2: ett kolon är avgränsare.

  * Table3: ett backstreck är avgränsare.

  * Table4: tabellen avgränsas genom att trycka på tabb-tangenten på tangentbordet. Det här alternativet är användbart när du kopierar en tabell från en ordbehandlare och klistrar in den i skriptet.

  I Table1 visas ett praktiskt användningsfall för att använda en alternativ avgränsare. I de andra alternativen visas fler alternativ för avgränsare.

Laddningsskript

```
Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');
```

Resultat

Ladda data och öppna ett ark. Skapa fyra tabeller och lägg till dimensioner i dem på följande sätt:

* Table1: ID, Phrase

* Table2: Num1, Chr1

* Table3: Num2, Chr2

* Table4: Num3, Chr3

Resultattabell: Table1Table1

| ID | Phrase |
| --- | --- |
| 1 | The transaction was complete, but the order has not yet shipped. |
| 2 | We need to confirm the following details: sales rep number, order status, and shipping priority. |

Resultattabell: Table2Table2

| Num1 | Chr1 |
| --- | --- |
| 1 | A |
| 2 | B |

Resultattabell: Table3Table3

| Num2 | Chr2 |
| --- | --- |
| 1 | A |
| 2 | B |

Resultattabell: Table4Table4

| Num3 | Chr3 |
| --- | --- |
| 1 | A |
| 2 | B |

## Exempel - Blanda inline-laddningar och laddningar från andra datakällor

#### Laddningsskript och resultat

Översikt

Det följande skriptet laddar först ett antal fält från en koppling och laddar sedan en inline-tabell med ett gemensamt fält och ytterligare ett fält. Detta nya fält ger en annan egenskap om det radobjekt som inte laddades via datakopplingen. Observera att detta bara fungerar smidigt när det finns ett enda gemensamt fältnamn mellan de två tabellerna. Om det finns mer än ett gemensamt fältnamn skapas en syntetisk nyckel.

I det här trunkerade exemplet laddar vi en tabell med orderdetaljer från en datakoppling. Sedan använder vi en inline-tabell för att lägga till ytterligare ett fält, Supplemental Info. Det kan t.ex. innehålla information om särskilda kommentarer om specifika order-ID:n.

Laddningsskript

```
SET DateFormat='MM/DD/YYYY';

Orders:

LIB CONNECT TO 'My_Generic_Connection';

LOAD PRODUCT_DIVISION_A_ORDER_ID as Order ID, 
PRODUCT_DIVISION_A_ORDER_DATE as ISSUE_KEY as Order Date, 
PRODUCT_DIVISION_A_TYPE as Product Type, 
PRODUCT_DIVISION_A_SALES_MANAGER as Manager,
PRODUCT_DIVISION_A_SHIPPED_STATUS as Shipped Status;

SELECT PRODUCT_DIVISION_A_ORDER_ID,
PRODUCT_DIVISION_A_ORDER_DATE,
PRODUCT_DIVISION_A_TYPE,
PRODUCT_DIVISION_A_SALES_MANAGER,
PRODUCT_DIVISION_A_SHIPPED_STATUS

FROM SourceTable
WITH PROPERTIES (

[...]

);

Orders_Inline_Info:
load * inline [
Order ID,Supplemental Info
PSF-001014,'Bulk order, pending deal with Paracel.'
PSF-001625,'NOTE: Product damaged. Investigation required.'
];
```

Resultat

När du har laddat data kan du till exempel lägga till följande dimensioner i en tabell:

* Order ID

* Order Date

* Product Type

* Manager

* Shipped Status

* Supplemental Info

Det resulterande diagrammet ska se ut så här.

Resultattabell: OrdersOrders

| Order ID | Order Date | Product Type | Manager | Shipped Status | Supplemental Info |
| --- | --- | --- | --- | --- | --- |
| PSF-000998 | 1/13/2024 | Electronics | Amanda Honda | Shipped | - |
| PSF-000999 | 1/15/2024 | Automotive | Molly McKenzie | Not Shipped | - |
| PSF-001014 | 1/17/2024 | Home Appliances | Amalia Craig | Undefined | Bulk order, pending deal with Paracel. |
| PSF-001625 | 1/21/2024 | Electronics | Amanda Honda | Undefined | Product damaged. Investigation required. |

Observera att alla fält från båda tabellerna kan läggas till i samma visualisering. Tabellerna associeras till varandra i datamodellen.

## Exempel - Utelämna kolumnrubriker

Redigera formatspecifikationen för att ladda en inline-tabell utan att definiera kolumnrubriker. Detta görs med labels-specifikationen (som ställs in till värdet no labels). Mer information finns i [Konfigurera formatspecifikationen i en inline-laddning](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#FormatSpec).

När du laddar en tabell utan att definiera kolumnnamn används systemdefinierade kolumnnamn automatiskt.

#### Laddningsskript och resultat

Översikt

I det här exemplet beskrivs hur du kan ladda en inline-tabell utan att definiera kolumnnamn.

Öppna Skriptredigeraren och lägg till följande laddningsskript till ett nytt delavsnitt.

Laddningsskript

```
Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);
```

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till dessa fält som dimensioner:

* @1

* @2

* @3

Resultattabell

| @1 | @2 | @3 |
| --- | --- | --- |
| 1 | Category1 | 40566.49 |
| 2 | Category2 | 3504.54 |
| 3 | Category3 | 593206.30 |

## Exempel - Ladda en annan datatyp

I det här exemplet beskrivs hur du kan ladda en inline-tabel i fast postformat. Se [Konfigurera formatspecifikationen i en inline-laddning](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#FormatSpec).

#### Laddningsskript och resultat

Översikt

Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.

Laddningsskriptet innehåller:

* En inline-load-sats som definierar tabellen DataTable.
* Att använda fix (som del av Table format-specifikationen) för att ange att data som ska laddas är i fast postformat.

Laddningsskript

```
DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);
```

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till dessa fält som dimensioner:

* a

* b

* c

* d

Resultattabell

| a | b | c | d |
| --- | --- | --- | --- |
| 1 | 2 | 3 | 4 |
| x | y | z | w |

## Exempel - Innehåll på flera rader

I det här exemplet beskrivs hur du kan skriva in fältinnehåll i flera rader i en inline-tabell. Se [Konfigurera formatspecifikationen i en inline-laddning](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#FormatSpec).

#### Laddningsskript och resultat

Översikt

Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.

Laddningsskriptet innehåller:

* En enkel inline-laddning som definierar tabellen T1.

* Användning av Quotes-specificeraren (med värdet msq) för att stödja innehåll på flera rader.

* Längdvärden anges i fot och tum.

* Symbolen med dubbla citattecken (") anger slutet på en flerradig post. I det här exemplet används samma symbol även för att beteckna tumvärdena. Detta görs för att visa syntaxen och hur den fungerar om du behöver använda båda i samma LOAD-sats. Om du anger "-symbolen för två tecken i följd ("") innebär det att koden ska tolkas som en enda textinstans av symbolen.

Laddningsskript

```
T1:
Load *, recno() as ID inline [
Length
"1' 2""
22' 10"""
14' 8"  ] (msq);
```

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till dessa fält som dimensioner:

* ID

* Length

För att visa innehåll med flera rader på avsett sätt måste inställningen Wrap text in cells (radbryt text i celler) vara aktiverad i egenskapspanelen. Dessutom måste appens tema (eller visualiseringsinställningar) tillåta tillräcklig Radhöjd (i rader).

Resultattabell

| ID | Length |
| --- | --- |
| 1 | 1' 2"<br><br>22' 10" |
| 2 | 14' 8" |

I tabellen ovan innehåller posten med ett ID-värde på 1 innehåll på flera rader.

## Exempel - Inline-laddningar med omvandlingar

I de här exemplen framgår hur du kan utföra beräkningar på fält som laddats inline för att skapa nya fält i datamodellen.

Mer information finns i [Dataomvandlingar](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#Transform).

#### Exempel: enkelt byte av namn på ett fält

Översikt

Öppna Skriptredigeraren och lägg till följande laddningsskript till ett nytt delavsnitt.

Laddningsskript

```
ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];
```

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till dessa fält som dimensioner:

* Original

* Updated

Resultattabell

| Original | Updated |
| --- | --- |
| ProductA | ProductA |
| ProductB | ProductB |
| ProductC | ProductC |

#### Exempel: enkel infogning av ett ID-fält

Översikt

I det här exemplet framgår hur du kan definiera ett beräknat fält för att ange ID för varje datarad utan att manuellt skriva in varje ID-värde.

Öppna Skriptredigeraren och lägg till följande laddningsskript till ett nytt delavsnitt.

Laddningsskript

```
ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];
```

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till dessa fält som dimensioner:

* ID

* ProductName

Resultattabell

| ID | ProductName |
| --- | --- |
| 1 | A |
| 2 | B |
| 3 | C |
| 4 | D |
| 5 | E |

#### Exempel: konfigurera LOAD-satser så att omvandlingar hanteras

Översikt

I det här exemplet visas flera sätt att tillämpa en enkel omvandling på inline-data. Du kan använda en eller flera LOAD-satser och konfigurera syntaxen på olika sätt för att definiera om en omvandling ersätter det ursprungliga fältet eller om både ursprungliga och nya fält laddas.

Lägg särskilt märke till variationerna i följande och hur de påverkar resultatet:

* Antal LOAD-satser i tabellen.

* Förekomst eller avsaknad av \*-symbol (laddar alla efterföljande fält).

* Förekomst eller avsaknad av kommatecken (,- symbol).

Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.

Laddningsskriptet innehåller:

* Fyra tabeller, som alla refererar till samma data. Fältnamnen är olika.

  * DerivedYears1: använder två LOAD satser för att ladda en inline-kolumn och en kolumn som innehåller en omvandling av inline-kolumnen.

  * DerivedYears2: använder två LOAD-satser. Skriptet laddar en inline-kolumn och laddar sedan ett beräknat fält som omvandlats från den ursprungliga kolumnen. Med den andra LOAD-satsen laddas inte originalkolumnen in i tabellen, vilket gör att det nya fältet i praktiken ersätter originalfältet.

  * DerivedYears3: använder en enda LOAD sats för att ladda både den ursprungliga inline-kolumnen och en omvandlad kolumn.

  * DerivedYears4: använder en enda LOAD-sats för att definiera ett inline-fält och en omvandling av det ursprungliga fältet. Endast det omvandlade fältet laddas i tabellen.

Laddningsskript

```
DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
```

Resultat

Ladda data och öppna ett ark. Skapa tre tabeller och lägg till dimensioner i dem på följande sätt:

* DerivedYears1: initial\_date1, derived\_year1

* DerivedYears2: initial\_date2

* DerivedYears3: initial\_date3, derived\_year3

Resultattabell: DerivedYears1DerivedYears1

| initial\_date1 | derived\_year1 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |

Resultattabell: DerivedYears2DerivedYears2

| derived\_year2 |
| --- |
| 2022 |
| 2023 |
| 2024 |

Resultattabell: DerivedYears3DerivedYears3

| initial\_date3 | derived\_year3 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |

Resultattabell: DerivedYears4DerivedYears4

| derived\_year4 |
| --- |
| 2022 |
| 2023 |
| 2024 |

#### Exempel: modifiera fältinnehåll

Översikt

Anta att du klistrar in information från en stor textfil i skriptredigeraren, men att du vill utföra ytterligare bearbetning av posterna i datauppsättningen. Du vill till exempel ta bort vissa tecken och prefix och skriva varje ord med stor bokstav.

Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.

Laddningsskriptet innehåller:

* En inline-tabell, Transformations, i vilken en omvandling definieras för att ändra textinnehållet i ett fält. Texten som omvandlas läggs till efter detta.

* Två LOAD -satser. Med konfigurationen i exemplet laddas bara det härledda fältet ProductName\_Trimmed till tabellen.

Laddningsskript

```
Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];
```

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till det här fältet som en dimension: ProductName\_Trimmed.

Resultattabell

| ProductName\_Trimmed |
| --- |
| Soft Drinks And Other Beverages |
| Snack Food |
| Electronics And Video Games |

## Exempel: Operatorer för omvandlingar och satser

Du kan använda operatorer för att definiera omvandlingar och specifika klausuler i LOAD-satsen. Mer information finns i [Operatorer och andra satser](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm#OpsAndClauses).

[Operatorer](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/Operators/operators.htm)

#### Laddningsskript och resultat

Översikt

Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.

Laddningsskriptet innehåller:

* En enkel inline-laddning som definierar tabellen Purchases.

* Infoga ett beräknat fält, OrderSize. Det här fältet är en omvandling av amount-fältet från inline-datauppsättningen. Det kategoriserar inköp som små eller stora, beroende på om beloppet överstiger $20000,00 eller inte.

* En where-sats som förhindrar poster från att laddas när amount är mindre än $0,05.

Laddningsskript

```
Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>0.05
;
```

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till dessa fält som dimensioner:

* ID

* amount

* OrderSize

Resultattabell

| ID | amount | OrderSize |
| --- | --- | --- |
| 1 | 2660.39 | Large Purchase |
| 2 | 100.01 | Small Purchase |
| 3 | 500.42 | Small Purchase |
| 4 | 5023.99 | Large Purchase |
| 6 | 2002.39 | Large Purchase |
| 7 | 31034.53 | Large Purchase |
| 8 | 1643.58 | Small Purchase |
| 9 | 3993.65 | Large Purchase |
| 10 | 614.34 | Small Purchase |
| 11 | 675.93 | Small Purchase |

I tabellen ovan har transaktionen med ett ID på 5 inte lagts in i tabellen. Detta beror på att amount-värdet är mindre än $0,05.

## Exempel - Skapa null-värden i en inline-tabell

I det här exemplet visas hur du kan använda NullInterpret-variabeln för att skapa null-värden i dina inline-data.

[NullInterpret](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ValueHandlingVariables/NullInterpret.htm)

#### Laddningsskript och resultat

Översikt

Öppna dataladdningsredigeraren och lägg till laddningsskriptet nedan i ett nytt delavsnitt.

Laddningsskriptet innehåller:

* En enkel inline-laddning som definierar tabellen T2.

* NullInterpret-variabeln definieras som två enstaka citatmärken. När skriptet laddas innehåller posterna det här värdet som null-värden.

Laddningsskript

```
set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];
```

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till det här fältet som en dimension: Test.

Resultattabell

| Test |
| --- |
| x |

I tabellen ovan är den första posten ett null-värd. Därför ingår det inte i visualiseringen. Null-värden som finns i tabeller med ytterligare dimensioner anges med en --symbol.

## Fler exempel

Ytterligare exempel hittar du i [Ladda](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/Load.htm).

RELATERAD INFORMATION:

* [Introduktion till Skriptredigeraren](https://help.qlik.com/lnk/Intro_Data_Load_Editor_QS)

## Mer information

* [Load](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/Load.htm)

* [Formatspecifikatorer](https://help.qlik.com/sv-SE/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptSpecifiers/format-specification-items.htm)

* [Introduktion till Skriptredigeraren](https://help.qlik.com/lnk/Intro_Data_Load_Editor_QS)