# Timestamp#funkcja skryptu i funkcja wykresu
Funkcja Timestamp#() ocenia wyrażenie jako wartość daty i czasu w formacie znacznika czasu ustawionym w skrypcie ładowania danych lub systemie operacyjnym, chyba że podano format ciągu znaków.
Składnia:
timestamp#(text[, format])
Typ zwracanych danych: wartość podwójna
Argumenty
| Argument | Opis |
| --- | --- |
| text | Tekstowy ciąg znaków do oceny. |
| format | Ciąg znaków opisujący format, którego należy użyć do interpretacji ciągu tekstowego. W przypadku pominięcia użyty jest krótki format daty, format godziny i separator dziesiętny ustawiony w systemie operacyjnym. Norma ISO 8601 jest obsługiwana w zakresie znaczników czasu.
Funkcja `Timestamp#` obsługuje wiele opcji formatu dla różnych struktur godziny, na przykład:
`DD/MM/YYYY`: koncentruje się tylko na dacie (na przykład: `15/11/2024`).
`YYYY-MM-DD hh:mm:ss`: : wyświetla pełny znacznik czasu (na przykład `2024-11-15 13:30:45`).
`MMM DD, YYYY`: wyświetla skróconą wersję miesiąca i pełny rok (na przykład `Nov 15, 2024`).
`hh:mm:ss TT`: pokazuje tylko godzinę w formacie 12-godzinnym (na przykład: `01:30:45 PM`).
`HH:mm:ss`: wyświetla godzinę w formacie 24-godzinnym (na przykład `13:30:45`).
`wwww, MMM DD YYYY`: wyświetla pełny dzień tygodnia i datę (na przykład `Friday, Nov 15 2024`).
`YYYY-MM-DD hh:mm:ss.fff`: dołącza milisekundy (na przykład `2024-11-15 13:30:45.123`).
[Opisy formatów liczb i godzin](https://help.qlik.com/pl-PL/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Introduction/conventions-number-time-formats.htm) |
Przykład: wyrażenia wykresu
| Przykład | Wynik |
| --- | --- |
| `Timestamp#('12-03-2023 10:25:30', 'DD-MM-YYYY hh:mm:ss')` | Zwraca wartość `12-03-2023 10:25:30` |
| `Timestamp#('2023/03/15 13:45', 'YYYY/MM/DD hh:mm')` | Zwraca wartość `2023/03/15 13:45` |
## Przykład — podstawy Timestamp\#
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/InterpretationFunctions/timestamp_hash.htm)
#### Skrypt ładowania
Przegląd
Otwórz Edytor ładowania danych i poniżej dodaj skrypt ładowania do nowej sekcji.
Skrypt ładowania zawiera:
* Zestaw danych załadowany do tabeli o nazwie `Example`.
* Następujące pole w tabeli danych:
* `InputString`
* Poprzedzające ładowanie, które wykorzystuje funkcję `Timestamp#` w celu potraktowania wyrażenia jako wartości daty i godziny. Po wykonaniu tworzy dodatkowe pole o nazwie `TimeStamp_InputString`.
Skrypt ładowania
```
SET DateFormat='M/D/YYYY'
Example:
Load *,
Timestamp(Timestamp#(InputString)) as TimeStamp_InputString;
LOAD * INLINE [
InputString
2015-09-15T12:13:14
1952-10-16T13:14:00+0200
1109-03-01T14:15
];
```
Wyniki
Załaduj dane i otwórz arkusz. Utwórz nową tabelę i dodaj te pola jako wymiary:
* ` InputString
`
* `TimeStamp_InputString`
Tabela wynikowa
| Ciąg wejściowy | TimeStamp\_InputString |
| --- | --- |
| 1109-03-01T14:15 | 3/1/1109 2:15:00 PM |
| 1952-10-16T13:14:00+0200 | 10/16/1952 11:14:00 AM |
| 2015-09-15T12:13:14 | 9/15/2015 12:13:14 PM |
W tym przykładzie można zobaczyć, jak wartości łańcuchowe mogą być oceniane jako znacznik czasu przy użyciu funkcji `Timestamp#`.
## Przykład — zastosowanie znacznika czasu
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/InterpretationFunctions/timestamp_hash.htm)
#### Skrypt ładowania
Przegląd
Dane z dziennika zdarzeń zawierają znacznik czasu, którego chcesz użyć.
Otwórz Edytor ładowania danych i poniżej dodaj skrypt ładowania do nowej sekcji.
Skrypt ładowania zawiera:
* Zestaw danych załadowany do tabeli o nazwie `Example`.
* Tabela zawiera następujące pola:
* `Event`
* `EventDateTime`
* Poprzedzające obciążenie, które wykorzystuje funkcję `Timestamp#` do konwersji wartości w polu `EventDateTime` na datę i godzinę zrozumiałe dla systemu. Po wykonaniu tworzy dodatkowe pole o nazwie `EventTimestamp`.
Skrypt ładowania
```
SET TimestampFormat='M/D/YYYY h:mm:ss[.fff] TT';
Example:
LOAD
Event,
EventDateTime,
Timestamp#(EventDateTime, 'DD-MM-YYYY hh:mm:ss') AS EventTimestamp
INLINE [
Event, EventDateTime
"Login", "12-03-2023 10:25:30"
"Logout", "12-03-2023 12:45:10"
"Login", "13-03-2023 09:10:15"
"Logout", "13-03-2023 17:30:20"
"Login", "14-03-2023 08:00:00"
];
```
Wyniki
Załaduj dane i otwórz arkusz. Utwórz nową tabelę i dodaj te pola jako wymiary:
* ` Event
`
* `EventDateTime`
* `EventTimestamp`
Utwórz następującą miarę:
* `=Timestamp(EventTimestamp)`, aby wyświetlić znacznik czasu przy użyciu formatu dostarczonego w skrypcie ładowania jako ustawienie domyślne.
Tabela wynikowa
| Zdarzenie | EventDateTime | EventTimestamp | Timestamp(EventTimestamp) |
| --- | --- | --- | --- |
| Logowanie | 12-03-2023 10:25:30 | 12-03-2023 10:25:30 | 3/12/2023 10:25:30 AM |
| Logowanie | 13-03-2023 09:10:15 | 13-03-2023 09:10:15 | 3/13/2023 9:10:15 AM |
| Logowanie | 14-03-2023 08:00:00 | 14-03-2023 08:00:00 | 3/14/2023 8:00:00 AM |
| Wyloguj się | 12-03-2023 12:45:10 | 12-03-2023 12:45:10 | 3/12/2023 12:45:10 PM |
| Wyloguj się | 13-03-2023 17:30:20 | 13-03-2023 17:30:20 | 3/13/2023 5:30:20 PM |
W tym przykładzie można zobaczyć, jak wartości mogą być konwertowane przy użyciu funkcji `Timestamp#`.