# Ładowanie danych z tabel wbudowanych
Wpisz dane ręcznie do skryptu, aby zdefiniować tabelę wbudowaną.
Tabele wbudowane tworzy się, wpisując dane ręcznie do skryptu, zamiast łączyć się z plikami i bazami danych. Użyj wymaganej składni, aby wskazać, że tekst skryptu ma być interpretowany jako dane wbudowane.
Podstawowe ładowanie wbudowane tworzy tabelę i wstawia pola danych oraz rekordy.
## Dlaczego warto korzystać z ładowań wbudowanych?
Ładowania wbudowane mogą być pomocne w wielu zastosowaniach:
* Administrowanie i edytowanie danych bez konieczności łączenia się ze źródłami zewnętrznymi.
* Uzupełnianie istniejących danych w modelu danych. Można na przykład dodać dodatkową tabelę do modelu danych, który pochodzi głównie ze źródeł bazodanowych.
* Dodawanie danych, których ciągłego ładowania ze źródeł zewnętrznych chcesz uniknąć. Może to zaoszczędzić czas, jeśli wiesz, że źródło danych może się zmienić w przyszłości, ale wartości danych pozostaną takie same.
* Łatwość kopiowania i wklejania zawartości do skryptu z innych plików. Na przykład plików .csv lub tabel z dokumentów edytora tekstu.
* Tworzenie skryptów testowych, które można szybko kopiować i wklejać.
## Podstawowy przykład składni
Poniższy skrypt zawiera proste ładowanie wbudowane.
```
MyTable:
Load * Inline [Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
];
```
Do powyższego ładowania wbudowanego używana jest następująca składnia:
* Load \* Inline instruuje QlikView, aby załadować wszystkie pola z poniższej tabeli wbudowanej.
* MyTable: definiuje nazwę tabeli.
* Nawiasy kwadratowe zamykają dane.
* Pierwszy wiersz instrukcji ładowania definiuje pola danych.
* Przecinki oddzielają pola danych i rekordy.
* Średnik zamyka instrukcję ładowania.
## Przegląd składni
### Nazywanie tabeli
Tak jak w przypadku innych ładowanych tabel możesz dodać nazwę tabeli wbudowanej. Zdefiniowanie nazwy tabeli jest opcjonalne.
Po nazwie tabeli wstaw dwukropek.
### Instrukcje LOAD i inline
Tabela wbudowana jest ładowana z klauzulą inline, gdy używasz instrukcji LOAD skryptu. Klauzula inline wskazuje, że dalszy tekst w tabeli będzie zawierać dane ręcznie wpisane do edytora. O ile nie wskazano inaczej, tabela wbudowana używa formatu txt zgodnego ze strukturą pliku tekstowego z rozdzielanymi wartościami.
Więcej informacji na temat instrukcji LOAD zawiera temat [Load](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm).
### Znaki do ujmowania danych i wprowadzanie danych
Dane wprowadzane przez klauzulę inline muszą być ujęte w określone znaki. Dopuszczalne kombinacje znaków do ujmowania danych:
* Nawiasy kwadratowe: `[` i `]`
* Podwójne cudzysłowy: `"` i `"`
* Pojedyncze cudzysłowy: `'` i `'`
* Grawisy: `` ` `` i `` ` ``
Znak wybrany do ujmowania danych może pomóc w ładowaniu danych wbudowanych zawierających znaki, które powodują konflikty. Jeżeli na przykład Twoje dane zawierają rekordy ujęte w nawiasy kwadratowe, możesz zamiast tego ująć je w cudzysłów lub grawisy.
Przykłady alternatywnych znaków do ujmowania danych zawiera temat [Przykład – alternatywne znaki do ujmowania danych](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDataEnc).
Jeżeli nie określisz alternatywnego formatu tabeli (domyślnie jest to txt), tekst pomiędzy znakami do ujmowania danych będzie interpretowany tak samo jak zawartość pliku. Oznacza to między innymi, że w tekście klauzuli inline należy wstawiać nowe wiersze w tych samych miejscach, w których występowałyby w pliku tekstowym: naciskając klawisz Enter podczas wpisywania skryptu.
### Kończenie ładowania wbudowanego
Koniec instrukcji ładowania wbudowanego jest oznaczany średnikiem.
### Transformacje danych
W prostym ładowaniu wbudowanym bez transformacji liczba kolumn jest określona w pierwszym wierszu. W tabeli ładowanej w następującym przykładzie są trzy kolumny: `Product_ID`, `Supplier_Name` i `Product_Category`.
```
Products:
Load * Inline [
Product_ID, Supplier_Name, Product_Category
1, Paracel, Home Decor
2, PageWave, Electronics
3, Talarian, Software
4, Userland, Appliances
];
```
Możesz także wykonywać przekształcenia i tworzyć nowe kolumny w tej samej tabeli wbudowanej. Można użyć poprzedzających ładowań, a do załadowania tej samej tabeli można użyć więcej niż jednej instrukcji LOAD.
Konkretne przykłady zawiera temat [Przykłady — ładowanie wbudowane z transformacjami](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExTransform).
### Konfigurowanie specyfikacji formatu w ładowaniu wbudowanym
Podobnie jak w przypadku innych ładowanych tabel, specyfikację formatu tabeli wbudowanej można modyfikować za pomocą elementów specyfikacji formatu. Specyfikacja formatu jest dodawana w nawiasach. Należy ją dodać po znakach do ujmowania danych, ale przed średnikiem kończącym instrukcję LOAD. Dodać można między innymi następujące dostosowania:
* Zmiana ogranicznika z przecinka na inny znak. Przykłady zawiera temat [Przykłady — alternatywne ograniczniki](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDelimiter).
Zobacz: [Delimiter](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/delimiter.htm)
* Pomijanie nagłówków kolumn tabeli. Na przykład zobacz temat [Przykład — pominięcie nagłówków kolumn](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOmitLabels).
Zobacz: [Labels](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/labels.htm)
* Używanie innego formatu danych (na przykład stałego formatu rekordu). Na przykład zobacz temat [Przykład — ładowanie innego typu danych](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExChangeFormat).
Zobacz: [Table format](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/table-format.htm)
InformacjaNie wszystkie opcje Table format są obsługiwane w przypadku ładowania wbudowanego.
* Zezwalanie na zawartość wielowierszową. Na przykład zobacz temat [Przykład — zawartość wielowierszowa](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExMultLine).
Zobacz: [Quotes](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/quotes.htm)
Aby użyć wielu elementów specyfikacji formatu w tej samej tabeli, oddziel je przecinkami. Na przykład:` (Delimiter is '|', no labels) `
Szczegółowe informacje na temat specyfikacji formatu zawiera temat [Elementy specyfikacji formatu](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm).
### Operatory i inne klauzule
Ponadto, ponieważ ładowanie wbudowane jest instrukcją LOAD, możesz połączyć inne argumenty instrukcji LOAD w ładowaniu wbudowanym. Na przykład użyj klauzuli where lub while, aby określić, czy załadować określony wiersz, czy nie, na podstawie zawartego w nim tekstu.
Podobnie możesz używać operatorów poza samą treścią tekstową. Dzięki operatorom możesz dostosować sposób przekształcania danych wbudowanych, a także określić, kiedy ładować określone dane, a kiedy nie.
Konkretne przykłady zawiera temat [Przykład — operatory transformacji i klauzul](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOpsAndClauses).
## Przykład – alternatywne znaki do ujmowania danych
Aby ująć ładowanie wbudowane, możesz użyć nawiasów kwadratowych, cudzysłowów lub grawisów. W tej sekcji zilustrowano to na przykładzie. Więcej informacji zawiera temat [Znaki do ujmowania danych i wprowadzanie danych](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Enclosure).
#### Skrypt ładowania i wyniki
Przegląd
Ten przykład pokazuje, jak można użyć grawisów do ujęcia danych wbudowanych. Dane w przykładzie zawierają nawiasy kwadratowe, co powoduje, że nawiasy kwadratowe nie są kompatybilne jako znaki do ujmowania danych w instrukcji LOAD .
Skrypt ładowania
```
DataTable:
Load * inline
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;
```
Wyniki
* `custom_property`
* `date`
* `amount`
Tabela wyników
| custom\_property | date | amount |
| --- | --- | --- |
| [11402] | 1/1/2024 | 92.99 |
| [11403] | 1/2/2024 | 102.34 |
| [11404] | 1/3/2024 | 50.26 |
| [11405] | 1/4/2024 | 153.69 |
| [11406] | 1/5/2024 | 75.62 |
## Przykłady — alternatywne ograniczniki
Do oddzielania wartości kolumn w tabeli można używać znaku innego niż przecinek. Więcej informacji zawiera temat [Konfigurowanie specyfikacji formatu w ładowaniu wbudowanym](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Skrypt ładowania i wyniki
Przegląd
Zamiana ogranicznika jest przydatna, gdy dane w tabeli zawierają przecinki, które w przeciwnym razie sygnalizowałyby przejście do następnej kolumny w tabeli.
Ten przykład zawiera:
* Cztery tabele do załadowania. Są to:
* Table1: ogranicznik to kreska pionowa. Dane w kolumnie Phrase zawierają przecinki.
* Table2: ogranicznikiem jest dwukropek.
* Table3: ogranicznikiem jest ukośnik odwrotny.
* Table4: tabela jest rozdzielana przez naciśnięcie klawisza Tab na klawiaturze. Ta opcja jest przydatna podczas kopiowania tabeli z edytora tekstu i wklejania jej do skryptu.
Table1 przedstawia praktyczne zastosowanie alternatywnego ogranicznika. Pozostałe tabele pokazują więcej opcji ograniczników.
Skrypt ładowania
```
Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');
Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');
Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);
Table4:
LOAD * INLINE [
Num3 Chr3
1 A
2 B ] (Delimiter is '\t');
```
Wyniki
Tabela wyników: Table1Table1
| ID | Phrase |
| --- | --- |
| 1 | The transaction was complete, but the order has not yet shipped. |
| 2 | We need to confirm the following details: sales rep number, order status, and shipping priority. |
Tabela wyników: Table2Table2
| Num1 | Chr1 |
| --- | --- |
| 1 | A |
| 2 | B |
Tabela wyników: Table3Table3
| Num2 | Chr2 |
| --- | --- |
| 1 | A |
| 2 | B |
Tabela wyników: Table4Table4
| Num3 | Chr3 |
| --- | --- |
| 1 | A |
| 2 | B |
## Przykład — pominięcie nagłówków kolumn
Edytuj specyfikację formatu, aby załadować tabelę wbudowaną bez definiowania nagłówków kolumn. Odbywa się to za pomocą specyfikacji labels (ustawienia jej na wartość no labels). Więcej informacji zawiera temat [Konfigurowanie specyfikacji formatu w ładowaniu wbudowanym](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
Kiedy ładujesz tabelę bez definiowania nazw kolumn, automatycznie używane są nazwy kolumn zdefiniowane przez system.
#### Skrypt ładowania i wyniki
Przegląd
Ten przykład ilustruje sposób ładowania tabeli wbudowanej bez definiowania nazw kolumn.
Skrypt ładowania
```
Expenses:
Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);
```
Wyniki
Tabela wyników
| @1 | @2 | @3 |
| --- | --- | --- |
| 1 | Category1 | 40566.49 |
| 2 | Category2 | 3504.54 |
| 3 | Category3 | 593206.30 |
## Przykład — ładowanie innego typu danych
Ten przykład ilustruje sposób ładowania tabeli wbudowanej w ustalonym formacie rekordu. Zobacz temat [Konfigurowanie specyfikacji formatu w ładowaniu wbudowanym](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Skrypt ładowania i wyniki
Przegląd
Ten przykładowy skrypt zawiera następujące elementy:
* Instrukcja ładowania wbudowanego definiująca tabelę DataTable.
* Użycie fix (jako części specyfikacji Table format) do wskazania, że dane do załadowania mają ustalony format rekordu.
Skrypt ładowania
```
DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a b c d
1 2 3 4
x y z w
] (fix, utf8, embedded labels);
```
Wyniki
Tabela wyników
| a | b | c | d |
| --- | --- | --- | --- |
| 1 | 2 | 3 | 4 |
| x | y | z | w |
## Przykład — zawartość wielowierszowa
Ten przykład ilustruje sposób wprowadzania wielowierszowej zawartości pól do tabeli wbudowanej. Zobacz temat [Konfigurowanie specyfikacji formatu w ładowaniu wbudowanym](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Skrypt ładowania i wyniki
Przegląd
Ten przykładowy skrypt zawiera następujące elementy:
* Prosta wbudowana instrukcja load w celu zdefiniowania tabeli T1.
* Użycie specyfikatora Quotes (z wartością msq) do obsługi zawartości wielowierszowej.
* Wartości długości są określone w stopach i calach.
* Symbol podwójnego cudzysłowu (") oznacza koniec wpisu wielowierszowego. W tym przykładzie ten sam symbol jest również używany do oznaczenia wartości w calach. Ma to na celu pokazanie składni i wynikającego z niej postępowania, jeśli trzeba użyć obu w tej samej instrukcji LOAD. Wprowadzenie symbolu " składającego się z dwóch kolejnych znaków ("") oznacza zasadniczo, że kod należy interpretować jako pojedynczą instancję tekstową symbolu.
Skrypt ładowania
```
T1:
Load *, recno() as ID inline [
Length
"1' 2""
22' 10"""
14' 8" ] (msq);
```
Wyniki
Aby zawartość wielowierszowa była wyświetlana zgodnie z zamierzeniami, w konfiguracji Właściwości... musi być włączone ustawienie Zawijaj tekst w komórkach.
Tabela wyników
| ID | Length |
| --- | --- |
| 1 | 1' 2"
22' 10" |
| 2 | 14' 8" |
W powyższej tabeli rekord o wartości ID wynoszącej 1 zawiera treść wielowierszową.
## Przykłady — ładowanie wbudowane z transformacjami
W tych przykładach pokazano, jak można wykonywać obliczenia na polach ładowanych w sposób wbudowany, aby utworzyć nowe pola w modelu danych.
Więcej informacji zawiera temat [Transformacje danych](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Transform).
#### Przykład: prosta zmiana nazwy pola
Skrypt ładowania
```
ORDERS:
Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];
```
Wyniki
Tabela wyników
| Original | Updated |
| --- | --- |
| ProductA | ProductA |
| ProductB | ProductB |
| ProductC | ProductC |
#### Przykład: proste wstawienie pola ID
Przegląd
Ten przykład pokazuje, jak można zdefiniować pole wyliczane wskazujące identyfikator każdego wiersza danych bez konieczności ręcznego wpisywania każdej wartości identyfikatora.
Skrypt ładowania
```
ORDERS:
Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];
```
Wyniki
Tabela wyników
| ID | ProductName |
| --- | --- |
| 1 | A |
| 2 | B |
| 3 | C |
| 4 | D |
| 5 | E |
#### Przykład: konfigurowanie instrukcji LOAD do obsługi transformacji
Przegląd
Ten przykład pokazuje kilka sposobów zastosowania prostej transformacji do danych wbudowanych. Można użyć jednej lub wielu instrukcji LOAD oraz skonfigurować składnię na różne sposoby, aby określić, czy transformacja zastępuje oryginalne pole, nie zastępuje, czy też ładowane są zarówno oryginalne, jak i nowe pole.
W szczególności zwróć uwagę na następujące różnice i ich wpływ na wynik:
* Liczba instrukcji LOAD w tabeli.
* Obecność lub brak symbolu \* (ładuje wszystkie kolejne pola).
* Obecność lub brak przecinków (symbol ,).
Ten przykładowy skrypt zawiera następujące elementy:
* Cztery tabele, z których wszystkie odwołują się do tych samych danych. Nazwy pól są różne.
* DerivedYears1: używa dwóch instrukcji LOAD do załadowania kolumny wbudowanej i kolumny zawierającej transformację kolumny wbudowanej.
* DerivedYears2: używa dwóch instrukcji LOAD. Skrypt ładuje kolumnę wbudowaną, a następnie ładuje pole wyliczane przekształcone z oryginalnej kolumny. W przypadku drugiej instrukcji LOAD pierwotna kolumna nie jest ładowana do tabeli, co w efekcie powoduje, że nowe pole zastępuje pole pierwotne.
* DerivedYears3: używa pojedynczej instrukcji LOAD do załadowania zarówno pierwotnej kolumny wbudowanej, jak i kolumny przekształconej.
* DerivedYears4: używa pojedynczej instrukcji LOAD do zdefiniowania pola wbudowanego i transformacji tego pierwotnego pola. Do tabeli ładowane jest tylko przekształcone pole.
Skrypt ładowania
```
DerivedYears1:
Load *,
Year(initial_date1) as derived_year1
;
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears2:
Load
Year(initial_date2) as derived_year2
;
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears3:
Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears4:
Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
```
Wyniki
Tabela wyników: DerivedYears1DerivedYears1
| initial\_date1 | derived\_year1 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Tabela wyników: DerivedYears2DerivedYears2
| derived\_year2 |
| --- |
| 2022 |
| 2023 |
| 2024 |
Tabela wyników: DerivedYears3DerivedYears3
| initial\_date3 | derived\_year3 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Tabela wyników: DerivedYears4DerivedYears4
| derived\_year4 |
| --- |
| 2022 |
| 2023 |
| 2024 |
#### Przykład: modyfikowanie zawartości pola
Przegląd
Załóżmy, że wklejasz informacje z dużego pliku tekstowego do edytora skryptów, ale chcesz dodatkowo przetworzyć rekordy w zestawie danych. Na przykład chcesz usunąć określone znaki oraz prefiksy i zapisać każde słowo wielką literą.
Ten przykładowy skrypt zawiera następujące elementy:
* Tabela wbudowana Transformations, w której zdefiniowano transformację zmieniającą zawartość tekstową pola. Następnie dodawany jest przekształcany tekst.
* Dwie instrukcje LOAD. W przypadku konfiguracji z przykładu do tabeli ładowane jest tylko pochodne pole ProductName\_Trimmed.
Skrypt ładowania
```
Transformations:
Load
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;
Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product: {snack food}
Product: {electronics and video games}
];
```
Wyniki
Tabela wyników
| ProductName\_Trimmed |
| --- |
| Soft Drinks And Other Beverages |
| Snack Food |
| Electronics And Video Games |
## Przykład — operatory transformacji i klauzul
Do definiowania transformacji i konkretnych klauzul w instrukcji LOAD można używać operatorów. Więcej informacji zawiera temat [Operatory i inne klauzule](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#OpsAndClauses).
[Operatory](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/Operators/operators.htm)
#### Skrypt ładowania i wyniki
Przegląd
Ten przykładowy skrypt zawiera następujące elementy:
* Prosta wbudowana instrukcja load w celu zdefiniowania tabeli Purchases.
* Wstawienie pola wyliczanego, OrderSize. To pole jest transformacją pola amount z wbudowanego zestawu danych. Klasyfikuje zakupy jako małe i duże w zależności od tego, czy kwota przekracza 2000,00 USD.
* Klauzula where uniemożliwiająca ładowanie rekordów, gdy wartość amount jest mniejsza niż 0,05 USD.
Skrypt ładowania
```
Purchases:
Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,
* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;
```
Wyniki
Tabela wyników
| ID | amount | OrderSize |
| --- | --- | --- |
| 1 | 2660.39 | Large Purchase |
| 2 | 100.01 | Small Purchase |
| 3 | 500.42 | Small Purchase |
| 4 | 5023.99 | Large Purchase |
| 6 | 2002.39 | Large Purchase |
| 7 | 31034.53 | Large Purchase |
| 8 | 1643.58 | Small Purchase |
| 9 | 3993.65 | Large Purchase |
| 10 | 614.34 | Small Purchase |
| 11 | 675.93 | Small Purchase |
W powyższej tabeli transakcja z ID 5 nie została załadowana do tabeli. Jest tak dlatego, że wartość amount wynosi mniej niż 0,05 USD.
## Przykład — tworzenie wartości null w tabeli wbudowanej
W tym przykładzie przedstawiono, jak można użyć zmiennej NullInterpret do tworzenia wartości null w danych wbudowanych.
[NullInterpret](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ValueHandlingVariables/NullInterpret.htm)
#### Skrypt ładowania i wyniki
Przegląd
Ten przykładowy skrypt zawiera następujące elementy:
* Prosta wbudowana instrukcja load w celu zdefiniowania tabeli T2.
* Zmienna NullInterpret zdefiniowana jako dwa pojedyncze cudzysłowy. Po załadowaniu skryptu rekordy zawierające tę wartość są przetwarzane jako wartości null.
Skrypt ładowania
```
set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];
```
Wyniki
Tabela wyników
| Test |
| --- |
| x |
W powyższej tabeli pierwszy rekord ma wartość null. W związku z tym nie jest uwzględniony w wizualizacji. Wartości null występujące w tabelach z dodatkowymi wymiarami zostałyby oznaczone symbolem -.
## Więcej przykładów
Dodatkowe przykłady zawiera temat [Load](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm).
## Dowiedz się więcej
* [Load](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm)
* [Elementy specyfikacji formatu](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm)
* [Kreator danych wbudowanych](https://help.qlik.com/pl-PL/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Inline_Data_Wizard.htm)