# 집합 수정자

집합 표현식은 계산 범위를 정의하는 데 사용됩니다. 집합 표현식의 중심 부분은 선택을 지정하는 집합 수정자입니다. 이는 사용자 선택 또는 집합 식별자의 선택을 수정하는 데 사용되며 결과는 계산을 위한 새 범위를 정의합니다.

집합 수정자는 하나 또는 여러 개의 필드 이름으로 구성되어 있는데, 각 필드 이름 다음에는 필드에 적용해야 하는 선택이 나옵니다. 수정자는 꺾쇠 괄호로 묶어야 합니다. `< >`

예:

* `Sum ( {$<Year = {2015}>} Sales )`

* `Count ( {1<Country = {Germany}>} distinct OrderID )`

* `Sum ( {$<Year = {2015}, Country = {Germany}>} Sales )`

## 요소 집합

요소 집합은 다음을 사용하여 정의할 수 있습니다.

* 값 목록

* 검색

* 다른 필드에 대한 참조

* 집합 함수

요소 집합 정의가 생략된 경우 집합 수정자는 이 필드의 모든 선택을 지웁니다. 예:

`Sum( {$<Year = >} Sales )`

## 예: 요소 집합을 기반으로 하는 집합 수정자의 차트 표현식

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers.htm)

#### 예 - 차트 표현식

로드 스크립트

데이터 로드 편집기에서 다음 데이터를 인라인 로드로 로드하여 아래 차트 표현식 예를 만듭니다.

```
MyTable:
Load * Inline [
Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
Belgium, 2014, 182766.87
Belgium, 2015, 178042.33
Brazil, 2014, 174492.67
Brazil, 2015, 2104.22
Canada, 2014, 101801.33
Canada, 2015, 40288.25
Denmark, 2014, 45273.25
Denmark, 2015, 106938.41
Finland, 2014, 107565.55
Finland, 2015, 30583.44
France, 2014, 115644.26
France, 2015, 30696.98
Germany, 2014, 8775.18
Germany, 2015, 77185.68
];
```

인라인 로드 사용에 대한 자세한 내용은 [인라인 로드를 사용하여 데이터 로드](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm)를 참조하십시오.

차트 표현식

다음 차트 표현식을 사용하여 Qlik Sense 시트에 테이블을 만듭니다.

테이블 - 요소 집합을 기반으로 한 집합 수정자

| 국가 | Sum(매출) | Sum({1&lt;Country={벨기에}&gt;} Sales) | Sum({1&lt;Country={"\*A\*"}&gt;} Sales) | 합계({1&lt;Country={"A\*"}&gt;} 매출) | 합계({1&lt;Year={$(=Max(Year))}&gt;} 매출) |
| --- | --- | --- | --- | --- | --- |
| 합계 | 1645397.3 | 360809.2 | 1284588.1 | 443238.88 | 788617.07 |
| 아르헨티나 | 206332.92 | 0 | 206332.92 | 206332.92 | 140037.89 |
| 오스트리아 | 236905.96 | 0 | 236905.96 | 236905.96 | 182739.87 |
| 벨기에 | 360809.2 | 360809.2 | 0 | 0 | 178042.33 |
| 브라질 | 176596.89 | 0 | 176596.89 | 0 | 2104.22 |
| 캐나다 | 142089.58 | 0 | 142089.58 | 0 | 40288.25 |
| 덴마크 | 152211.66 | 0 | 152211.66 | 0 | 106938.41 |
| 핀란드 | 138148.99 | 0 | 138148.99 | 0 | 30583.44 |
| 프랑스 | 146341.24 | 0 | 146341.24 | 0 | 30696.98 |
| 독일 | 85960.86 | 0 | 85960.86 | 0 | 77185.68 |

설명

* 차원:

  * `Country`

* 측정값:

  * `Sum(Sales)`

    집합 표현식 없는 합계 `Sales`입니다.

  * `Sum({1<Country={Belgium}>}Sales)`

    `Belgium`를 선택한 다음 해당하는 `Sales` 합계를 구합니다.

  * `Sum({1<Country={"*A*"}>}Sales)`

    `A`가 있는 모든 국가를 선택한 다음 해당하는 `Sales` 합계를 구합니다.

  * `Sum({1<Country={"A*"}>}Sales)`

    `A`로 시작하는 모든 국가를 선택한 다음 해당하는 `Sales` 합계를 구합니다.

  * `Sum({1<Year={$(=Max(Year))}>}Sales)`

    `Max(Year)`(`2015`)를 계산한 다음 해당하는 `Sales` 합계를 구합니다.

요소 집합 기반 집합 수정자

요소 집합 기반 집합 수정자

요소 집합 기반 집합 수정자 ![요소 집합 기반 집합 수정자입니다.](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_set_modifiers_element_sets.png)

## 나열된 값

요소 집합의 가장 일반적인 예는 중괄호로 묶인 필드 값 목록을 기반으로 하는 것입니다. 예:

* `{$<Country = {Canada, Germany, Singapore}>}`

* `{$<Year = {2015, 2016}>}`

내부 중괄호는 요소 집합을 정의합니다. 개별 값은 쉼표로 구분됩니다.

## 따옴표 및 대/소문자 구분

값이 공백이나 특수 문자를 포함하는 경우, 해당 값은 따옴표로 묶어야 합니다. 작은따옴표는 단일 필드 값과 대/소문자를 구분하는 리터럴 일치를 의미합니다. 이중 따옴표는 하나 또는 여러 필드 값과 대소문자를 구분하지 않는 일치를 의미합니다. 예:

* `<Country = {'New Zealand'}>`

  `New Zealand`만 일치합니다.

* `<Country = {"New Zealand"}>`

  `New Zealand`, `NEW ZEALAND` 및 `new zealand`가 일치합니다.

날짜는 따옴표로 묶어야 하며 해당 필드의 날짜 형식을 사용해야 합니다. 예:

* `<ISO_Date = {'2021-12-31'}>`

* `<US_Date = {'12/31/2021'}>`

* `<UK_Date = {'31/12/2021'}>`

이중 따옴표는 대괄호 또는 억음 악센트로 대체될 수 있습니다.

## 검색

검색을 통해 요소 집합을 만들 수도 있습니다. 예:

* `<Country = {"C*"}>`
* `<Ingredient = {"*garlic*"}>`
* `<Year = {">2015"}>`
* `<Date = {">12/31/2015"}>`

텍스트 검색에 와일드카드를 사용할 수 있습니다. 별표(`*`)는 임의 개수의 문자를 나타내고 물음표(`?`)는 단일 문자를 나타냅니다. 관계 연산자를 사용하여 숫자 검색을 정의할 수 있습니다.

검색에는 항상 큰따옴표를 사용해야 합니다. 검색은 대소문자를 구분하지 않습니다.

자세한 내용은 [검색을 사용하는 집합 수정자](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-advanced-searches.htm)을 참조하십시오.

## 달러 기호 확장

요소 집합 내에서 계산을 사용하려면 달러 기호 확장이 필요합니다. 예를 들어, 마지막 가능한 연도만 살펴보려면 다음과 같이 사용할 수 있습니다:

`<Year = {$(=Max(Year))}>`

자세한 내용은 [집합 수정자 및 달러 기호 확장](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-dollar-sign-expansions.htm)을 참조하십시오.

## 다른 필드에서 선택된 값

수정자는 다른 필드의 선택된 값을 기반으로 할 수 있습니다. 예:

`<OrderDate = DeliveryDate>`

이 수정자는 `DeliveryDate`에서 선택된 값을 가져와 `OrderDate`에 선택 내용으로 적용합니다. 고유 값(수백 개 이상)이 많을 경우 이 연산은 CPU에 부하를 주므로 피해야 합니다.

## 요소 집합 함수

요소 집합은 집합 함수 `P()` (가능한 값) 및 `E()` (제외된 값)을 기반으로 할 수도 있습니다.

예를 들어 `Cap` 제품이 판매된 국가를 선택하려면 다음을 사용할 수 있습니다.

`<Country = P({1<Product={Cap}>} Country)>`

마찬가지로, 제품 `Cap`이(가) 판매되지 않은 국가를 선택하려면 다음과 같이 사용할 수 있습니다:

`<Country = E({1<Product={Cap}>} Country)>`

자세한 내용은 [집합 함수를 사용하는 집합 수정자](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-implicit-field-value-definitions.htm)을 참조하십시오.

## 자세한 정보

* [집합 분석](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-analysis-expressions.htm)

* [집합 식별자](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-identifiers.htm)

* [집합 연산자](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-operators.htm)