# Gegevens laden vanuit inline-tabellen
Typ gegevens handmatig in een script om een inline-tabel te definiëren.
U maakt inline-tabellen door gegevens handmatig in het script te typen, in plaats van verbinding te maken met bestanden en databases. Gebruik de vereiste syntaxis om aan te geven dat de scripttekst als inline-gegevens geïnterpreteerd moet worden.
Bij een basis inline-lading wordt een tabel gemaakt en worden de gegevensvelden en records ingevoegd.
## Waarom zou u inline-ladingen gebruiken?
Inline-ladingen zijn in de volgende gevallen praktisch:
* Voor het beheren en bewerken van gegevens zonder verbinding te hoeven maken met externe bronnen.
* Voor het aanvullen van bestaande gegevens in het gegevensmodel. U kunt bijvoorbeeld een extra tabel toevoegen aan een gegevensmodel dat voor het grootste deel afkomstig is van databasebronnen.
* Voor het toevoegen van gegevens waarvan u niet wilt dat ze voortdurend van externe bronnen worden geladen. Dit kan tijd besparen als u weet dat de gegevensbron in de toekomst mogelijk wijzigt, maar de gegevenswaarden gelijk blijven.
* Voor het eenvoudig kopiëren en plakken van inhoud vanuit andere bestanden in het script. Bijvoorbeeld .csv-bestanden of tabellen van tekstverwerkingsdocumenten.
* Voor het maken van testscripts die snel gekopieerd en geplakt kunnen worden.
## Voorbeeld basissyntaxis
Het volgende script bevat een simpele inline-lading.
```
MyTable:
Load * Inline [Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
];
```
De volgende syntaxis is gebruikt voor de bovenstaande inline-lading:
* Load \* Inline instrueert QlikView om alle velden te laden van de inline-tabel die volgt.
* MyTable: definieert de naam van de tabel.
* De gegevens staan tussen vierkante haakjes.
* De eerste regel van de load-instructie definieert de gegevensvelden.
* Gegevensvelden en records worden gescheiden door komma's.
* De load-instructie wordt afgesloten met een puntkomma.
## Syntaxisoverzicht
### De tabel een naam geven
U kunt een naam voor de inline-tabel toevoegen, net zoals u dat voor andere geladen tabellen zou doen. De tabelnaam definiëren is optioneel.
Plaats een dubbelepunt na de naam van de tabel.
### LOAD- en inline-instructies
Een inline-tabel wordt geladen met de inline-clausule als u de LOAD scriptinstructie gebruikt. De inline-clausule geeft aan dat de daaropvolgende tekst in de tabel gegevens bevat die handmatig in de editor zijn getypt. Tenzij anders aangegeven, gebruikt de inline-tabel de txt-indeling, die de structuur van een tekstbestand met scheidingstekens volgt.
Voor meer informatie over de LOAD-instructie raadpleegt u [Load](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm).
### Insluitingen en gegevensinvoer
Gegevens die zijn ingevoerd via een inline-clausule moeten met specifieke tekens worden ingesloten. Hieronder volgende geaccepteerde tekencombinaties voor het insluiten van de gegevens:
* Vierkante haakjes: `[` en `]`
* Dubbele aanhalingstekens: `"` en `"`
* Enkele aanhalingstekens: `'` en `'`
* Backticks: `` ` `` en `` ` ``
Het teken dat u kiest voor het insluiten kan u helpen om inline-gegevens te laden die conflicterende tekens bevatten. Als uw gegevens bijvoorbeeld records bevatten met vierkante haakjes, kunt u deze in plaats daarvan insluiten met aanhalingstekens of backticks.
Zie [Voorbeeld - Alternatieve gegevensinsluitingen](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDataEnc) voor een voorbeeld van alternatieve insluitingen.
Tenzij u een alternatieve tabelopmaak opgeeft (de standaardinstelling is txt), wordt tekst tussen de insluitingen op dezelfde manier geïnterpreteerd als de inhoud van een bestand. Waar u in een tekstbestand bijvoorbeeld een nieuwe regel zou invoegen, moet u dat ook doen in de tekst van een inline-clausule: u drukt op Enter bij het typen van het script.
### De inline-lading eindigen
Het einde van een inline-load-instructie wordt aangegeven door een puntkomma.
### Gegevenstransformaties
In een simpele inline-lading zonder transformaties wordt het aantal kolommen gedefinieerd door de eerste regel. Er worden drie kolommen in de tabel geladen door het volgende voorbeeld: `Product_ID`, `Supplier_Name` en `Product_Category`.
```
Products:
Load * Inline [
Product_ID, Supplier_Name, Product_Category
1, Paracel, Home Decor
2, PageWave, Electronics
3, Talarian, Software
4, Userland, Appliances
];
```
U kunt ook transformaties uitvoeren en nieuwe kolommen maken binnen dezelfde inline-tabel U kunt voorafgaande loads gebruiken en meer dan één LOAD-instructie kan gebruikt worden om dezelfde tabel te laden.
Zie [Voorbeelden - Inline-ladingen met transformaties](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExTransform) voor specifieke voorbeelden.
### De opmaakspecificatie in een inline-lading configureren
Net als bij andere geladen tabellen, kunt u de indelingsspecificatie van de inline-tabel aanpassen met behulp van opmaakspecificaties. De opmaakspecificatie wordt toegevoegd binnen haakjes. Dit moet na de insluiting van gegevens worden toegevoegd, maar vóór de puntkomma die de LOAD-instructie afsluit. Aanpassingen die u kunt opnemen zijn:
* Het scheidingsteken wijzigen van een komma in een ander teken. Zie [Voorbeelden - Alternatieve scheidingstekens](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDelimiter) voor voorbeelden
Zie: [Delimiter](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/delimiter.htm)
* Tabelkolomkoppen weglaten. Zie [Voorbeeld - Kolomkoppen weglaten](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOmitLabels) voor een voorbeeld.
Zie: [Labels](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/labels.htm)
* Een andere gegevensopmaak gebruiken (bijvoorbeeld opmaak met vaste recordlengte). Zie [Voorbeeld - Ander gegevenstype laden](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExChangeFormat) voor een voorbeeld.
Zie: [Tabelopmaak](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/table-format.htm)
InformatieNiet alle opties van de Table format worden ondersteund voor inline-ladingen.
* Meerregelige inhoud toestaan. Zie [Voorbeeld - Meerregelige inhoud](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExMultLine) voor een voorbeeld.
Zie: [Quotes](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/quotes.htm)
Als u meerdere opmaakspecificaties in dezelfde tabel wilt gebruiken, moet u ze scheiden met komma's. Bijvoorbeeld:` (Delimiter is '|', no labels) `
Zie [Opmaakspecificaties](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm) voor meer informatie over de opmaakspecificatie.
### Operatoren en andere clausules
Aangezien een inline-lading een LOAD-instructie is, kunt u daarnaast andere argumenten combineren voor de LOAD-instructie in de inline-lading. Gebruik bijvoorbeeld de where- of while-clausule om te definiëren of een specifieke rij wel of niet wordt geladen op basis van de tekst die het bevat.
U kunt op een vergelijkbare manier ook operatoren buiten de tekstinhoud gebruiken. Met operatoren kunt u aanpassen hoe u de inline-gegevens transformeert en ook definiëren wanneer bepaalde gegevens wel of niet geladen moeten worden.
Zie [Voorbeeld - Operatoren voor transformaties en clausules](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOpsAndClauses) voor een specifiek voorbeeld.
## Voorbeeld - Alternatieve gegevensinsluitingen
U kunt vierkante haakjes, aanhalingstekens of backticks gebruiken om een inline-lading in te sluiten. Dit wordt in deze sectie aan de hand voor een voorbeeld getoond. Zie voor meer informatie [Insluitingen en gegevensinvoer](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Enclosure).
#### Load-script en resultaten
Overzicht
In dit voorbeeld wordt getoond hoe u backticks kunt gebruiken om de inline-gegevens in te sluiten. De gegevens in het voorbeeld bevatten vierkante haakjes, waardoor de vierkante haakjes niet gebruikt kunnen worden om de LOAD-instructie in te sluiten.
Load-script
```
DataTable:
Load * inline
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;
```
Resultaten
* `custom_property`
* `date`
* `amount`
Resultatentabel
| custom\_property | date | amount |
| --- | --- | --- |
| [11402] | 1/1/2024 | 92.99 |
| [11403] | 1/2/2024 | 102.34 |
| [11404] | 1/3/2024 | 50.26 |
| [11405] | 1/4/2024 | 153.69 |
| [11406] | 1/5/2024 | 75.62 |
## Voorbeelden - Alternatieve scheidingstekens
U kunt een ander teken dan de komma gebruiken om kolomwaarden in de tabel te scheiden. Zie voor meer informatie [De opmaakspecificatie in een inline-lading configureren](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Load-script en resultaten
Overzicht
Het wijzigen van het scheidingsteken is handig als gegevens in de tabel komma's bevatten, wat anders aangeeft dat er naar de volgende kolom in de tabel overgeschakeld moet worden.
Dit voorbeeld bevat vier tabellen die geladen moeten worden. Ze zijn als volgt:
* Vier tabellen moeten geladen worden. Ze zijn als volgt:
* Table1: scheidingsteken is een verticale staaf (pijp). De gegevens in de kolom Phrase bevatten komma's.
* Table2: scheidingsteken is een dubbele punt.
* Table3 is een backslash.
* Table4: de tabel wordt gescheiden door op de Tab-toets op het toetsenbord te drukken. Deze optie is handig als u een tabel van een tekstverwerker kopieert en plakt in het script.
Table1 toont een praktische usecase voor het gebruik van een alternatief scheidingsteken. De andere tabellen tonen meer scheidingstekens.
Load-script
```
Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');
Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');
Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);
Table4:
LOAD * INLINE [
Num3 Chr3
1 A
2 B ] (Delimiter is '\t');
```
Resultaten
Resultatentabel: Table1Table1
| ID | Phrase |
| --- | --- |
| 1 | The transaction was complete, but the order has not yet shipped. |
| 2 | We need to confirm the following details: sales rep number, order status, and shipping priority. |
Resultatentabel: Table2Table2
| Num1 | Chr1 |
| --- | --- |
| 1 | A |
| 2 | B |
Resultatentabel: Table3Table3
| Num2 | Chr2 |
| --- | --- |
| 1 | A |
| 2 | B |
Resultatentabel: Table4Table4
| Num3 | Chr3 |
| --- | --- |
| 1 | A |
| 2 | B |
## Voorbeeld - Kolomkoppen weglaten
Bewerk de opmaak om een inline-tabel te laden zonder kolomkoppen te definiëren. Dit doet u met de specificatie labels (stel een waarde van no labels in). Zie voor meer informatie [De opmaakspecificatie in een inline-lading configureren](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
Door het systeem gedefinieerde kolomnamen worden automatisch gebruikt als u een tabel laadt zonder kolomnamen te definiëren.
#### Load-script en resultaten
Overzicht
In dit voorbeeld wordt getoond hoe u een inline-tabel kunt laden zonder kolomnamen te definiëren.
Load-script
```
Expenses:
Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);
```
Resultaten
Resultatentabel
| @1 | @2 | @3 |
| --- | --- | --- |
| 1 | Category1 | 40566.49 |
| 2 | Category2 | 3504.54 |
| 3 | Category3 | 593206.30 |
## Voorbeeld - Ander gegevenstype laden
In dit voorbeeld wordt getoond hoe u een inline-tabel in een opmaak met vaste recordlengte kunt laden. Zie [De opmaakspecificatie in een inline-lading configureren](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Load-script en resultaten
Overzicht
In dit voorbeeldscript wordt het volgende getoond:
* Een inline-load-instructie die de tabel DataTable definieert.
* Het gebruik van fix (als onderdeel van de specificatie Table format) om aan te geven dat de gegevens in een opmaak met vaste recordlengte worden geladen.
Load-script
```
DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a b c d
1 2 3 4
x y z w
] (fix, utf8, embedded labels);
```
Resultaten
Resultatentabel
| a | b | c | d |
| --- | --- | --- | --- |
| 1 | 2 | 3 | 4 |
| x | y | z | w |
## Voorbeeld - Meerregelige inhoud
In dit voorbeeld wordt getoond hoe u meerregelige veldinhoud in een inline-tabel kunt invoeren. Zie [De opmaakspecificatie in een inline-lading configureren](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Load-script en resultaten
Overzicht
In dit voorbeeldscript wordt het volgende getoond:
* Een simpele inline-lading om de tabel T1 te definiëren.
* Gebruik van de specificatie Quotes (met de waarde msq) ter ondersteuning van meerregelige inhoud.
* Lengtewaarden die zijn opgegeven in voet en inches.
* Het markeringssymbool van dubbele aanhalingstekens (") geeft het einde van een meerregelige invoer aan. In dit voorbeeld wordt hetzelfde symbool ook gebruikt om de inchwaarden aan te geven. Dit wordt gedaan om de syntaxis en het resulterende gedrag te tonen als u beide moet gebruiken in dezelfde LOAD-instructie. In wezen geeft het invoeren van het " symbool voor twee opeenvolgende tekens ("") aan dat de code geïnterpreteerd moet worden als een afzonderlijk tekstexemplaar van het symbool.
Load-script
```
T1:
Load *, recno() as ID inline [
Length
"1' 2""
22' 10"""
14' 8" ] (msq);
```
Resultaten
U moet Instellingen voor meerdere regels aanpassen voor de grafiek in de configuratie Eigenschappen... om meerregelige inhoud zoals bedoeld weer te geven.
Resultatentabel
| ID | Length |
| --- | --- |
| 1 | 1' 2"
22' 10" |
| 2 | 14' 8" |
De bovenstaande tabel bevat een record met een ID-waarde van 1 meerregelige inhoud.
## Voorbeelden - Inline-ladingen met transformaties
Deze voorbeelden tonen hoe u berekeningen kunt uitvoeren voor velden die inline zijn geladen om nieuwe velden in het gegevensmodel te maken.
Zie voor meer informatie [Gegevenstransformaties](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Transform).
#### Voorbeeld: eenvoudig een veld hernoemen
Load-script
```
ORDERS:
Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];
```
Resultaten
Resultatentabel
| Original | Updated |
| --- | --- |
| ProductA | ProductA |
| ProductB | ProductB |
| ProductC | ProductC |
#### Voorbeeld: eenvoudig een ID-veld invoegen
Overzicht
In dit voorbeeld wordt getoond hoe u een berekend veld kunt definiëren om de ID van elke gegevensrij aan te geven, zonder elke ID-waarde handmatig te hoeven typen.
Load-script
```
ORDERS:
Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];
```
Resultaten
Resultatentabel
| ID | ProductName |
| --- | --- |
| 1 | A |
| 2 | B |
| 3 | C |
| 4 | D |
| 5 | E |
#### Voorbeeld: LOAD-instructies configureren voor de afhandeling van transformaties
Overzicht
Dit voorbeeld toont verschillende manieren waarop een eenvoudige transformatie op inline-gegevens kan worden toegepast. U kunt één of meerdere LOAD-instructies gebruiken en de syntaxis op verschillende manieren configureren om te definiëren of een transformatie het originele veld vervangt of dat zowel het origineel en nieuwe velden worden geladen.
Let met name op de variaties in het volgende voorbeeld en hoe ze de uitvoer beïnvloeden:
* Aantal LOAD-instructies in de tabel.
* Aanwezigheid of afwezigheid van het symbool \* (laadt alle voorgaande velden).
* Aanwezigheid of afwezigheid van komma's (symbool ,).
In dit voorbeeldscript wordt het volgende getoond:
* Vier tabellen die allemaal naar dezelfde gegevens verwijzen. De veldnamen zijn verschillend.
* DerivedYears1: gebruikt twee LOAD-instructies om een inline-kolom te laden en een kolom die de transformatie van de inline-kolom bevat.
* DerivedYears2: gebruikt twee LOAD-instructies. Het script laadt een inline-kolom en laadt vervolgens een berekend veld dat is getransformeerd op basis van de originele kolom. Bij de tweede LOAD-instructie wordt de originele kolom niet geladen in de tabel, waardoor het nieuwe veld in feite een vervanging is van het originele veld.
* DerivedYears3: gebruikt een afzonderlijke LOAD-instructie om zowel de originele inline-kolom als de getransformeerde kolom te laden.
* DerivedYears4: gebruikt een afzonderlijke LOAD-instructie om een inline-veld en een transformatie van dat originele veld te definiëren. Alleen het getransformeerde veld wordt geladen in de tabel.
Load-script
```
DerivedYears1:
Load *,
Year(initial_date1) as derived_year1
;
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears2:
Load
Year(initial_date2) as derived_year2
;
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears3:
Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears4:
Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
```
Resultaten
Resultatentabel: DerivedYears1DerivedYears1
| initial\_date1 | derived\_year1 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Resultatentabel: DerivedYears2DerivedYears2
| derived\_year2 |
| --- |
| 2022 |
| 2023 |
| 2024 |
Resultatentabel: DerivedYears3DerivedYears3
| initial\_date3 | derived\_year3 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Resultatentabel: DerivedYears4DerivedYears4
| derived\_year4 |
| --- |
| 2022 |
| 2023 |
| 2024 |
#### Voorbeeld: veldinhoud aanpassen
Overzicht
Stel dat u gegevens van een groot tekstbestand in de scripteditor plakt, maar u wilt een aanvullende verwerking van de records in de gegevensverzameling uitvoeren. U wilt bijvoorbeeld bepaalde tekens en prefixen verwijderen en elk woord beginnen met een hoofdletter.
In dit voorbeeldscript wordt het volgende getoond:
* Een inline-tabel, Transformations, waarin een transformatie is gedefinieerd om tekstinhoud van een veld te wijzigen. De tekst die wordt getransformeerd wordt hierna toegevoegd.
* Twee LOAD-instructies. Bij de configuratie in het voorbeeld, wordt alleen het afgeleide veld ProductName\_Trimmed geladen in de tabel.
Load-script
```
Transformations:
Load
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;
Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product: {snack food}
Product: {electronics and video games}
];
```
Resultaten
Resultatentabel
| ProductName\_Trimmed |
| --- |
| Soft Drinks And Other Beverages |
| Snack Food |
| Electronics And Video Games |
## Voorbeeld - Operatoren voor transformaties en clausules
U kunt operatoren gebruiken om transformaties en specifieke clausules in de LOAD-instructie te definiëren. Zie voor meer informatie [Operatoren en andere clausules](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#OpsAndClauses).
[Operatoren](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/Operators/operators.htm)
#### Load-script en resultaten
Overzicht
In dit voorbeeldscript wordt het volgende getoond:
* Een simpele inline-lading om de tabel Purchases te definiëren.
* Het invoegen van een berekend veld, OrderSize. Dit veld is een transformatie van het veld amount van de inline-gegevensverzameling. Hierin worden aankopen gecategoriseerd als klein of groot, afhankelijk van het feit of het bedrag $2000.00 overschrijdt.
* Een where-clausule die voorkomt dat records worden geladen als het amount lager is dan $0.05.
Load-script
```
Purchases:
Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,
* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;
```
Resultaten
Resultatentabel
| ID | amount | OrderSize |
| --- | --- | --- |
| 1 | 2660.39 | Large Purchase |
| 2 | 100.01 | Small Purchase |
| 3 | 500.42 | Small Purchase |
| 4 | 5023.99 | Large Purchase |
| 6 | 2002.39 | Large Purchase |
| 7 | 31034.53 | Large Purchase |
| 8 | 1643.58 | Small Purchase |
| 9 | 3993.65 | Large Purchase |
| 10 | 614.34 | Small Purchase |
| 11 | 675.93 | Small Purchase |
In de bovenstaande tabel is een transactie met een ID van 5 niet geladen in de tabel. Dit komt doordat de waarde amount lager is dan $0.05.
## Voorbeeld - Null-waarden maken in een inline-tabel
In dit voorbeeld wordt getoond hoe u de variabele NullInterpret gebruikt om null-waarden te maken in uw inline-gegevens.
[NullInterpret](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ValueHandlingVariables/NullInterpret.htm)
#### Load-script en resultaten
Overzicht
In dit voorbeeldscript wordt het volgende getoond:
* Een simpele inline-lading om de tabel T2 te definiëren.
* De variabele NullInterpret is gedefinieerd als twee enkele aanhalingstekens. Als het script is geladen, worden records die deze waarde bevatten verwerkt als null-waarden.
Load-script
```
set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];
```
Resultaten
Resultatentabel
| Test |
| --- |
| x |
In de bovenstaande tabel is het eerste record een null-waarde. Daardoor wordt deze niet opgenomen in de visualisatie. Null-waarden die aanwezig zijn in tabellen met aanvullende dimensies worden aangegeven met het symbool -.
## Meer voorbeelden
Zie [Load](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm) voor aanvullende voorbeelden.
## Meer informatie
* [Load](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm)
* [Opmaakspecificaties](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm)
* [Wizard Inline-gegevens](https://help.qlik.com/nl-NL/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Inline_Data_Wizard.htm)