# Set-modifierare med sökningar

Du kan skapa uppsättningar av element genom sökningar med set-modifierare.

Exempel:

* `<Country = {"C*"}>`
* `<Year = {">2015"}>`
* `<Ingredient = {"*garlic*"}>`

Sökningar bör alltid vara inom dubbla citattecken, hakparenteser eller grava accenter. Du kan använda en blandning av stränglitteraler (enkla citattecken) och sökningar (dubbla citattecken). Exempel:

`<Product = {'Nut', "*Bolt", Washer}>`

## Textsökningar

Jokertecken och andra symboler kan användas i textsökningar:

* En asterisk (\*) kommer att motsvara valfritt antal tecken.

* Ett frågetecken (?) kommer att motsvara ett enda tecken.

* En grav accent (^) kommer att markera början på ett ord.

Exempel:

* `<Country = {"C*", "*land"}>`

  Matcha alla länder som börjar med ett `C` eller slutar med `land`.

* `<Country = {"*^z*"}>`

  Det kommer att matcha alla länder som har ett ord som börjar på `z`, som `New Zealand`.

## Numeriska sökningar

Du kan göra numeriska sökningar med hjälp av dessa relationsoperatorer: `>`, `>=`, `<`, `<=`

En numerisk sökning börjar alltid med en av dessa operatorer. Exempel:

* `<Year = {">2015"}>`

  Matcha 2016 och efterföljande år.

* `<Date = {">=1/1/2015<1/1/2016"}>`

  Matcha alla datum under 2015. Notera syntaxen för att beskriva ett tidsintervall mellan de två datumen. Datumformatet behöver matcha datumformatet för fältet i fråga.

## Sökningar med hjälp av uttryck

Du kan använda sökuttryck till att göra mer avancerade sökningar. En aggregering utvärderas sedan för varje fältvärde i sökfältet. Alla värden för vilka sökuttrycket returnerar sant väljs.

En uttryckssökning börjar alltid med ett likhetstecken: `=`

Exempel:

`<Customer = {"=Sum(Sales)>1000"}>`

Det returnerar alla kunder med ett försäljningsvärde som är större än 1 000. `Sum(Sales)` beräknas utifrån det aktuella urvalet. Det betyder att om du har ett urval i ett annat fält, till exempel fältet `Product`, får du endast kunder som uppfyllt försäljningsvillkoret för de valda produkterna som resultat.

Om du vill att villkoret ska vara oberoende av ditt urval behöver du använda set-analysen inne i söksträngen. Exempel:

`<Customer = {"=Sum({1} Sales)>1000"}>`

Uttrycken efter likhetstecknet kommer att tolkas som ett booleskt värde. Det betyder att om det utvärderas till något annat kommer alla tal utom noll att tolkas som sanna, samtidigt som noll och strängar tolkas som falska.

## Citat

Använd citattecken när söksträngar innehåller mellanslag eller specialtecken. Enkla citattecken implicerar en exakt, skiftlägeskänslig matchning med ett enda fältvärde. Dubbla citattecken implicerar en sökning som inte är skiftlägeskänslig och som potentiellt matchar flera fältvärden.

Exempel:

* `<Country = {'New Zealand'}>`

  Matcha endast `New Zealand`.

* `<Country = {"New Zealand"}>`

  Matcha `New Zealand`, `NEW ZEALAND` och `new zealand`.

Dubbla citattecken kan bytas ut av hakparenteser eller grava accenter.

Mer information finns i [Söka inom urval eller visualiseringar](https://help.qlik.com/sv-SE/cloud-services/Subsystems/Hub/Content/Sense_Hub/Selections/SelectionsToolbar/search-selections.htm).

Anteckning om informationI tidigare versioner av Qlik Sense hanterades enkla och dubbla citattecken på samma sätt, och alla strängar inom citattecken behandlades som sökningar. För att säkerställa bakåtkompatibiliteten kommer appar som skapats med äldre versioner av Qlik Sense att fungera på samma sätt som i tidigare versioner. Appar som skapats med Qlik Sense från november 2017 och framåt kommer att skilja mellan enkla och dubbla citattecken.

## Exempel: diagramuttryck för set-modifierare med sökningar

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-advanced-searches.htm)

#### Exempel – diagramuttryck

Laddningsskript

Ladda följande data som en inline-laddning i Skriptredigeraren för att skapa diagramuttrycksexemplen nedan.

```
MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1];	
```

Mer information om hur du använder inline-laddningar finns i [Använda inline-laddningar för att ladda data](https://help.qlik.com/sv-SE/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm).

Exempel 1: diagramuttryck med textsökningar

Skapa en tabell i ett Qlik Sense-ark med följande diagramuttryck.

Tabell – set-modifierare med textsökningar

| Land | Summa (Belopp) | Summa({&lt;Country={"C\*"}&gt;} Belopp) | Summa({&lt;Country={"\*^R\*"}&gt;} Belopp) | Summa({&lt;Product={"\*bolt\*"}&gt;} Belopp) |
| --- | --- | --- | --- | --- |
| Totalvärden | 41 | 24 | 10 | 26 |
| Kanada | 14 | 14 | 0 | 8 |
| Tjeckien | 10 | 10 | 10 | 4 |
| Frankrike | 4 | 0 | 0 | 1 |
| Tyskland | 13 | 0 | 0 | 13 |

Förklaring

* Dimensioner:

  * `Country`

* Mått:

  * `Sum(Amount)`

    Summa `Amount` utan set-uttryck.

  * `Sum({<Country={"C*"}>}Amount)`

    Summan `Amount` för alla länder som börjar på `C`, till exempel `Canada` och `Czech Republic`.

  * `Sum({<Country={"*^R*"}>}Amount)`

    Summan `Amount` för alla länder som har ett ord som börjar på `R`, som `Czech Republic`.

  * `Sum({<Product={"*bolt*"}>}Amount)`

    Summan `Amount` för alla produkter som innehåller strängen `bolt`, som `Bolt` och `Anchor bolt`.

Set-modifierare med textsökningar

Set-modifierare med textsökningar

Set-modifierare med textsökningar ![Diagramuttryck med textsökningar.](https://help.qlik.com/sv-SE/cloud-services/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_text_search.png)

Mer information om uttryck finns i [Använda uttryck i visualiseringar](https://help.qlik.com/sv-SE/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/use-expressions-in-visualizations.htm).

Exempel: diagramuttryck med numeriska sökningar.

Skapa en tabell i ett Qlik Sense-ark med följande diagramuttryck.

Tabell – set-modifierare med numeriska sökningar

| Land | Summa (Belopp) | Summa({&lt;År={"&gt;2019"}&gt;} Belopp) | Summa({&lt;ISO\_Datum={"&gt;=2019-07-01"}&gt;} Belopp) | Summa({&lt;US\_Datum={"&gt;=4/1/2018&lt;=12/31/2018"}&gt;} Belopp) |
| --- | --- | --- | --- | --- |
| Totalvärden | 41 | 10 | 16 | 16 |
| Kanada | 14 | 8 | 8 | 0 |
| Tjeckien | 10 | 0 | 6 | 1 |
| Frankrike | 4 | 2 | 2 | 2 |
| Tyskland | 13 | 0 | 0 | 13 |

Förklaring

* Dimensioner:

  * `Country`

* Mått:

  * `Sum(Amount)`

    Summa `Amount` utan set-uttryck.

  * `Sum({<Year={">2019"}>}Amount)`

    Summan `Amount` för alla år efter `2019`.

  * `Sum({<ISO_Date={">=2019-07-01"}>}Amount)`

    Summan `Amount` för alla datum från och med `2019-07-01`. Formatet på datumet i sökningen måste matcha formatet i fältet.

  * `Sum({<US_Date={">=4/1/2018<=12/31/2018"}>}Amount)`

    Summan `Amount` för alla datum från `4/1/2018` till `12/31/2018`, inklusive start- och slutdatum. Formatet på datumen i sökningen måste matcha formatet i fältet.

Set-modifierare med numeriska sökningar

Set-modifierare med numeriska sökningar

Set-modifierare med numeriska sökningar ![Diagramuttryck med numeriska sökningar.](https://help.qlik.com/sv-SE/cloud-services/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_numeric_search.png)

Exempel 3: diagramuttryck med uttryckssökningar

Skapa en tabell i ett Qlik Sense-ark med följande diagramuttryck.

Table - Set modifiers with expression searches

| Country | Sum (Amount) | Sum({&lt;Country={"=Sum(Amount)&gt;10"}&gt;} Amount) | Sum({&lt;Country={"=Count(distinct Product)=1"}&gt;} Amount) | Sum({&lt;Product={"=Count(Amount)&gt;3"}&gt;} Amount) |
| --- | --- | --- | --- | --- |
| Totals | 41 | 27 | 13 | 22 |
| Canada | 14 | 14 | 0 | 8 |
| Czech Republic | 10 | 0 | 0 | 0 |
| France | 4 | 0 | 0 | 1 |
| Germany | 13 | 13 | 13 | 13 |

Förklaring

* Dimensioner:

  * `Country`

* Mått:

  * `Sum(Amount)`

    Summa `Amount` utan set-uttryck.

  * `Sum({<Country={"=Sum(Amount)>10"}>}Amount)`

    Summan `Amount` för alla länder som har en aggregerad summa på `Amount` över `10`.

  * `Sum({<Country={"=Count(distinct Product)=1"}>}Amount)`

    Summan `Amount` för alla länder som är kopplade till exakt en distinkt produkt.

  * `Sum({<Product={"=Count(Amount)>3"}>}Amount)`

    Summan `Amount` för alla länder som har över tre transaktioner i data.

Set-modifierare med uttryckssökningar

Set-modifierare med uttryckssökningar

Set-modifierare med uttryckssökningar ![Diagramuttryck med uttryckssökningar.](https://help.qlik.com/sv-SE/cloud-services/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_expression_search.png)

| Exempel | Resultat |
| --- | --- |
| sum( {$–1&lt;Product = {“\*Internal\*”, “\*Domestic\*”}&gt;} Sales ) | Returnerar försäljningen för det aktuella valet, exklusive transaktioner som hör till produkter med strängen 'Internal' eller 'Domestic' i produktnamnet. |
| sum( {$&lt;Customer = {“=Sum({1&lt;Year = {2007}&gt;} Sales ) &gt; 1000000”}&gt;} Sales ) | Returnerar försäljningen för det aktuella valet, men med ett nytt val i fältet ”Customer”: enbart kunder som under 2007 hade en total försäljning på över 1 000 000. |