# Drop table
Een of meer QlikView interne tabellen kunnen op elk moment tijdens de uitvoering van het script uit het gegevensmodel, en dus uit het geheugen, worden verwijderd door middel van een drop table-instructie. Gebruik eventueel de variant drop mapping table om toewijzingstabellen—die zijn gemaakt met het voorvoegsel Mapping—vóór het einde van de scriptuitvoering te verwijderen.
drop [mapping] table tablename [, tablename2 ...]
drop [mapping] tables [ tablename [, tablename2 ...]
InformatieDe vormen drop table en drop tables worden beide geaccepteerd.
De volgende items gaan als gevolg hiervan verloren:
* De feitelijke tabel(len).
* Alle velden die geen onderdeel vormen van de resterende tabellen.
* Veldwaarden in resterende velden die uitsluitend uit de te wissen tabel(len) afkomstig zijn.
Voorbeelden en resultaten
| Voorbeeld | Resultaat |
| --- | --- |
| ```
drop table Orders, Salesmen, T456a;
``` | Deze regel verwijdert drie tabellen uit het geheugen. |
| ```
Tab1:
Load * Inline [
Customer, Items, UnitPrice
Bob, 5, 1.50
];
Tab2:
LOAD Customer, Sum( Items * UnitPrice ) as Sales
resident Tab1
group by Customer;
drop table Tab1;
``` | Nadat de tabel Tab2 is gemaakt, wordt de tabel Tab1 verwijderd. |
| ```
// Load mapping table of country codes:
map1:
mapping LOAD *
Inline [
CCode, Country
Sw, Sweden
Dk, Denmark
No, Norway
] ;
// Load list of salesmen, mapping country code to country
// If the country code is not in the mapping table, put Rest of the world
Salespersons:
LOAD *,
ApplyMap('map1', CCode,'Rest of the world') As Country
Inline [
CCode, Salesperson
Sw, John
Sw, Mary
Sw, Per
Dk, Preben
Dk, Olle
No, Ole
Sf, Risttu] ;
// We don't need the CCode anymore
Drop Field 'CCode';
Drop Mapping Table map1;
Metrics:
Load * Inline [
Transaction ID, Sales Amount, Sales Cost, City, Customer ID
1000012, 4509.33, 1234.22, Oslo, 250v9849
1000013, 1043.21, 180.23, Gothenburg, 195d5930
1000014, 6038.35, 1400.10, Copenhagen, 195d5930
];
``` | Dit voorbeeld laat zien hoe de Drop mapping table-variant kan worden gebruikt. Er wordt een toewijzingstabel map1 gemaakt en vervolgens gebruikt in een volgende LOAD-instructie met de functie ApplyMap. Nadat de toewijzingstabel is gebruikt, wordt deze uit het geheugen verwijderd, waardoor het RAM-gebruik wordt geoptimaliseerd voor de gegevens die in volgende tabellen van de scriptuitvoering worden geladen.
In dit geval, met slechts enkele rijen in de toewijzingstabel, zou de RAM-optimalisatie minimaal zijn. Bij grote mappingtabellen of bij het maken van mappingtabellen binnen lussen kunnen de prestaties echter aanzienlijk worden verbeterd. |
[Rename table](https://help.qlik.com/nl-NL/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/rename-table.htm)
[Drop field](https://help.qlik.com/nl-NL/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/drop-field.htm)
[Drop](https://help.qlik.com/nl-NL/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Drop.htm)
[Table/Tables](https://help.qlik.com/nl-NL/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Table.htm)
[Mapping](https://help.qlik.com/nl-NL/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptPrefixes/Mapping.htm)