# Num — funkcja skryptu i funkcja wykresu

Funkcja Num() formatuje liczbę, to znaczy konwertuje wartość liczbową danych wejściowych na wyświetlany tekst przy użyciu formatu określonego w drugim parametrze. Jeśli drugi parametr zostanie pominięty, używa separatorów dziesiętnych i tysięcznych ustawionych w skrypcie ładowania danych. Parametrami opcjonalnymi są niestandardowe symbole separatora dziesiętnego i separatora tysięcy.

Składnia:

Num(number[, format[, dec\_sep [, thou\_sep]]])

Typ zwracanych danych: dual

Funkcja Num zwraca wartość podwójną z ciągiem i wartością liczbową. Funkcja pobiera wartość liczbową wyrażenia wejściowego i generuje ciąg reprezentujący liczbę.

Argumenty:

Argumenty

| Argument | Opis |
| --- | --- |
| number | Liczba do sformatowania. |
| format | Ciąg określający sposób formatowania otrzymywanego ciągu. W przypadku pominięcia zostaną użyte separatory dziesiętne i tysięcy ustawione w skrypcie ładowania danych. |
| dec\_sep | Ciąg znaków określający separator dziesiętny. W przypadku pominięcia zostanie użyta wartość zmiennej DecimalSep ustawiona w skrypcie ładowania danych. |
| thou\_sep | Ciąg znaków określający separator tysięcy. W przypadku pominięcia zostanie użyta wartość zmiennej ThousandSep ustawiona w skrypcie ładowania danych. |

Więcej informacji o formatowaniu liczb zawiera temat [Konwencje formatów liczb i godzin](https://help.qlik.com/pl-PL/sense/November2024/Subsystems/Hub/Content/Sense_Hub/Introduction/conventions-number-time-formats.htm).

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/FormattingFunctions/Num.htm)

#### Przykład: Wyrażenie wykresu

Przykład:

Poniższa tabela przedstawia wyniki, gdy wartość pola A równa się 35648,312.

Wyniki

| Symbol | Wynik |
| --- | --- |
| Num(A) | 35648.312 (zależy od zmiennych środowiskowych w skrypcie) |
| Num(A, '0.0', '.') | 35648.3 |
| Num(A, '0,00', ',') | 35648,31 |
| Num(A, '#,##0.0', '.', ',') | 35,648.3 |
| Num(A, '# ##0', ',', ' ') | 35 648 |

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/FormattingFunctions/Num.htm)

#### Przykład: Skrypt ładowania

Skrypt ładowania

Funkcja Num może być używana w skrypcie ładowania w celu formatowania liczb, nawet jeśli separatory tysięcy i dziesiętne są już ustawione w skrypcie. Poniższy skrypt ładowania zawiera konkretne separatory tysięcy i dziesiętne, a następnie używa funkcji Num w celu formatowania danych na inne sposoby.

W edytorze ładowania danych utwórz nową sekcję, a następnie dodaj skrypt przykładowy i uruchom go. Następnie dodaj do arkusza w swojej aplikacji co najmniej pola wyszczególnione w kolumnie wyników, aby wyświetlić wynik.

```
SET ThousandSep=',';
SET DecimalSep='.';
Transactions:
Load
*,
Num(transaction_amount) as [No formatting],
Num(transaction_amount,'0') as [0],
Num(transaction_amount,'#,##0') as [#,##0],
Num(transaction_amount,'# ###,00') as [# ###,00],
Num(transaction_amount,'# ###,00',',',' ') as [# ###,00 , ',' , ' '],
Num(transaction_amount,'#,###.00','.',',') as [#,###.00 , '.' , ','],
Num(transaction_amount,'$#,###.00') as [$#,###.00],
;
Load * Inline [
transaction_id, transaction_date, transaction_amount, transaction_quantity, discount, customer_id, size, color_code
3750, 20180830, 12423.56, 23, 0,2038593, L, Red
3751, 20180907, 5356.31, 6, 0.1, 203521, m, orange
3752, 20180916, 15.75, 1, 0.22, 5646471, S, blue
3753, 20180922, 1251, 7, 0, 3036491, l, Black
3754, 20180922, 21484.21, 1356, 75, 049681, xs, Red
3756, 20180922, -59.18, 2, 0.333333333333333, 2038593, M, Blue
3757, 20180923, 3177.4, 21, .14, 203521, XL, Black
];
```

Tabela aplikacji Qlik SenseQlik Sense pokazująca wyniki różnych zastosowań funkcji NumNum w skrypcie ładowania. Czwarta kolumna tabeli zawiera niepoprawne użycie formatowania — do celów przykładowych.

| No formatting | 0 | #,##0 | # ###,00 | # ###,00 , ',' , ' ' | #,###.00 , '.' , ',' | $#,###.00 |
| --- | --- | --- | --- | --- | --- | --- |
| -59.18 | -59 | -59 | -59###,00 | -59,18 | -59.18 | $-59,18 |
| 15.75 | 16 | 16 | 16###,00 | 15,75 | 15.75 | $15,75 |
| 1251 | 1251 | 1,251 | 1251###,00 | 1 251,00 | 1,251.00 | $1,251.00 |
| 3177.4 | 3177 | 3,177 | 3177###,00 | 3 177,40 | 3,177.40 | $3,177.40 |
| 5356.31 | 5356 | 5,356 | 5356###,00 | 5 356,31 | 5,356.31 | $5,356.31 |
| 12423.56 | 12424 | 12,424 | 12424###,00 | 12 423,56 | 12,423.56 | $12,423.56 |
| 21484.21 | 21484 | 21,484 | 21484###,00 | 21 484,21 | 21,484.21 | $21,484.21 |

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/FormattingFunctions/Num.htm)

#### Przykład: Skrypt ładowania

Skrypt ładowania

Funkcja Num może być używana w skrypcie ładowania w celu sformatowania liczby jako procentu.

W edytorze ładowania danych utwórz nową sekcję, a następnie dodaj skrypt przykładowy i uruchom go. Następnie dodaj do arkusza w swojej aplikacji co najmniej pola wyszczególnione w kolumnie wyników, aby wyświetlić wynik.

```
SET ThousandSep=',';
SET DecimalSep='.';
Transactions:
Load
*,
Num(discount,'#,##0%') as [Discount #,##0%]
;
Load * Inline [
transaction_id, transaction_date, transaction_amount, transaction_quantity, discount, customer_id, size, color_code
3750, 20180830, 12423.56, 23, 0,2038593, L, Red
3751, 20180907, 5356.31, 6, 0.1, 203521, m, orange
3752, 20180916, 15.75, 1, 0.22, 5646471, S, blue
3753, 20180922, 1251, 7, 0, 3036491, l, Black
3754, 20180922, 21484.21, 1356, 75, 049681, xs, Red
3756, 20180922, -59.18, 2, 0.333333333333333, 2038593, M, Blue
3757, 20180923, 3177.4, 21, .14, 203521, XL, Black
];
```

Tabela aplikacji Qlik SenseQlik Sense pokazująca wyniki funkcji NumNum używanej w skrypcie ładowania w celu formatowania procentów.

| Discount | Discount #,##0% |
| --- | --- |
| 0.333333333333333 | 33% |
| 0.22 | 22% |
| 0 | 0% |
| .14 | 14% |
| 0.1 | 10% |
| 0 | 0% |
| 75 | 7,500% |