# Above — funkcja wykresu

Funkcja Above() oblicza wartość wyrażenia w wierszu znajdującym się nad bieżącym wierszem w ramach segmentu kolumny w tabeli. Wiersz wybierany do obliczeń zależy od wartości opcjonalnego parametru offset — domyślnie jest to wiersz bezpośrednio poprzedzający bieżący. W przypadku wykresów niebędących tabelami funkcja Above() oblicza wartość dla wiersza poprzedzającego bieżący w tabeli prostej odpowiadającej wykresowi.

Składnia:

Above([TOTAL] expr [ , offset [,count]])

Typ zwracanych danych: wartość podwójna

Argumenty

| Argument | Opis |
| --- | --- |
| expr | Wyrażenie lub pole zawierające mierzone dane. |
| offset | Określenie wartości offset n większej niż 0 umożliwia przeniesienie oceny wyrażenia o n wierszy w górę z bieżącego wiersza.<br><br>Podanie argumentu offset równego 0 spowoduje ocenę wartości wyrażenia w bieżącym wierszu.<br><br>Określenie ujemnej wartości argumentu offset sprawia, że funkcja Above działa tak samo jak funkcja Below z odpowiednią dodatnią wartością argumentu offset. |
| count | Jeśli trzeci argument count będzie większy od 1, funkcja zwróci zakres wartości count, po jednej dla każdego z count wierszy tabeli liczonych w górę od pierwotnej komórki.<br><br>W tej postaci funkcja może być używana jako argument dla specjalnych funkcji zakresu. [Funkcje zakresu](https://help.qlik.com/pl-PL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/RangeFunctionsInCharts.htm) |
| TOTAL | Jeśli tabela jest jednowymiarowa lub jako argument zostanie podany kwalifikator TOTAL, bieżący segment kolumny jest zawsze równy całej kolumnie.<br><br>[Określenie zakresu agregacji](https://help.qlik.com/pl-PL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |

W przypadku pierwszego wiersza segmentu kolumny zostanie zwrócona wartość NULL, ponieważ nie ma żadnego wiersza nad tym wierszem.

InformacjaSegment kolumny definiuje się jako ciągły podzbiór komórek o tych samych wartościach dla wymiarów w bieżącej kolejności sortowania. Międzywierszowe funkcje wykresu są obliczane w segmencie kolumny z pominięciem skrajnego prawego wymiaru w równoważnym wykresie tabeli prostej. Jeśli wykres ma tylko jeden wymiar lub jeśli podano kwalifikator TOTAL, wartość wyrażenia jest obliczana na pełnej tabeli.

InformacjaJeśli tabela lub równoważnik tabeli zawiera wiele wymiarów pionowych, wówczas segment bieżącej kolumny będzie zawierał tylko wiersze z takimi samymi wartościami we wszystkich kolumnach wymiaru jak bieżący wiersz, ale bez kolumny przedstawiającej ostatni wymiar w kolejności sortowania między polami.

Ograniczenia:

* Wywołania rekurencyjne będą zwracać NULL.

* Sortowanie według wartości Y w wykresach albo sortowanie według kolumn wyrażeń w tabelach jest niedozwolone, gdy w dowolnym z wyrażeń wykresu stosowana jest ta funkcja wykresu. W takiej sytuacji te opcje sortowania są automatycznie wyłączone. Kiedy używasz tej funkcji wykresu w wizualizacji albo tabeli, sortowanie wizualizacji zostanie przywrócone do sortowania danych wejściowych tej funkcji.

Przykład: wyrażenia wykresu

| Przykład | Wynik |
| --- | --- |
| `Above( Sum(Sales) )` | Zwraca wartość `Sales` dla wiersza powyżej bieżącego wiersza. |

## Przykład — podstawy Above

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Wyrażenie wykresu

Przegląd

Otwórz Edytor ładowania danych i poniżej dodaj skrypt ładowania do nowej sekcji.

Skrypt ładowania zawiera:

* Zestaw danych załadowany do tabeli o nazwie `Example`.

* Tabela zawiera następujące pola:

  * `Year`

  * `Sales`

Skrypt ładowania

```
Example:
LOAD * INLINE [
Year, Sales
2019, 1000
2020, 1500
2021, 1200
2022, 1800
2023, 1700
];
```

Wyniki

Załaduj dane i otwórz arkusz. Utwórz nową tabelę i dodaj to pole jako wymiar:

* `Year`

Utwórz następujące miary:

* `=Sum(Sales)` w celu znalezienia sprzedaży rocznej.

* `=Above(Sum(Sales))` w celu znalezienia wartości sprzedaży za poprzedni rok.

* `=Sum(Sales) - Above(Sum(Sales))` w celu obliczenia odchylenia między wartością `Sales` w bieżącym roku a wartością w roku poprzednim.

* `=RangeSum(Above(Sales, 1, 2))` w celu wykazania kroczącej dwuletniej agregacji sprzedaży z poprzednich dwóch lat.

* `=(Sales - Above(Sales)) / Above(Sales)` w celu zwrócenia zmiany `Sales` jako stosunku/procentu. Aby wyświetlić tę wartość w procentach, w sekcji Formatowanie liczb wybierz opcję Liczba &gt; Formatowanie proste &gt; 12,34%.

Tabela wynikowa

| Year | Sum(Sales) | Above(Sum(Sales)) | Sum(Sales) - Above(Sum(Sales)) | RangeSum(Above(Sales, 1, 2) | (Sales - Above(Sales)) / Above(Sales) |
| --- | --- | --- | --- | --- | --- |
| Totals | 7200 | - | - | 0 | - |
| 2019 | 1000 | - | - | 0 | - |
| 2020 | 1500 | 1000 | 500 | 1000 | 50.00% |
| 2021 | 1200 | 1500 | -300 | 2500 | -20.00% |
| 2022 | 1800 | 1200 | 600 | 2700 | 50.00% |
| 2023 | 1700 | 1800 | -100 | 3000 | -5.56% |

Patrząc na wyniki, można porównać wartości `Sales` w bieżącym okresie z poprzednim okresem.

* Miara `Sum(Sales)- Above(Sum(Sales))` zwraca zmianę wartości `Sales` poprzez porównanie bieżącego okresu z poprzednim okresem.

* Miara `RangeSum(Above(Sales, 1, 2))` zwraca sumę dwóch poprzednich wartości `Sales`.

* Miara `(Sales - Above(Sales)) / Above(Sales)` zwraca zmianę wartości `Sales` w porównaniu z poprzednim okresem jako wartość procentową.

WskazówkaTej funkcji można też używać w wykresach innego rodzaju niż tabele, na przykład wykresach słupkowych.

Wykonaj następujące czynności:

Utwórz wykres słupkowy i dodaj to pole jako wymiar:

* `Year`

Utwórz następującą miarę:

* `=Sum(Sales) - Above(Sum(Sales))` w celu zwrócenia odchylenia rok do roku.

Wykres słupkowy przedstawiający wyniki funkcji Above

Wykres słupkowy przedstawiający wyniki funkcji Above

Wykres słupkowy przedstawiający wyniki funkcji AboveAbove ![Wykres słupkowy pokazujący odchylenie rok do roku dla sumy sprzedaży](https://help.qlik.com/pl-PL/cloud-services/Subsystems/Hub/Content/Resources/Images/scripting-functions-above-example.png)

Użycie funkcji `Above` na wykresie słupkowym zapewnia wizualne porównanie odchylenia między sprzedażą w bieżącym okresie a poprzednim okresem.

## Przykład — zastosowanie Above

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Wyrażenie wykresu

Przegląd

Otwórz Edytor ładowania danych i poniżej dodaj skrypt ładowania do nowej sekcji.

Skrypt ładowania zawiera:

* Zestaw danych załadowany do tabeli o nazwie `Example`.

* Tabela zawiera następujące pola:

  * `SalesYear`

  * `SalesAmount`

Skrypt ładowania

```
Example:
LOAD * INLINE [
SalesYear, SalesAmount
2019, 500
2020, 800
2021, 400
2022, 700
2023, 600
];
```

Wyniki

Załaduj dane i otwórz arkusz. Utwórz nową tabelę i dodaj to pole jako wymiar:

* `SalesYear`

Utwórz następujące miary:

* `=Sum(SalesAmount)` w celu agregacji sprzedaży.

* `=RangeSum(Above(SalesAmount, 0, RowNo()))` w celu obliczenia bieżącej sumy wartości `SalesAmount`.

Tabela wynikowa

| SalesYear | Sum(SalesAmount) | RangeSum(Above(SalesAmount, 0, RowNo())) |
| --- | --- | --- |
| Totals | 3000 | 0 |
| 2019 | 500 | 500 |
| 2020 | 800 | 1300 |
| 2021 | 400 | 1700 |
| 2022 | 700 | 2400 |
| 2023 | 600 | 3000 |

Wyniki pokazują, jak można użyć kombinacji funkcji `RangeSum` i funkcji `Above`, aby utworzyć skumulowaną sumę bieżącą.

WskazówkaTej funkcji można też używać w wykresach innego rodzaju niż tabele, na przykład wykresach słupkowych.

Wykonaj następujące czynności:

Utwórz wykres słupkowy i dodaj to pole jako wymiar:

* `SalesYear`

Utwórz następującą miarę:

* `=RangeSum(Above(SalesAmount, 0, RowNo()))` w celu zwrócenia skumulowanej wartości sprzedaży.

Wykres słupkowy pokazujący skumulowaną wartość sprzedaży według roku

Wykres słupkowy pokazujący skumulowaną wartość sprzedaży według roku

Wykres słupkowy pokazujący skumulowaną wartość sprzedaży według roku ![Wykres słupkowy pokazujący skumulowaną wartość sprzedaży według roku sprzedaży.](https://help.qlik.com/pl-PL/cloud-services/Subsystems/Hub/Content/Resources/Images/scripting-functions-above-example2.png)

## Przykład — wyrażenie wykresu używające Above

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Wyrażenie wykresu

Przegląd

Otwórz Edytor ładowania danych i poniżej dodaj skrypt ładowania do nowej sekcji.

Skrypt ładowania zawiera:

* Dwie tabele danych o nazwach `Monthnames` i `Sales2013`.

Skrypt ładowania

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];
Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');
```

Wyniki

Załaduj dane i otwórz arkusz. Utwórz nową tabelę i dodaj to pole jako wymiar:

* `Customer`

Utwórz następujące miary:

* `=Sum(Sales)` w celu obliczenia sumy sprzedaży.

* `=Above(Sum(Sales))` w celu pokazania sumy sprzedaży w poprzednim wierszu.

* `=Sum(Sales)+Above(Sum(Sales))`, aby zsumować sumę wartości sprzedaży z sumą sprzedaży dla wiersza klienta powyżej bieżącego wiersza.

* `=Sum(Sales)+Above(Sum(Sales), 3)`, aby zsumować wartość `Sum(Sales)` dla bieżącego wiersza w kolumnie `Customer` z wartością `Customer` trzy wiersze powyżej.

* `=IF(Sum(Sales)>Above(Sum(Sales)), 'Higher')` w celu dodania etykiety „`Higher`” do klientów, których wyniki `Sum(Sales)` są większe niż `Sum(Sales)` klienta w wierszu powyżej.

Tabela wynikowa

| Customer | Sum(Sales) | Above(Sum(Sales)) | Sum(Sales)+Above(Sum(Sales)) | Sum(Sales)+Above(Sum(Sales), 3) | IF(Sum(Sales)&gt;Above(Sum(Sales)), 'Higher') |
| --- | --- | --- | --- | --- | --- |
| Totals | 2566 | - | - | - | - |
| Astrida | 587 | - | - | - | - |
| Betacab | 539 | 587 | 1126 | - | - |
| Canutility | 683 | 539 | 1222 | - | Higher |
| Divadip | 757 | 683 | 1440 | 1344 | Higher |

Miara `Above(Sum(Sales))` zwraca NULL dla klienta `Astrida`, ponieważ nie ma nad nią wiersza. Wynik dla klienta `Betacab` pokazuje wartość `Sum(Sales)` dla `Astrida`. Wynik `Canutility` pokazuje wartość `Sum(Sales)` dla `Betacab` i tak dalej.

Dla miary `Sum(Sales)+Above(Sum(Sales))` wiersz dotyczący `Betacab` zwraca wynik dodania wartości `Sum(Sales)` dla wierszy `Betacab` + `Astrida` (`539+587`). Wynik wiersza `Canutility` pokazuje wynik dodania wartości `Sum(Sales)` dla `Canutility` + `Betacab` (`683+539`).

Miara `Sum(Sales)+Above(Sum(Sales), 3)` ma argument `offset` ustawiony na `3`. Pobiera wartość w wierszu, który znajduje się 3 wiersze powyżej bieżącego wiersza. W efekcie jej działania wartość `Sum(Sales)` dla bieżącego wiersza w kolumnie `Customer` jest dodawana do wartości wiersza w kolumnie `Customer` znajdującej się o trzy wiersze powyżej. Na przykład, `Sum(Sales)` dla `Divadip`, jest dodawane do `Sum(Sales)` dla `Astrida`, klienta znajdującego się trzy wiersze powyżej `Divadip`. Dla pierwszych 3 wierszy w kolumnie `Customer` zwracane są wartości null, ponieważ nie ma danych.

Miara `IF(Sum(Sales)>Above(Sum(Sales)), 'Higher')` zwraca wartość `Higher` dla klientów `Canutility` i `Divadip`, ponieważ ich wyniki sprzedaży są wyższe niż suma sprzedaży klientów w wierszu powyżej, odpowiednio `Betacab` i `Canutility`.

WskazówkaTej funkcji można też używać w wykresach innego rodzaju niż tabele, na przykład wykresach słupkowych.

WskazówkaW przypadku innych typów wykresu należy przekształcić wykres w odpowiadającą mu tabelę prostą, aby umożliwić łatwe interpretowanie wiersza, do którego odnosi się funkcja.

## Przykład — zastosowanie Above oparte na kolejności sortowania

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Wyrażenie wykresu

Przegląd

Otwórz Edytor ładowania danych i poniżej dodaj skrypt ładowania do nowej sekcji.

Skrypt ładowania zawiera:

* Trzy tabele danych o nazwach Monthnames, Sales2013 i Product.

Skrypt ładowania

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];

Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');

Product:
LOAD * inline [
Customer|Product|OrderNumber|UnitSales|UnitPrice
Astrida|AA|1|4|16
Astrida|AA|7|10|15
Astrida|BB|4|9|9
Betacab|CC|6|5|10
Betacab|AA|5|2|20
Betacab|BB||| 25
Canutility|AA|||15
Canutility|CC| ||19
Divadip|CC|2|4|16
Divadip|DD|3|1|25
] (delimiter is '|');
```

```

                                
```

Wyniki

Załaduj dane i otwórz arkusz. Utwórz nową tabelę i dodaj te pola jako wymiary:

* Customer

* Product

* Month

Utwórz następujące miary:

* =Sum(Sales) w celu obliczenia sumy sprzedaży.

* =Above(Sum(Sales)) w celu pokazania sumy sprzedaży w poprzednim wierszu.

Tabela wynikowa

| Customer | Product | Month | Sum(Sales) | Above(Sum(Sales)) |
| --- | --- | --- | --- | --- |
| Totals | - | - | 2566 | - |
| Astrida | AA | Jan | 46 | - |
| Astrida | AA | Feb | 60 | 46 |
| Astrida | AA | Mar | 70 | 60 |
| Astrida | AA | Apr | 13 | 70 |
| Astrida | AA | May | 78 | 13 |
| Astrida | AA | Jun | 20 | 78 |
| Astrida | AA | Jul | 45 | 20 |
| Astrida | AA | Aug | 65 | 45 |
| Astrida | AA | Sep | 78 | 65 |
| Astrida | AA | Oct | 12 | 78 |
| Astrida | AA | Nov | 78 | 12 |
| Astrida | AA | Dec | 22 | 78 |
| Astrida | BB | Jan | 46 | - |
| Astrida | BB | Feb | 60 | 46 |

W przypadku wykresów wielowymiarowych wyniki wyrażeń zawierających funkcje Above, Below, Top i Bottom są zależne od kolejności sortowania wymiarów kolumn przez Qlik Sense. Qlik Sense oblicza wartości funkcji na podstawie segmentów kolumny uzyskanych z wymiaru sortowanego jako ostatni. Kolejność sortowania kolumn określa się w panelu właściwości w sekcji Sortowanie i może ona być inna od kolejności wyświetlania kolumn w tabeli.

W tabeli wyników ostatnim sortowanym wymiarem jest Month, funkcja Above dokonuje zatem oceny na podstawie miesięcy. Dla każdej wartości w kolumnie Product istnieje szereg wyników dla każdego miesiąca (od Jan do Dec) — segment kolumny. Następnie pojawia się szereg dla następnego segmentu kolumny: dla każdego miesiąca Month dla następnej wartości z kolumny Product. Będzie istnieć segment kolumny dla każdej wartości w kolumnie Customer dla każdej wartości z kolumny Product.

## Przykład — zastosowanie Above wykorzystujące inną kolejność sortowania

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Wyrażenie wykresu

Przegląd

Otwórz Edytor ładowania danych i poniżej dodaj skrypt ładowania do nowej sekcji.

Skrypt ładowania zawiera:

* Trzy tabele danych o nazwach Monthnames, Sales2013 i Product.

Skrypt ładowania

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];

Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');

Product:
LOAD * inline [
Customer|Product|OrderNumber|UnitSales|UnitPrice
Astrida|AA|1|4|16
Astrida|AA|7|10|15
Astrida|BB|4|9|9
Betacab|CC|6|5|10
Betacab|AA|5|2|20
Betacab|BB||| 25
Canutility|AA|||15
Canutility|CC| ||19
Divadip|CC|2|4|16
Divadip|DD|3|1|25
] (delimiter is '|');
```

Wyniki

Załaduj dane i otwórz arkusz. Utwórz nową tabelę i dodaj te pola jako wymiary:

* Customer

* Product

* Month

Utwórz następujące miary:

* =Sum(Sales) w celu obliczenia sumy sprzedaży.

* =Above(Sum(Sales)) w celu pokazania sumy sprzedaży w poprzednim wierszu.

Zmień kolejność sortowania tabeli w panelu właściwości. Wybierz Sortowanie, a następnie przeciągnij wymiar Product na trzecią pozycję w kolejności sortowania.

Tabela wynikowa

| Customer | Product | Month | Sum(Sales) | Above(Sum(Sales)) |
| --- | --- | --- | --- | --- |
| Totals | - | - | 2566 | - |
| Astrida | AA | Jan | 46 | - |
| Astrida | BB | Jan | 46 | 46 |
| Astrida | AA | Feb | 60 | - |
| Astrida | BB | Feb | 60 | 60 |
| Astrida | AA | Mar | 70 | - |
| Astrida | BB | Mar | 70 | 70 |
| Astrida | AA | Apr | 13 | - |
| Astrida | BB | Apr | 13 | 13 |
| Astrida | AA | May | 78 | - |
| Astrida | BB | May | 78 | 78 |
| Astrida | AA | Jun | 20 | - |
| Astrida | BB | Jun | 20 | 20 |
| Astrida | AA | Jul | 45 | - |
| Astrida | BB | Jul | 45 | 45 |

W tabeli wyników ostatnim posortowanym wymiarem jest Product. Funkcja Above jest oceniana dla każdej wartości w kolumnie Product. Występują tam tylko dwa produkty ( AA i BB), w każdym szeregu jest zatem tylko jeden wynik niebędący wartością null. W wierszu BB dla miesiąca Jan wartością Above(Sum(Sales)) jest 46. W przypadku wiersza AA wartość wynosi null. Wartość w każdym wierszu AA dla dowolnego miesiąca zawsze będzie null, ponieważ nie ma żadnej wartości Product powyżej AA. Drugi szereg jest oceniany dla wartości AA i BB za miesiąc Feb dla znajdującego się w kolumnie Customer klienta Astrida. Po dokonaniu oceny wszystkich miesięcy dla klienta Astrida sekwencja ta zostaje powtórzona dla kolejnego klienta Betacab itd.

InformacjaWyniki w tabeli przedstawiają tylko częściową listę danych. Aby zobaczyć pełne wyniki, wypróbuj przykład w aplikacji.

## Przykład — użycie funkcji Above z RangeAvg

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Wyrażenie wykresu

Przegląd

Funkcję Above można stosować jako źródło danych wejściowych dla funkcji zakresu. W tym przykładzie wykorzystano tę funkcję w RangeAvg.

Otwórz Edytor ładowania danych i poniżej dodaj skrypt ładowania do nowej sekcji.

Skrypt ładowania zawiera:

* Trzy tabele danych o nazwach Monthnames, Sales2013 i Product.

Skrypt ładowania

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];

Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');

Product:
LOAD * inline [
Customer|Product|OrderNumber|UnitSales|UnitPrice
Astrida|AA|1|4|16
Astrida|AA|7|10|15
Astrida|BB|4|9|9
Betacab|CC|6|5|10
Betacab|AA|5|2|20
Betacab|BB||| 25
Canutility|AA|||15
Canutility|CC| ||19
Divadip|CC|2|4|16
Divadip|DD|3|1|25
] (delimiter is '|');
```

Wyniki

Załaduj dane i otwórz arkusz. Utwórz nową tabelę i dodaj to pole jako wymiar:

* Customer

Utwórz następującą miarę:

* =RangeAvg (Above(Sum(Sales),1,3))

Tabela wynikowa\*

| Customer | RangeAvg (Above(Sum(Sales),1,3)) |
| --- | --- |
| Totals | - |
| Astrida | - |
| Betacab | 587 |
| Canutility | 563 |
| Divadip | 603 |

W argumentach funkcji Above offset ma wartość 1, a count ma wartość 3. Funkcja ta znajduje wyniki wyrażenia Sum(Sales) w trzech wierszach znajdujących się bezpośrednio nad bieżącym wierszem w segmencie kolumny (o ile jest tam wiersz). Wspomniane trzy wartości są stosowane jako dane wejściowe dla funkcji RangeAvg, która znajduje średnią wartości w określonym szeregu liczbowym.

## Dowiedz się więcej

* [Below — funkcja wykresu](https://help.qlik.com/pl-PL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
* [Bottom — funkcja wykresu](https://help.qlik.com/pl-PL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
* [Top — funkcja wykresu](https://help.qlik.com/pl-PL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/top.htm)
* [RangeAvg funkcja skryptu i funkcja wykresu](https://help.qlik.com/pl-PL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/rangeavg.htm)