# Rozszerzenie przez znak dolara przy użyciu wyrażenia

W rozszerzeniach przez znak dolara mogą być używane wyrażenia.

Zawartość między nawiasami musi zaczynać się od znaku równości:

`$(=expression)`

Wyrażenie zostanie ocenione, a wartość będzie używana w rozwinięciu. Na przykład:

```
// returns a string with the current year
$(=Year(Today())); 
```

```
// returns the year before the selected one
$(=Only(Year)-1);
```

## Przykład: wybierz miarę przez odwołanie się do miary w wyrażeniu wykresu.

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/dollar-sign-expansion-using-expression.htm)

#### Przykład: skrypt ładowania

Skrypt ładowania

Załaduj następujące dane jako ładowanie wbudowane w edytorze ładowania danych:

```
// Load string “=MinString(Measure)” into variable VSelectMeasure
Let vSelectMeasure = '=MinString(Measure)';
MyTable1: // Create table and load values for Dim and Sales
Load * inline [
Dim, Sales
A, 150
A, 200
B, 240
B, 230
C, 410
C, 330 ];                      
 
 
MyTable2: // Create table and load aggregations as field values for Measure
Load * Inline [
Measure
avg(Sales)
sum(Sales)
count(distinct Dim)];
```

Aby uzyskać więcej informacji o ładowaniu wbudowanym, zobacz temat [Używanie wbudowanych ładowań do ładowania danych](https://help.qlik.com/pl-PL/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm).

Objaśnienie

Skrypt umożliwia wybranie miary poprzez odwołanie się do miary w wyrażeniu wykresu. Wyrażenie wykresu zawiera rozszerzenie zmiennej `$(=MinString(Measure))`. `MinString()` znajduje wartości ciągu w wyrażeniu i zwraca pierwszą wartość tekstową posortowaną alfabetycznie, w tym przypadku `avg(Sales)`. Umożliwia to interaktywne decydowanie (i wybieranie), którego wyrażenia użyć w wizualizacji, bez uzyskiwania dostępu do obiektu i manipulowania jego właściwościami.

Dane wyjściowe

Utwórz następującą tabelę w Qlik Sense, używając:

* Wymiar: `Dim`

* Miary:

  * `='$(vSelectMeasure)'`

  * `=$(=MinString(Measure))`

  * `Avg(Sales)`

Tabela – rozszerzenie przez znak dolara używające wyrażenia

| Dim | ='$(vSelectMeasure)' | =$(=MinString(Measure)) | Avg(Sales) |
| --- | --- | --- | --- |
| Sumy | - | 260 | 260 |
| A | avg(Sales) | 175 | 175 |
| B | avg(Sales) | 235 | 235 |
| C | avg(Sales) | 370 | 370 |

## Przykład: oblicz przydział między dwoma wymiarami

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/dollar-sign-expansion-using-expression.htm)

#### Przykład: skrypt ładowania

Skrypt ładowania

Załaduj następujące dane jako ładowanie wbudowane w edytorze ładowania danych:

```
Let vDivision = '=MinString(Numerator) / MinString(Denominator)';
Load recno() as Numerator autogenerate 100;
Load recno() as Denominator autogenerate 100;
```

Objaśnienie

Ten skrypt generuje parę pól zawierających po 100 wartości, które działają jako liczniki i mianowniki przy obliczaniu przydziału między nimi. Miara wykresu zawiera rozszerzenie zmiennej ='$( vDivision )', dzięki czemu można interaktywnie decydować (i wybierać), który przydział ma zostać obliczony.

Dane wyjściowe

Utwórz następującą tabelę w Qlik Sense, używając:

* Wymiary:

  * Numerator

  * Denominator

* Miara: ='$(vDivision)'

Na wynikowy przydział (Sumy) mają wpływ wybrane wartości w polach. Numerator (=5) i Denominator (=3) będą obliczane ponownie z każdym nowym wyborem w dowolnym polu.

Tabela – rozszerzenie przez znak dolara jako wyrażenie

| Licznik | Mianownik | ='$(vDivision)' |
| --- | --- | --- |
| Sumy | - | 1,6666666666667 |
| 5 | 3 | 1,6666666666667 |

## Uwzględnianie plików

Operacje uwzględnienia plików są wykonywane przy użyciu rozszerzeń przez znak dolara. Składnia jest następująca:

$(include=filename)

Powyższy tekst zostanie zastąpiony przez treść pliku określonego po znaku równości. Ta opcja przydaje się do przechowywania skryptów albo części skryptów w plikach tekstowych.

Więcej informacji zawiera temat [Include](https://help.qlik.com/pl-PL/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/SystemVariables/Include.htm).

## Rozszerzenia przez znak dolara i stany alternatywne

Rozszerzenie przez znak dolara zwykle nie jest wrażliwe na stany alternatywne. Jeżeli jednak rozszerzenie przez znak dolara ma wyrażenie, jest ono obliczane w stanie dotyczącym obiektu, w którym dokonuje się rozszerzenia przez znak dolara.

Na przykład:

```
$(=Sum(Amount))
```

Obliczenie zwróci sumę kwoty na podstawie wyboru w stanie obiektu.

## Interakcje między rozszerzeniami przez znak dolara a zewnętrznymi wyrażeniami zestawu

W przypadku łączenia rozszerzeń przez znak dolara z zewnętrznymi wyrażeniami zestawu, obowiązuje określona kolejność oceny. Więcej informacji zawiera temat [Zewnętrzne wyrażenia zestawu z rozszerzeniami przez znak dolara](https://help.qlik.com/pl-PL/sense/May2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/outer-set-expression-dollar-sign-expansion.htm).