# ApplyMap Scriptfunctie

De scriptfunctie ApplyMap wordt gebruikt voor het toewijzen van de uitvoer van een uitdrukking aan een eerdere geladen toewijzingstabel.

Syntaxis:

ApplyMap('map\_name', expression [ , default\_mapping ] )

Retourgegevenstypen: dubbele waarde

Argumenten:

Argumenten

| Argument | Beschrijving |
| --- | --- |
| map\_name | De naam van een toewijzingstabel die eerder is gemaakt met de opdracht mapping load of mapping select. De naam moet tussen enkele, rechte aanhalingstekens staan.<br><br>WaarschuwingAls u deze functie gebruikt voor een variabele die is uitgebreid met een macro en verwijst naar een toewijzingstabel die niet bestaat, geeft de functie een fout weer en wordt er geen veld gemaakt. |
| expression | De uitdrukking waarvan het resultaat moet worden toegewezen. |
| default\_mapping | Als de uitdrukking is opgegeven, wordt deze waarde gebruikt als standaardwaarde als de toewijzingstabel geen overeenkomstige waarde bevat voor expression. Als de uitdrukking niet is opgegeven, wordt de waarde van expression ongewijzigd geretourneerd. |

WaarschuwingHet uitvoerveld van ApplyMap mag niet dezelfde naam hebben als een van de invoervelden. Dit kan tot onverwachte resultaten leiden. Voorbeeld dat u niet moet gebruiken: ApplyMap('Map', A) as A.

Voorbeeld:

In dit voorbeeld laden wij een lijst met verkopers waarbij een landcode het land aangeeft waar zijn wonen. Wij gebruiken een tabel waarin een landcode wordt toegewezen aan een land ter vervanging van de landcode door de landnaam. Er zijn slechts drie landen gedefinieerd in de toewijzingstabel, andere landcode worden toegewezen aan 'Rest of the world'.

```
// Load mapping table of country codes:
map1:
mapping LOAD * 
Inline [
CCode, Country
Sw, Sweden
Dk, Denmark
No, Norway
] ;

// Load list of salesmen, mapping country code to country
// If the country code is not in the mapping table, put Rest of the world
Salespersons:
LOAD *, 
ApplyMap('map1', CCode,'Rest of the world') As Country 
Inline [
CCode, Salesperson 
Sw, John
Sw, Mary
Sw, Per 
Dk, Preben
Dk, Olle
No, Ole 
Sf, Risttu
] ;

// We don't need the CCode anymore
Drop Field 'CCode';
```

De resulterende tabel (Verkopers) ziet er als volgt uit:

Resulting table

| Salesperson | Country |
| --- | --- |
| John | Sweden |
| Mary | Sweden |
| Per | Sweden |
| Preben | Denmark |
| Olle | Denmark |
| Ole | Norway |
| Risttu | Rest of the world |

## Meer informatie

* [](https://help.qlik.com/nl-NL/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptPrefixes/Mapping.htm)[Toewijzingen](https://help.qlik.com/nl-NL/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptPrefixes/Mapping.htm)
* [Gebruik van aanhalingstekens in het script](https://help.qlik.com/nl-NL/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/use-quotes-in-script.htm)