# daynumberofquarter Função de script e de gráfico

Esta função calcula o número do dia do trimestre em que um timestamp cai. Essa função é usada ao criar um calendário mestre.

Sintaxe:

DayNumberOfQuarter(timestamp[,start\_month])

Tipo de dados de retorno: inteiro

Argumentos

| Argumento | Descrição |
| --- | --- |
| timestamp | A data ou o carimbo de data/hora a ser avaliado. |
| start\_month | Ao especificar um start\_month entre 2 e 12 (1, se omitido), o início do ano pode avançar para o primeiro dia de qualquer mês. Por exemplo, para trabalhar com um ano fiscal que inicia em 1º de março, especifique start\_month = 3. |

Estes exemplos usam o formato de data DD/MM/YYYY. O formato de data é especificado no comando SET DateFormat na parte superior do seu script de carga de dados. Altere o formato nos exemplos para atender às suas necessidades.

Exemplos de funções

| Exemplo | Resultado |
| --- | --- |
| `DayNumberOfQuarter('12/09/2014')` | Retorna 74, o número do dia do trimestre atual. |
| `DayNumberOfQuarter('12/09/2014',3)` | Retorna 12, o número do dia do trimestre atual.<br>Neste caso, o primeiro trimestre começa em março (pois o start\_month está especificado como 3). Isto significa que o trimestre atual é o terceiro semestre, que começou dia 1 de setembro. |

## Exemplo 1 – Início do ano em janeiro (script)

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/DateAndTimeFunctions/daynumberofquarter.htm)

#### Script de carregamento e resultados

Visão geral

Abra o Editor da carga de dados e adicione o script de carregamento abaixo em uma nova guia.

O script de carregamento contém:

* Um conjunto de dados simples contendo uma lista de datas, que é carregada em uma tabela chamada `Calendar`. A variável de sistema `DateFormat` padrão MM/DD/AAAA é usada.

* Um carregamento anterior que cria um campo adicional, chamado `DayNrQtr`, usando a função `DayNumberOfQuarter()`.

Além da data, nenhum parâmetro adicional é fornecido para a função.

Script de carregamento

```
SET DateFormat='MM/DD/YYYY'; 
 
Calendar: 
Load 
        date, 
        DayNumberOfQuarter(date) as DayNrQtr 
        ; 
Load 
date 
Inline  
[	 
date 
01/01/2022 
01/10/2022 
01/31/2022 
02/01/2022 
02/10/2022 
02/28/2022 
03/01/2022 
03/31/2022 
04/01/2022 
]; 
```

Resultados

Carregue os dados e abra uma pasta. Crie uma nova tabela e adicione esses campos como dimensões:

* `date`

* `daynrqtr`

Tabela de resultados

| data | daynrqtr |
| --- | --- |
| 01/01/2022 | 1 |
| 01/10/2022 | 10 |
| 01/31/2022 | 31 |
| 02/01/2022 | 32 |
| 02/10/2022 | 41 |
| 02/28/2022 | 59 |
| 03/01/2022 | 61 |
| 03/31/2022 | 91 |
| 04/01/2022 | 1 |

O primeiro dia do ano é 1º de janeiro porque um segundo argumento não foi transmitido para a função `DayNumberOfQuarter()`.

1º de janeiro é o 1º dia do trimestre, enquanto 1º de fevereiro é o 32º dia do trimestre. 31 de março é o 91º e último dia do trimestre, enquanto o 1º de abril é o 1º dia do 2º trimestre.

## Exemplo 2 – Início do ano em fevereiro (script)

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/DateAndTimeFunctions/daynumberofquarter.htm)

#### Script de carregamento e resultados

Visão geral

Abra o Editor da carga de dados e adicione o script de carregamento abaixo em uma nova guia.

O script de carregamento contém:

* O mesmo conjunto de dados do primeiro exemplo.

* A variável de sistema `DateFormat` padrão MM/DD/AAAA é usada.

* Um argumento `start_month` que começa em 1º de fevereiro. Isso define o exercício como 1º de fevereiro.

Script de carregamento

```
SET DateFormat='MM/DD/YYYY'; 
					
Calendar:
Load
	date,
	DayNumberOfQuarter(date,2) as DayNrQtr
	;
Load
date
Inline
[
date
01/01/2022
01/10/2022
01/31/2022
02/01/2022
02/10/2022
02/28/2022
03/01/2022
03/31/2022
04/01/2022
]; 
```

Resultados

Carregue os dados e abra uma pasta. Crie uma nova tabela e adicione esses campos como dimensões:

* `date`

* `daynrqtr`

Tabela de resultados

| data | daynrqtr |
| --- | --- |
| 01/01/2022 | 62 |
| 01/10/2022 | 71 |
| 01/31/2022 | 92 |
| 02/01/2022 | 1 |
| 02/10/2022 | 10 |
| 02/28/2022 | 28 |
| 03/01/2022 | 30 |
| 03/31/2022 | 60 |
| 04/01/2022 | 61 |

O primeiro dia do ano é 1º de fevereiro, pois o segundo argumento transmitido para a função `DayNumberOfQuarter()` foi 2.

O primeiro trimestre do ano opera entre fevereiro e abril, enquanto o quarto trimestre opera entre novembro e janeiro. Isso é mostrado na tabela de resultados, onde 1º de fevereiro é o 1º dia do trimestre, enquanto 31 de janeiro é o 92º e último dia do trimestre.

## Exemplo 3 – Início do ano em janeiro (gráfico)

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/DateAndTimeFunctions/daynumberofquarter.htm)

#### Script de carregamento e expressão de gráfico

Visão geral

Abra o Editor da carga de dados e adicione o script de carregamento abaixo em uma nova guia.

O script de carregamento contém:

* O mesmo conjunto de dados do primeiro exemplo.

* A variável de sistema `DateFormat` padrão MM/DD/AAAA é usada.

No entanto, neste exemplo, o conjunto de dados inalterado é carregado no aplicativo. O valor do dia do trimestre é calculado por meio de uma medida em um objeto de gráfico.

Script de carregamento

```
SET DateFormat='MM/DD/YYYY';
						
Calendar:
Load
date
Inline
[
date
01/01/2022
01/10/2022
01/31/2022
02/01/2022
02/10/2022
02/28/2022
03/01/2022
03/31/2022
04/01/2022
]; 
```

Resultados

Carregue os dados e abra uma pasta. Crie uma nova tabela e adicione esse campo como uma dimensão: `date`.

Crie a seguinte medida:

`=daynumberofquarter(date)`

Tabela de resultados

| data | =daynumberofquarter(date) |
| --- | --- |
| 01/01/2022 | 1 |
| 01/10/2022 | 10 |
| 01/31/2022 | 31 |
| 02/01/2022 | 32 |
| 02/10/2022 | 41 |
| 02/28/2022 | 59 |
| 03/01/2022 | 61 |
| 03/31/2022 | 91 |
| 04/01/2022 | 1 |

O primeiro dia do ano é 1º de janeiro, pois um segundo argumento não foi transmitido para a função `DayNumberOfQuarter()`.

1º de janeiro é o 1º dia do trimestre, enquanto 1º de fevereiro é o 32º dia do trimestre. 31 de março é o 91º e último dia do trimestre, enquanto o 1º de abril é o 1º dia do 2º trimestre.

## Exemplo 4 – Início do ano em fevereiro (gráfico)

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/DateAndTimeFunctions/daynumberofquarter.htm)

#### Script de carregamento e expressão de gráfico

Visão geral

Abra o Editor da carga de dados e adicione o script de carregamento abaixo em uma nova guia.

O script de carregamento contém:

* O mesmo conjunto de dados do primeiro exemplo.

* A variável de sistema DateFormat padrão MM/DD/AAAA é usada.

* O exercício vai de 1º de fevereiro a 31 de janeiro.

No entanto, neste exemplo, o conjunto de dados inalterado é carregado no aplicativo. O valor do dia do trimestre é calculado por meio de uma medida em um objeto de gráfico.

Script de carregamento

```
SET DateFormat='MM/DD/YYYY';
						
Calendar:
Load
date
Inline
[
date
01/01/2022
01/10/2022
01/31/2022
02/01/2022
02/10/2022
02/28/2022
03/01/2022
03/31/2022
04/01/2022
]; 
```

Objeto de gráfico

Carregue os dados e abra uma pasta. Crie uma nova tabela e adicione esse campo como uma dimensão: date.

Crie a seguinte medida:

=daynumberofquarter(date,2)

Resultados

Tabela de resultados

| data | =daynumberofquarter(date,2) |
| --- | --- |
| 01/01/2022 | 62 |
| 01/10/2022 | 71 |
| 01/31/2022 | 92 |
| 02/01/2022 | 1 |
| 02/10/2022 | 10 |
| 02/28/2022 | 28 |
| 03/01/2022 | 30 |
| 03/31/2022 | 60 |
| 04/01/2022 | 61 |

O primeiro dia do ano é 1º de janeiro, pois o segundo argumento transmitido para a função DayNumberOfQuarter() foi 2.

O primeiro trimestre do ano opera entre fevereiro e abril, enquanto o quarto trimestre opera entre novembro e janeiro. Isso é evidenciado na tabela de resultados, onde 1º de fevereiro é o 1º dia do trimestre, enquanto 31 de janeiro é o 92º e último dia do trimestre.