# match — funkcja skryptu i funkcja wykresu

Funkcja match porównuje pierwszy parametr z wszystkimi kolejnymi parametrami i zwraca liczbową lokalizację z wyrażeń dopasowanych. Wielkość liter w porównaniu ma znaczenie.

Składnia:

match( str, expr1 [ , expr2,...exprN ])

WskazówkaAby dokonywać porównań ignorujących wielkość liter, należy użyć funkcji mixmatch. Aby dokonywać porównań ignorujących wielkość liter i symboli wieloznacznych, należy użyć funkcji wildmatch.

Niektóre przykłady w tym temacie wykorzystują ładowania wbudowane. Więcej informacji zawiera temat [Używanie wbudowanych ładowań do ładowania danych](https://help.qlik.com/pl-PL/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm).

## Przykład — skrypt ładowania używający match

####

Skrypt ładowania

Funkcji match można użyć, aby załadować podzbiór danych. Można na przykład zwrócić wartość liczbową dla wyrażenia w funkcji. Następnie można ograniczyć załadowane dane na podstawie tej wartości liczbowej. W przypadku braku dopasowania funkcja Match zwraca 0. Wszystkie wyrażenia, dla których nie zostanie znalezione dopasowanie, zwrócą w tym przykładzie 0 i zostaną wykluczone z danych ładowanych przez instrukcję WHERE.

Utwórz nową kartę w edytorze ładowania danych, a następnie załaduj następujące dane jako ładowanie wbudowane. Utwórz tabelę poniżej w Qlik Sense, aby zobaczyć wyniki.

```
Transactions:
Load * Inline [
transaction_id, transaction_date, transaction_amount, transaction_quantity, customer_id, size, color_code
3750, 20180830, 23.56, 2, 2038593, L, Red
3751, 20180907, 556.31, 6, 203521, m, orange
3752, 20180916, 5.75, 1, 5646471, S, blue
3753, 20180922, 125.00, 7, 3036491, l, Black
3754, 20180922, 484.21, 13, 049681, xs, Red
3756, 20180922, 59.18, 2, 2038593, M, Blue
3757, 20180923, 177.42, 21, 203521, XL, Black
];
 
/*
Create new table called Transaction_Buckets
Create new fields called Customer, and Color code Blue and Black
Load Transactions table.
Match returns 1 for 'Blue', 2 for 'Black'. 
Does not return a value for 'blue' because match is case sensitive.
Only values that returned numeric value greater than 0 
are loaded by WHERE statement into Transactions_Buckets table.
*/
 
Transaction_Buckets:
Load
 customer_id,
 customer_id as [Customer], 
 color_code as [Color Code Blue and Black]
Resident Transactions
Where match(color_code,'Blue','Black') > 0; 
```

Wyniki

Tabela programu Qlik SenseQlik Sense przedstawiająca wynik użycia funkcji matchmatch w skrypcie ładowania

| Color Code Blue and Black | Customer |
| --- | --- |
| Black | 203521 |
| Black | 3036491 |
| Blue | 2038593 |

## Przykład — wyrażenia wykresu używające match

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/match.htm)

#### Przykłady: wyrażenia wykresu

Wyrażenie wykresu 1

Skrypt ładowania

Utwórz nową kartę w edytorze ładowania danych, a następnie załaduj następujące dane jako ładowanie wbudowane. Po załadowaniu danych utwórz poniższe przykłady wyrażeń wykresu w tabeli Qlik Sense.

```
MyTable:
Load * inline [Cities, Count
Toronto, 123
Toronto, 234
Toronto, 231
Boston, 32
Boston, 23
Boston, 1341
Beijing, 234
Beijing, 45
Beijing, 235
Stockholm, 938
Stockholm, 39
Stockholm, 189
zurich, 2342
zurich, 9033
zurich, 0039];
```

Pierwsze wyrażenie z tabeli poniżej zwraca 0 dla Stockholm, ponieważ „Stockholm” nie znajduje się na liście wyrażeń w funkcji match. Zwraca również 0 dla „Zurich”, ponieważ porównanie match rozróżnia wielkość liter.

Tabela Qlik SenseQlik Sense z przykładami funkcji matchmatch w wyrażeniu wykresu

| Miasta | match( Cities,'Toronto','Boston','Beijing','Zurich') | match( Cities,'Toronto','Boston','Beijing','Stockholm','zurich') |
| --- | --- | --- |
| Beijing | 3 | 3 |
| Boston | 2 | 2 |
| Stockholm | 0 | 4 |
| Toronto | 1 | 1 |
| zurich | 0 | 5 |

Wyrażenie wykresu 2

Funkcji match można użyć, aby wykonać niestandardowe sortowanie dla wyrażenia.

Domyślnie kolumny są posortowane w porządku liczbowym lub alfabetycznym — w zależności od danych.

Tabela aplikacji Qlik SenseQlik Sense pokazująca przykład domyślnego porządku sortowania

| Miasta |
| --- |
| Beijing |
| Boston |
| Stockholm |
| Toronto |
| zurich |

Aby zmienić porządek, wykonaj następujące czynności:

1. W panelu Właściwości otwórz sekcję Sortowanie dla wykresu.

2. Wyłącz automatyczne sortowanie dla kolumny, względem której chcesz wykonać sortowanie niestandardowe.

3. Usuń zaznaczenie opcji Sortuj w kolejności liczbowej i Sortuj alfabetycznie.

4. Zaznacz opcję Sortuj wg wyrażenia, a następnie wprowadź wyrażenie podobne do następującego:

   `=match( Cities, 'Toronto','Boston','Beijing','Stockholm','zurich')`

   Porządek sortowania w kolumnie Cities ulegnie zmianie.

Tabela aplikacji Qlik SenseQlik Sense pokazująca przykład zmiany porządku sortowania za pomocą funkcji matchmatch

| Miasta |
| --- |
| Toronto |
| Boston |
| Beijing |
| Stockholm |
| zurich |

Możesz także wyświetlić zwróconą wartość liczbową.

Tabela aplikacji Qlik SenseQlik Sense pokazująca przykład wartości liczbowych, które są zwracane przez funkcję matchmatch

| Miasta | Cities & ' - ' & match ( Cities, 'Toronto','Boston', 'Beijing','Stockholm','zurich') |
| --- | --- |
| Toronto | Toronto - 1 |
| Boston | Boston - 2 |
| Beijing | Beijing - 3 |
| Stockholm | Stockholm - 4 |
| zurich | zurich - 5 |

## Dowiedz się więcej

* [mixmatch — funkcja skryptu i funkcja wykresu](https://help.qlik.com/pl-PL/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/mixmatch.htm)
* [wildmatch — funkcja skryptu i funkcja wykresu](https://help.qlik.com/pl-PL/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/wildmatch.htm)