# wildmatch Script- en diagramfunctie

Met de functie wildmatch vergelijkt u de eerste parameter met alle volgende parameters en krijgt u het aantal overeenkomende uitdrukkingen als resultaat. Bij deze functie kunt u jokertekens ( \* en ?) gebruiken in de tekenreeksen die worden vergeleken. \* komt overeen met een willekeurige reeks tekens. ? komt overeen met een willekeurig enkel teken. De vergelijking is niet hoofdlettergevoelig en maakt geen onderscheid tussen de Japanse Hiragana- en Katakana-tekensystemen.

Syntaxis:

wildmatch( str, expr1 [ , expr2,...exprN ])

Retourgegevenstypen: geheel getal

Als u een vergelijking wilt gebruiken zonder jokertekens, gebruikt u de functie match of mixmatch.

Argumenten

| Argument | Beschrijving |
| --- | --- |
| str | De tekenreeks die moet worden geëvalueerd. |
| expr1 | De eerste uitdrukking voor controle op een geldige getalsnotatie. |
| expr2 | De tweede uitdrukking voor controle op een geldige getalsnotatie. |
| expr3 | De derde uitdrukking voor controle op een geldige getalsnotatie. |

Voorbeeld: diagramuitdrukkingen

| Voorbeeld | Resultaat |
| --- | --- |
| `wildmatch( ColorCode,'black','*Blue*' )` | Deze uitdrukking retourneert `1` als de waarde van `ColorCode` `Black` is of `2` als de waarde van `ColorCode` `Blue` is of `Light Blue` of `blue`. |
| ` wildmatch( Cities,'toronto','Boston','Beijing','Zurich')  ` | Deze uitdrukking retourneert de indexatie van het item dat overeenkomt met de waarde in het veld `Cities`. |

In sommige voorbeelden in dit onderwerp worden inline loads gebruikt. Ga voor meer informatie naar [Inline-ladingen gebruiken om gegevens te laden](https://help.qlik.com/nl-NL/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm).

## Voorbeeld - Producten categoriseren met wildmatch

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/wildmatch.htm)

#### Diagramuitdrukking

Overzicht

Een gegevensverzameling bevat productgegevens. U wilt producten identificeren en categoriseren die consumeerbaar zijn.

Open de editor voor laden van gegevens en voeg het onderstaande load-script toe aan een nieuwe sectie.

Het load-script bevat:

* Een gegevensverzameling die wordt geladen in een tabel met de naam `Example`.

* De volgende velden in de gegevenstabel:

  * `ProductID`

  * `ProductName`

  * `ProductCategory`

Load-script

```
Example:
LOAD * INLINE [
ProductID, ProductName, ProductCategory
1, "Laptop", "Electronics"
2, "Banana", "fruit"
3, "Shampoo", "toiletries"
4, "TV", "Electronics"
5, "Apple", "Fruits and vegetables"
];
```

Resultaten

Laad de gegevens en open een werkblad. Maak een nieuwe tabel en voeg deze velden toe als dimensies:

* `ProductID`

* `ProductName`

* `ProductCategory`

Maak de volgende metingen:

* `=wildmatch(ProductCategory, 'Toiletries*', 'Fruit*')`, om de indexatie te retourneren waarbij `ProductCategory` de waarde heeft die begint met `Toiletries` of begint met `Fruit`.

* `=If(wildmatch(ProductCategory, 'Toiletries*', 'Fruit*'), 'Consumable', 'Other')`, om de indexatie te retourneren waarbij `ProductCategory` de waarde heeft die begint met `Toiletries` of begint met `Fruits`. Als een van beide wordt gevonden, dan wordt `Consumable` geretourneerd. Anders wordt `Other` geretourneerd.

InformatieDe functie `wildmatch` retourneert een positieve waarde (niet nul) als er een overeenkomst is gevonden, anders nul als er geen overeenkomst is gevonden. De `if` instructie interpreteert op zijn beurt resultaten die niet nul zijn als `true` en resultaten die nul zijn als `false`. Door een `if` instructie te combineren met `mixmatch`, `wildmatch` of `match` functies, is het mogelijk om gemakkelijk overeenkomsten en mismatches te decoderen.

Resultatentabel

| ProductID | ProductName | ProductCategory | wildmatch(ProductCategory, 'Toiletries\*', 'Fruit\*') | If(wildmatch(ProductCategory, 'Toiletries\*', 'Fruit\*') |
| --- | --- | --- | --- | --- |
| 1 | Laptop | Electronics | 0 | Other |
| 2 | Banana | fruit | 2 | Consumable |
| 3 | Shampoo | toiletries | 1 | Consumable |
| 4 | TV | Electronics | 0 | Other |
| 5 | Apple | Fruits and vegetables | 2 | Consumable |

De functie `wildmatch` retourneert de indexatie van de zoekreeks in de eerste meting. In de tweede meting wordt dit resultaat vervolgens gebruikt in een `If` functie om aangepaste resultaten te bieden. Let op dat de functie `wildmatch` hoofdletterongevoelig is en jokertekens (`*` en `?`) toestaat.

## Voorbeeld - Klantgegevens evalueren en classificeren met behulp van wildmatch

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/wildmatch.htm)

#### Diagramuitdrukking

Overzicht

Een gegevensverzameling bevat klantgegevens. U wilt de klanten identificeren en categoriseren waarvan de regio en industriecategorie aan uw classificatievereisten voldoen.

Open de editor voor laden van gegevens en voeg het onderstaande load-script toe aan een nieuwe sectie.

Het load-script bevat:

* Een gegevensverzameling die wordt geladen in een tabel met de naam `Example`.

* De volgende velden in de gegevenstabel:

  * `ClientID`

  * `ClientName`

  * `Region`

  * `Industry`

Load-script

```
Example:
LOAD * INLINE [ 
ClientID, ClientName, Region, Industry 
1, "Acme Corp", "north territory", "Vehicle Manufacturing" 
2, "Beta Ltd", "East location", "Science & Technology" 
3, "Gamma Inc", "west", "Retail Sales" 
4, "Delta LLC", "North", "Technology" 
5, "Epsilon GmbH", "South", "healthcare" 
];
```

Resultaten

Laad de gegevens en open een werkblad. Maak een nieuwe tabel en voeg deze velden toe als dimensies:

* `ClientID`

* `ClientName`

* `Region`

* `Industry`

Maak de volgende meting:

`=If(wildmatch(Region, 'North*', 'East*') AND wildmatch(Industry, '*Technology*', '*Manufacturing*'), 'Target Segment', 'Secondary Segment')`, om de indexatie van de zoekreeks te retourneren. Als deze wordt gevonden, dan wordt `Target Segment` geretourneerd. Als deze niet wordt gevonden, dan wordt `Secondary Segment` geretourneerd.

Resultatentabel

| ClientID | ClientName | Region | Industry | If(wildmatch(Region, 'North\*', 'East\*') AND wildmatch(Industry, '\*Technology\*', '\*Manufacturing\*'), 'Target Segment', 'Secondary Segment') |
| --- | --- | --- | --- | --- |
| 1 | Acme Corp | north territory | Vehicle Manufacturing | Target Segment |
| 2 | Beta Ltd | East location | Science & Technology | Target Segment |
| 3 | Gamma Inc | west | Retail Sales | Secondary Segment |
| 4 | Delta LLC | North | Technology | Target Segment |
| 5 | Epsilon GmbH | South | healthcare | Secondary Segment |

De functie `wildmatch` zoekt naar tekst en stuurt een indexatie terug die vervolgens kan worden gebruikt om aanvullende analyses en gegevensclassificatie uit te voeren. Bijvoorbeeld, `Acme Corp` wordt geclassificeerd als een `Target Segment` omdat het voldoet aan de zoekvereisten van de `wildmatch` functie voor zowel het veld `Region` als `Industry`. Let op dat de functie `wildmatch` hoofdletterongevoelig is en jokertekens (`*` en `?`) toestaat.

## Voorbeeld - Load-script met gebruik van wildmatch

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/wildmatch.htm)

#### Load-script

Overzicht

U kunt wildmatch gebruiken om een gegevens-subset te laden. U kunt bijvoorbeeld een numerieke waarde als resultaat krijgen voor een uitdrukking in de functie. Vervolgens kunt u de gegevens beperken die zijn geladen op basis van de numerieke waarde. Wildmatch geeft 0 als resultaat als er geen overeenkomst is. Alle uitdrukkingen zonder overeenkomst retourneren in dit voorbeeld daarom 0 en worden uitgesloten van de gegevens die zijn geladen door de `WHERE`-instructie.

Open de editor voor laden van gegevens en voeg het onderstaande load-script toe aan een nieuwe sectie.

Het load-script bevat:

* Een gegevensverzameling die wordt geladen in twee tabellen met de naam:

  * `Transactions`: bevat transactievelden

  * `Transaction_Buckets`: maakt twee nieuwe velden, `Customer` en `Color code - Black, Blue, blue, red`. De `where`-instructie laadt de resultaten van de functie `wildmatch`.

Load-script

```
Transactions:
Load * Inline [
transaction_id, transaction_date, transaction_amount, transaction_quantity, customer_id, size, color_code
3750, 20180830, 23.56, 2, 2038593, L, Red
3751, 20180907, 556.31, 6, 203521, m, orange
3752, 20180916, 5.75, 1, 5646471, S, blue
3753, 20180922, 125.00, 7, 3036491, l, Black
3754, 20180922, 484.21, 13, 049681, xs, Red
3756, 20180922, 59.18, 2, 2038593, M, Blue
3757, 20180923, 177.42, 21, 203521, XL, Black
];
 
/*
Create new table called Transaction_Buckets
Create new fields called Customer, and Color code - Black, Blue, blue, red
Load Transactions table.
Wildmatch returns 1 for 'Black', 'Blue', and 'blue', and 2 for 'Red'. 
Only values that returned numeric value greater than 0 
are loaded by WHERE statement into Transactions_Buckets table.
*/
 
Transaction_Buckets:
Load
   customer_id,
   customer_id as [Customer],
   color_code as [Color Code Black, Blue, blue, Red]
Resident Transactions
Where wildmatch(color_code,'Bl*','R??') > 0;
```

Resultaten

Laad de gegevens en open een werkblad. Maak een nieuwe tabel en voeg deze velden toe als dimensies:

* `[Color code - Black, Blue, blue, red]`

* `Customer`

Resultatentabel met de uitvoer van het gebruik van de functie wildmatchwildmatch in het load-script.

| Color code - Black, Blue, blue, red | Customer |
| --- | --- |
| Black | 203521 |
| Black | 3036491 |
| Blue | 2038593 |
| blue | 5646471 |
| Red | 049681 |
| Red | 2038593 |

## Voorbeeld - Diagramuitdrukking met gebruik van wildmatch

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/wildmatch.htm)

#### Diagramuitdrukking

Overzicht

Open de editor voor laden van gegevens en voeg het onderstaande load-script toe aan een nieuwe sectie.

Het load-script bevat:

* Een gegevensverzameling die wordt geladen in een tabel met de naam Example.

* De volgende velden in de gegevenstabel:

  * Cities

  * Count

Load-script

```
Example:
Load * inline [Cities, Count
Toronto, 123
Toronto, 234
Toronto, 231
Boston, 32
Boston, 23
Boston, 1341
Beijing, 234
Beijing, 45
Beijing, 235
Stockholm, 938
Stockholm, 39
Stockholm, 189
zurich, 2342
zurich, 9033
zurich, 0039];
```

Resultaten

Laad de gegevens en open een werkblad. Maak een nieuwe tabel en voeg dit veld toe als dimensie:

* Cities

Maak de volgende metingen:

* =wildmatch( Cities,'Tor\*','?ton','Beijing','\*urich') , om de indexatie van de zoekreeks te retourneren.

* =wildmatch( Cities,'Tor\*','???ton','Beijing','Stockholm','\*urich'), om de indexatie van de zoekreeks te retourneren.

* =Cities & ' - ' & wildmatch ( Cities, 'Tor\*','???ton','Beijing','Stockholm','\*urich'), om het veld Cities en de indexatie van de zoekreeks te retourneren.

De eerste meting in de onderstaande tabel retourneert 0 voor Stockholm, aangezien Stockholm niet is opgenomen in de lijst met uitdrukkingen in de functie wildmatch. Het retourneert ook 0 voor Boston, omdat ? alleen overeenkomt met een enkel teken.

Resultatentabel

| Cities | wildmatch( Cities,'Tor\*','?ton','Beijing','\*urich') | wildmatch( Cities,'Tor\*','???ton','Beijing','Stockholm','\*urich') | Cities & ' - ' & wildmatch ( Cities, 'Tor\*','???ton','Beijing','Stockholm','\*urich') |
| --- | --- | --- | --- |
| Beijing | 3 | 3 | Beijing - 3 |
| Boston | 0 | 2 | Boston - 2 |
| Stockholm | 0 | 4 | Stockholm - 4 |
| Toronto | 1 | 1 | Toronto - 1 |
| zurich | 4 | 5 | zurich - 5 |

## Voorbeeld - Aangepaste sorteeruitdrukking met gebruik van wildmatch

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/wildmatch.htm)

#### Diagramuitdrukking

Overzicht

U kunt wildmatch gebruiken om een uitdrukking op aangepaste wijze te sorteren. Dit voorbeeld gebruikt dezelfde gegevensverzameling als het vorige voorbeeld.

Kolommen worden standaard numeriek of alfabetisch gesorteerd, afhankelijk van de gegevens.

Resultaten

Laad de gegevens en open een werkblad. Maak een nieuwe tabel en voeg dit veld toe als dimensie:

* Cities

Resultatentabel toont de standaardsorteervolgorde

| Cities |
| --- |
| Beijing |
| Boston |
| Stockholm |
| Toronto |
| zurich |

Doe het volgende om de sorteervolgorde te wijzigen:

1. Open de sectie Sorteren in het eigenschappenvenster.

2. Schakel automatisch sorteren uit voor de kolom die u aangepast wilt sorteren.

3. Schakel de selectievakjes Numeriek sorteren en Alfabetisch sorteren uit.

4. Selecteer Sorteren op uitdrukking en voer een uitdrukking in die hierop lijkt:

   =wildmatch( Cities, 'Tor\*','???ton','Beijing','Stockholm','\*urich')

   De sorteervolgorde van de kolom Cities wordt gewijzigd.

Resultatentabel toont de sorteervolgorde met de functie wildmatchwildmatch.

| Cities |
| --- |
| Toronto |
| Boston |
| Beijing |
| Stockholm |
| zurich |

## Meer informatie

* [match Script- en diagramfunctie](https://help.qlik.com/nl-NL/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/match.htm)
* [mixmatch Script- en diagramfunctie](https://help.qlik.com/nl-NL/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/mixmatch.htm)