# Modyfikatory zestawów

Wyrażenia zestawu służą do definiowania zakresu obliczenia. Centralną częścią wyrażenia zestawu jest modyfikator zestawu, który określa wybór. Służy do modyfikowania wyboru użytkownika lub wyboru w identyfikatorze zestawu, a wynik określa nowy zakres obliczeń.

Modyfikator ustawień składa się z jednej lub więcej nazw pól, po których następuje wybór, który ma zostać dokonany na danym polu. Modyfikator jest ujęty w nawiasy kątowe: `< >`

Na przykład:

* `Sum ( {$<Year = {2015}>} Sales )`

* `Count ( {1<Country = {Germany}>} distinct OrderID )`

* `Sum ( {$<Year = {2015}, Country = {Germany}>} Sales )`

## Zestawy elementów

Zestaw elementów można zdefiniować, używając następujących sposobów:

* Lista wartości

* Wyszukiwanie

* Odwołanie do innego pola

* Funkcja zestawu

Jeśli definicja zestawu elementów zostanie pominięta, modyfikator zestawu wyczyści wszystkie wybory w tym polu. Na przykład:

`Sum( {$<Year = >} Sales )`

## Przykłady: wyrażenia wykresu do modyfikatorów zestawów na podstawie zestawów elementów

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers.htm)

#### Przykłady — wyrażenia wykresu

Skrypt ładowania

Załaduj następujące dane w edytorze ładowania danych jako ładowanie wbudowane, aby utworzyć poniższe przykłady wyrażeń wykresu:

```
MyTable:
Load * Inline [
Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
Belgium, 2014, 182766.87
Belgium, 2015, 178042.33
Brazil, 2014, 174492.67
Brazil, 2015, 2104.22
Canada, 2014, 101801.33
Canada, 2015, 40288.25
Denmark, 2014, 45273.25
Denmark, 2015, 106938.41
Finland, 2014, 107565.55
Finland, 2015, 30583.44
France, 2014, 115644.26
France, 2015, 30696.98
Germany, 2014, 8775.18
Germany, 2015, 77185.68
];
```

Aby uzyskać więcej informacji o ładowaniu wbudowanym, zobacz temat [Używanie wbudowanych ładowań do ładowania danych](https://help.qlik.com/pl-PL/sense/November2024/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm).

Wyrażenia wykresu

Utwórz tabelę w arkuszu Qlik Sense z następującymi wyrażeniami wykresu

Tabela — modyfikatory zestawu oparte na zestawach elementów

| Kraj | Sum(Sales) | Sum({1&lt;Country={Belgium}&gt;} Sales) | Sum({1&lt;Country={"\*A\*"}&gt;} Sales) | Sum({1&lt;Country={"A\*"}&gt;} Sales) | Sum({1&lt;Year={$(=Max(Year))}&gt;} Sales) |
| --- | --- | --- | --- | --- | --- |
| Sumy | 1645397.3 | 360809.2 | 1284588.1 | 443238.88 | 788617.07 |
| Argentyna | 206332.92 | 0 | 206332.92 | 206332.92 | 140037.89 |
| Austria | 236905.96 | 0 | 236905.96 | 236905.96 | 182739.87 |
| Belgia | 360809.2 | 360809.2 | 0 | 0 | 178042.33 |
| Brazylia | 176596.89 | 0 | 176596.89 | 0 | 2104.22 |
| Kanada | 142089.58 | 0 | 142089.58 | 0 | 40288.25 |
| Dania | 152211.66 | 0 | 152211.66 | 0 | 106938.41 |
| Finlandia | 138148.99 | 0 | 138148.99 | 0 | 30583.44 |
| Francja | 146341.24 | 0 | 146341.24 | 0 | 30696.98 |
| Niemcy | 85960.86 | 0 | 85960.86 | 0 | 77185.68 |

Objaśnienie

* Wymiary:

  * `Country`

* Miary:

  * `Sum(Sales)`

    Suma `Sales` bez wyrażenia zestawu.

  * `Sum({1<Country={Belgium}>}Sales)`

    Wybierz `Belgium`, a następnie zsumuj odpowiednie `Sales`.

  * `Sum({1<Country={"*A*"}>}Sales)`

    Wybierz wszystkie kraje, które mają w nazwie `A`, a następnie zsumuj odpowiednie `Sales`.

  * `Sum({1<Country={"A*"}>}Sales)`

    Wybierz wszystkie kraje, które zaczynają się od `A`, a następnie zsumuj odpowiednie `Sales`.

  * `Sum({1<Year={$(=Max(Year))}>}Sales)`

    Oblicz `Max(Year)`, czyli `2015`, a następnie zsumuj odpowiednie `Sales`.

Modyfikatory zestawów oparte na zestawach elementów

Modyfikatory zestawów oparte na zestawach elementów

Modyfikatory zestawów oparte na zestawach elementów ![Modyfikatory zestawów oparte na zestawach elementów.](https://help.qlik.com/pl-PL/sense/November2024/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_set_modifiers_element_sets.png)

## Lista wartości

Najbardziej typowym przykładem zestawu elementów jest zestaw oparty na liście wartości pól ujętych w nawiasy klamrowe. Na przykład:

* `{$<Country = {Canada, Germany, Singapore}>}`

* `{$<Year = {2015, 2016}>}`

Wewnętrzne nawiasy klamrowe definiują zestaw elementów. Poszczególne wartości są rozdzielane przecinkami.

## Cudzysłowy i rozróżnianie wielkości liter

Jeśli wartości zawierają spacje lub znaki specjalne, należy je umieścić w cudzysłowie. Pojedyncze cudzysłowy implikują dosłowne dopasowanie z rozróżnianiem wielkości liter, z pojedynczą wartością pola. Podwójne cudzysłowy oznaczają dopasowanie bez rozróżniania wielkości liter z co najmniej jedną wartością pola. Na przykład:

* `<Country = {'New Zealand'}>`

  Dopasowanie tylko do `New Zealand`.

* `<Country = {"New Zealand"}>`

  Dopasowanie do `New Zealand`, `NEW ZEALAND` i `new zealand`.

Daty muszą być ujęte w cudzysłów i zgodne z formatem daty w danym polu. Na przykład:

* `<ISO_Date = {'2021-12-31'}>`

* `<US_Date = {'12/31/2021'}>`

* `<UK_Date = {'31/12/2021'}>`

Cudzysłowy podwójne można zastąpić nawiasami kwadratowymi lub akcentami słabymi.

## Wyszukiwania

Zestawy elementów można również tworzyć przez wyszukiwanie. Na przykład:

* `<Country = {"C*"}>`
* `<Ingredient = {"*garlic*"}>`
* `<Year = {">2015"}>`
* `<Date = {">12/31/2015"}>`

W wyszukiwaniach tekstowych można używać symboli wieloznacznych: gwiazdka (`*`) reprezentuje dowolną liczbę znaków, a znak zapytania (`?`) reprezentuje pojedynczy znak. Do definiowania wyszukiwań liczbowych można używać operatorów relacyjnych.

Do wyszukiwania zawsze należy używać cudzysłowów. W wyszukiwaniach wielkość liter nie jest rozróżniana.

Więcej informacji zawiera temat [Modyfikatory zestawów z wyszukiwaniami](https://help.qlik.com/pl-PL/sense/November2024/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-advanced-searches.htm).

## Rozszerzenia przez znak dolara

Rozszerzenia przez znak dolara są potrzebne, jeśli chcesz użyć obliczeń w swoim zestawie elementów. Jeśli na przykład chcesz spojrzeć tylko na ostatni możliwy rok, możesz użyć:

`<Year = {$(=Max(Year))}>`

Więcej informacji zawiera temat [Modyfikatory zestawów z rozszerzeniami przez znak dolara](https://help.qlik.com/pl-PL/sense/November2024/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-dollar-sign-expansions.htm).

## Wybrane wartości w innych polach

Modyfikatory mogą być oparte na wybranych wartościach innego pola. Na przykład:

`<OrderDate = DeliveryDate>`

Taki modyfikator spowoduje pobranie wybranych wartości z pola `DeliveryDate` i zastosowanie ich jako selekcji w polu `OrderDate`. Jeśli odrębnych wartości jest wiele (więcej niż kilkaset), taka operacja bardzo obciąża procesor i nie jest zalecana.

## Funkcje zestawu elementów

Zestaw elementów może też być oparty na funkcjach zestawu `P()` (wartości możliwe) i `E()` (wartości wykluczone).

Jeżeli na przykład chcesz wybrać kraje, w których jest lub był sprzedawany produkt `Cap`, możesz użyć:

`<Country = P({1<Product={Cap}>} Country)>`

Podobnie jeżeli chcesz wybrać kraje, w których produkt `Cap` nie był sprzedawany, możesz użyć:

`<Country = E({1<Product={Cap}>} Country)>`

Więcej informacji zawiera temat [Modyfikatory zestawów z wykorzystaniem funkcji zestawu](https://help.qlik.com/pl-PL/sense/November2024/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-implicit-field-value-definitions.htm).

## Dowiedz się więcej

* [Analiza zestawów](https://help.qlik.com/pl-PL/sense/November2024/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-analysis-expressions.htm)

* [Identyfikatory zestawu](https://help.qlik.com/pl-PL/sense/November2024/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-identifiers.htm)

* [Operatory zestawów](https://help.qlik.com/pl-PL/sense/November2024/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-operators.htm)