# Set-modificaties

Set-uitdrukkingen worden gebruikt om het bereik van een berekening te definiëren. Het belangrijkste onderdeel van de set-uitdrukking is de set-modificator die een selectie definieert. Deze wordt gebruik om de gebruikersselectie of de selectie in de set-id te wijzigen. Het resultaat definieert een nieuw bereik voor de berekening.

De set-modificatie bestaat uit een of meer veldnamen, elk gevolgd door een selectie die op het veld wordt toegepast. De modificatie is omsloten door punthaken: `< >`

Bijvoorbeeld:

* `Sum ( {$<Year = {2015}>} Sales )`

* `Count ( {1<Country = {Germany}>} distinct OrderID )`

* `Sum ( {$<Year = {2015}, Country = {Germany}>} Sales )`

## Elementsets

Een elementset kan als volgt worden gedefinieerd:

* Een lijst met waarden

* Een zoekopdracht

* Een verwijzing naar een ander veld

* Een setfunctie

Als de definitie van een elementset wordt verwijderd, zorgt de set-modificatie dat alle selecties in dit veld worden gewist. Bijvoorbeeld:

`Sum( {$<Year = >} Sales )`

## Voorbeelden: diagramuitdrukkingen voor set-modificaties op basis van elementsets

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers.htm)

#### Voorbeelden - Diagramuitdrukkingen

Load-script

Laad de volgende gegevens als een inline-load in de editor voor laden van gegevens om de onderstaande voorbeelden van diagramuitdrukkingen te maken.

```
MyTable:
Load * Inline [
Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
Belgium, 2014, 182766.87
Belgium, 2015, 178042.33
Brazil, 2014, 174492.67
Brazil, 2015, 2104.22
Canada, 2014, 101801.33
Canada, 2015, 40288.25
Denmark, 2014, 45273.25
Denmark, 2015, 106938.41
Finland, 2014, 107565.55
Finland, 2015, 30583.44
France, 2014, 115644.26
France, 2015, 30696.98
Germany, 2014, 8775.18
Germany, 2015, 77185.68
];
```

Voor meer informatie over inline loads, raadpleegt u [Inline-ladingen gebruiken om gegevens te laden](https://help.qlik.com/nl-NL/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm).

Diagramuitdrukkingen

Maak een tabel in een Qlik Sense-werkblad met de volgende diagramuitdrukkingen.

Tabel - Set-modificaties op basis van elementsets

| Land | Sum(Sales) | Som({1&lt;Land={België}&gt;} Verkoop) | Som({1&lt;Land={"\*A\*"}&gt;} Verkoop) | Som({1&lt;Land={"A\*"}&gt;} Verkoop) | Sum({1&lt;Year={$(=Max(Year))}&gt;} Sales) |
| --- | --- | --- | --- | --- | --- |
| Totalen | 1645397.3 | 360809.2 | 1284588.1 | 443238.88 | 788617.07 |
| Argentinië | 206332.92 | 0 | 206332.92 | 206332.92 | 140037.89 |
| Oostenrijk | 236905.96 | 0 | 236905.96 | 236905.96 | 182739.87 |
| België | 360809.2 | 360809.2 | 0 | 0 | 178042.33 |
| Brazilië | 176596.89 | 0 | 176596.89 | 0 | 2104.22 |
| Canada | 142089.58 | 0 | 142089.58 | 0 | 40288.25 |
| Denemarken | 152211.66 | 0 | 152211.66 | 0 | 106938.41 |
| Finland | 138148.99 | 0 | 138148.99 | 0 | 30583.44 |
| Frankrijk | 146341.24 | 0 | 146341.24 | 0 | 30696.98 |
| Duitsland | 85960.86 | 0 | 85960.86 | 0 | 77185.68 |

Uitleg

* Dimensies:

  * `Country`

* Metingen:

  * `Sum(Sales)`

    Sum `Sales` zonder set-uitdrukking.

  * `Sum({1<Country={Belgium}>}Sales)`

    Selecteer `Belgium` en vervolgens de som die overeenkomt met `Sales`.

  * `Sum({1<Country={"*A*"}>}Sales)`

    Selecteer alle landen die een `A` bevatten en vervolgens de som die overeenkomt met `Sales`.

  * `Sum({1<Country={"A*"}>}Sales)`

    Selecteer alle landen die beginnen met een `A` en vervolgens de som die overeenkomt met `Sales`.

  * `Sum({1<Year={$(=Max(Year))}>}Sales)`

    Bereken de `Max(Year)`, dit is `2015`, en vervolgens de som die overeenkomt met `Sales`.

Set-modificaties op basis van elementsets

Set-modificaties op basis van elementsets

Set-modificaties op basis van elementsets ![Set-modificaties op basis van elementsets.](https://help.qlik.com/nl-NL/cloud-services/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_set_modifiers_element_sets.png)

## Weergegeven waarden

Het meest voorkomende voorbeeld van een elementset is een elementset die is gebaseerd op een lijst van veldwaarden die tussen accolades zijn geplaatst. Bijvoorbeeld:

* `{$<Country = {Canada, Germany, Singapore}>}`

* `{$<Year = {2015, 2016}>}`

De binnenste accolades definiëren de elementset. De individuele waarden worden gescheiden door komma's.

## Aanhalingstekens en hoofdlettergevoeligheid

Als de waarden lege waarden of speciale tekens bevatten, moeten de waarden tussen aanhalingstekens worden geplaatst. Bij het gebruik van enkele aanhalingstekens is er sprake van een hoofdlettergevoelige overeenkomst met de waarde van één veld. Bij het gebruik van dubbele aanhalingstekens is er sprake van een niet-hoofdlettergevoelige overeenkomst met één of meerdere veldwaarden. Bijvoorbeeld:

* `<Country = {'New Zealand'}>`

  Komt alleen overeen met `New Zealand`.

* `<Country = {"New Zealand"}>`

  Komt overeen met `New Zealand`, `NEW ZEALAND` en `new zealand`.

Datums moeten tussen aanhalingstekens worden geplaatst. U moet de datumindeling gebruiken van het desbetreffende veld. Bijvoorbeeld:

* `<ISO_Date = {'2021-12-31'}>`

* `<US_Date = {'12/31/2021'}>`

* `<UK_Date = {'31/12/2021'}>`

Dubbele aanhalingstekens kunnen worden vervangen door vierkante haken of accent graves.

## Zoekopdrachten

U kunt elementsets ook maken met behulp van zoekopdrachten. Bijvoorbeeld:

* `<Country = {"C*"}>`
* `<Ingredient = {"*garlic*"}>`
* `<Year = {">2015"}>`
* `<Date = {">12/31/2015"}>`

Jokertekens kunnen worden gebruikt voor zoekopdrachten in tekst: een asterisk (`*`) vertegenwoordigt een willekeurig aantal tekens en een vraagteken (`?`) vertegenwoordigt één teken. Relationele operatoren kunnen worden gebruikt om numerieke zoekopdrachten te definiëren.

U moet bij zoekopdrachten altijd dubbele aanhalingstekens gebruiken. Zoekopdrachten zijn niet hoofdlettergevoelig.

Ga voor meer informatie naar [Set-modificaties met zoekopdrachten](https://help.qlik.com/nl-NL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-advanced-searches.htm).

## Uitbreidingen met dollarteken

Uitbreidingen met dollarteken zijn nodig als u een berekening binnen uw elementenset wilt gebruiken. Als u bijvoorbeeld alleen naar het laatst mogelijke jaar wilt kijken, gebruikt u:

`<Year = {$(=Max(Year))}>`

Ga voor meer informatie naar [Set-modificaties met uitbreiding via dollartekens](https://help.qlik.com/nl-NL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-dollar-sign-expansions.htm).

## Geselecteerde waarden in andere velden

Modificaties kunnen worden gebaseerd op de geselecteerde waarden van een ander veld. Bijvoorbeeld:

`<OrderDate = DeliveryDate>`

Deze modificatie neemt de geselecteerde waarden uit `DeliveryDate` en past deze toe als selectie op `OrderDate`. Als er veel afzonderlijke waarden zijn – meer dan een paar honderd – vormt deze bewerking een te intensieve belasting van de processor en u dient deze dan te vermijden.

## Functies elementset

De elementset kan ook worden gebaseerd op de set-functies `P()` (mogelijke waarden) en `E()` (uitgesloten waarden).

Als u bijvoorbeeld de landen wilt selecteren waarin het product `Cap` is verkocht, kunt u het volgende gebruiken:

`<Country = P({1<Product={Cap}>} Country)>`

Als u de landen wilt bekijken waar het product `Cap` niet is verkocht, kunt u het volgende gebruiken:

`<Country = E({1<Product={Cap}>} Country)>`

Ga voor meer informatie naar [Set-modificaties die gebruikmaken van set-functies](https://help.qlik.com/nl-NL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-implicit-field-value-definitions.htm).

## Meer informatie

* [Set-analyse](https://help.qlik.com/nl-NL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-analysis-expressions.htm)

* [Set-Id's](https://help.qlik.com/nl-NL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-identifiers.htm)

* [Set-operatoren](https://help.qlik.com/nl-NL/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-operators.htm)