# Expansão de sinal de dólar usando uma expressão

Expressões podem ser usadas em expansões de sinal de dólar.

O conteúdo entre os colchetes deve começar com um sinal de igual:

`$(=expression)`

A expressão será avaliada e o valor será usado na expansão. Por exemplo:

```
// returns a string with the current year
$(=Year(Today())); 
```

```
// returns the year before the selected one
$(=Only(Year)-1);
```

## Exemplo: selecione uma medida fazendo referência a ela em uma expressão de gráfico

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/dollar-sign-expansion-using-expression.htm)

#### Exemplo: script de carregamento

Script de carregamento

Carregue os seguintes dados como um carregamento inline no editor da carga de dados:

```
// Load string “=MinString(Measure)” into variable VSelectMeasure
Let vSelectMeasure = '=MinString(Measure)';
MyTable1: // Create table and load values for Dim and Sales
Load * inline [
Dim, Sales
A, 150
A, 200
B, 240
B, 230
C, 410
C, 330 ];                      
 
 
MyTable2: // Create table and load aggregations as field values for Measure
Load * Inline [
Measure
avg(Sales)
sum(Sales)
count(distinct Dim)];
```

Para obter mais informações sobre como usar carregamentos inline, consulte [Usando carregamentos inline para carregar dados](https://help.qlik.com/pt-BR/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm).

Explicação

O script permite que você selecione uma medida fazendo referência a ela em uma expressão de gráfico. A expressão de gráfico contém a expansão da variável `$(=MinString(Measure))`. `MinString()` encontra valores de string na expressão e retorna o primeiro valor de texto classificado em ordem alfabética, neste caso, `avg(Sales)`. Isso torna possível decidir (e selecionar) interativamente qual expressão usar em uma visualização, sem acessar e manipular as propriedades do objeto.

Saída

Crie a seguinte tabela no Qlik Sense usando:

* Dimensão: `Dim`

* Medidas:

  * `='$(vSelectMeasure)'`

  * `=$(=MinString(Measure))`

  * `Avg(Sales)`

Tabela - Expansão de sinal de cifrão usando uma expressão

| Dim | ='$(vSelectMeasure)' | =$(=MinString(Measure)) | Avg(Sales) |
| --- | --- | --- | --- |
| Totais | - | 260 | 260 |
| A | avg(Sales) | 175 | 175 |
| B | avg(Sales) | 235 | 235 |
| C | avg(Sales) | 370 | 370 |

## Exemplo: calcular a cota entre duas dimensões

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/dollar-sign-expansion-using-expression.htm)

#### Exemplo: script de carregamento

Script de carregamento

Carregue os seguintes dados como um carregamento inline no editor da carga de dados:

```
Let vDivision = '=MinString(Numerator) / MinString(Denominator)';
Load recno() as Numerator autogenerate 100;
Load recno() as Denominator autogenerate 100;
```

Explicação

Este script gera um par de campos, cada um com 100 valores, que funcionam como Numeradores e Denominadores em um cálculo da cota entre os dois. A medida do gráfico contém a expansão da variável ='$( vDivision )', possibilitando decidir (e selecionar) de forma interativa a cota a ser calculada.

Saída

Crie a seguinte tabela no Qlik Sense usando:

* Dimensões:

  * Numerator

  * Denominator

* Medida: ='$(vDivision)'

A cota resultante (Totais) é afetada pelos valores selecionados nos campos. Numerator (=5) e Denominator (=3) e será recalculado a cada nova seleção em qualquer um dos campos.

Tabela - Expansão de sinal de cifrão como expressão

| Numerador | Denominador | ='$(vDivision)' |
| --- | --- | --- |
| Totais | - | 1,6666666666667 |
| 5 | 3 | 1,6666666666667 |

## Inclusão de arquivo

Inclusões de arquivo são feitas usando as expansões do sinal de dólar. A sintaxe é:

$(include=filename)

O texto acima será substituído pelo conteúdo do arquivo especificado após o sinal de igual. Esse recurso é bastante útil ao armazenar scripts ou partes de scripts em arquivos de texto.

Para obter mais informações, consulte [Include](https://help.qlik.com/pt-BR/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/SystemVariables/Include.htm).

## Expansões de moeda e estados alternados

Uma expansão de moeda normalmente não é sensível a estados alternados. No entanto, se a expansão de sinal de cifrão tiver uma expressão, ela será avaliada no estado relevante para o objeto onde essa expansão é feita.

Por exemplo:

```
$(=Sum(Amount))
```

O cálculo retornará a soma do valor com base na seleção no estado do objeto.

## Interações entre expansões de sinal de dólar e expressões de conjunto externo

Ao combinar expansões de cifrão com expressões de conjunto externo, uma ordem específica de avaliação se aplica. Para obter detalhes, consulte [Expressões de conjunto externo e expansões de sinal de dólar](https://help.qlik.com/pt-BR/sense/May2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/outer-set-expression-dollar-sign-expansion.htm).