# Mode - 차트 함수

Mode() 는 집계된 데이터에서 가장 자주 발생하는 값인 모드 값을 찾습니다. Mode() 함수는 숫자 값뿐만 아니라 텍스트 값도 처리할 수 있습니다.

구문:

Mode({[SetExpression] [TOTAL [<fld {,fld}>]]} expr)

반환 데이터 유형: 이중

인수

| 인수 | 설명 |
| --- | --- |
| expr | 측정할 데이터가 포함된 표현식 또는 필드입니다. |
| SetExpression | 기본적으로 집계 함수는 선택에 의해 정의된 사용 가능한 레코드의 집합을 집계합니다. 집합 분석 표현식으로 대체 레코드 집합을 정의할 수 있습니다. |
| TOTAL | TOTAL이 함수 인수 앞에 오는 경우, 현재 선택을 고려하되 현재 차원 값에 관련되지 않은 가능한 모든 값에 대한 계산이 실행됩니다. 즉, 차트 차원은 무시됩니다.<br><br>TOTAL [&lt;fld {.fld}&gt;](여기서 TOTAL 한정자 뒤에는 하나 이상의 필드 이름 목록이 차트 차원 변수의 하위 집합으로 옴)을 사용하여 가능한 전체 값의 하위 집합을 만듭니다.<br><br>[집계 범위 정의](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |

예: 차트 표현식

| 예제 | 결과 |
| --- | --- |
| `Mode(UnitSales)` | `UnitSales`에서 가장 일반적으로 발생하는 값을 반환합니다.<br><br>`NULL (-)`을 반환합니다. 다른 값보다 발생 빈도가 높은 단일 값이 없습니다. |
| `Mode(Customer)` | `Customer`에서 가장 일반적으로 발생하는 값을 반환합니다.<br><br>`NULL (-)`을 반환합니다. 다른 값보다 발생 빈도가 높은 단일 값이 없습니다. |
| `Mode(TOTAL UnitSales)` | `TOTAL` 한정자는 차트 차원을 무시하고 `Unitsales`에서 가장 일반적으로 발생하는 값을 반환합니다. |
| `Mode({1} TOTAL UnitSales)` | 집합 분석 표현식 `{1}`은 선택한 내용과 관계없이 평가할 레코드 집합을 `ALL`로 정의합니다. 예를 들어, 특정 고객을 선택한 경우에도 전체 데이터 집합에서 가장 일반적으로 발생하는 `UnitSales` 값이 반환됩니다. |

## 예 - Mode 기본 사항

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/mode.htm)

#### 차트 표현식

개요

데이터 로드 편집기를 열고 새 섹션에 아래 로드 스크립트를 추가합니다.

로드 스크립트에는 다음이 포함됩니다.

* `Example`이라는 데이터 테이블에 로드되는 데이터 집합입니다.

* 데이터 테이블의 필드는 다음과 같습니다.

  * `Customer`

  * `UnitSales`

  * `UnitPrice`

로드 스크립트

```
Example:
LOAD * inline [
Customer|UnitSales|UnitPrice
Astrida|4|16
Astrida|10|15
Astrida|9|9
Astrida|10|10
Betacab|5|10
Betacab|4|20
Betacab||25
Canutility|8|15
Canutility|4|19
] (delimiter is '|');
```

결과

데이터를 로드하고 시트를 엽니다. 새 테이블을 만들고 이 필드를 차원으로 추가합니다.

* `Customer`

다음 측정값을 만듭니다.

* `=Mode(UnitSales)`: 가장 일반적으로 발생하는 `UnitSales` 값을 계산합니다.

* `=Mode(Customer)`: 가장 일반적으로 발생하는 `Customer` 값을 계산합니다.

* `=Mode(TOTAL UnitSales)`: 차트 차원을 무시하고 전체 데이터 집합에서 가장 일반적으로 발생하는 `UnitSales` 값을 계산합니다. 선택하면, 해당 선택 항목을 반영하여 값이 조정됩니다.

* `=Mode({1} TOTAL UnitSales)`: 선택 항목을 무시하고 가장 일반적으로 발생하는 `UnitSales` 값을 계산합니다. 선택하면, 값은 일정하게 유지됩니다.

Results table

| Customer | Mode(UnitSales) | Mode(Customer) | Mode(TOTAL UnitSales) | Mode({1} TOTAL UnitSales) |
| --- | --- | --- | --- | --- |
| Totals | 4 | Astrida | 4 | 4 |
| Astrida | 10 | Astrida | 4 | 4 |
| Betacab | - | Betacab | 4 | 4 |
| Canutility | - | Canutility | 4 | 4 |

이 예에서는 다음 사항을 관찰합니다.

* 첫 번째 측정값(`Mode(UnitSales)`)에서 고객 `Astrida`에게 가장 일반적으로 발생하는 값은 `10`입니다. `Totals` 셀은 `4`를 반환합니다. 이는 전체 데이터 집합에서 `UnitSales`에 대해 가장 일반적으로 발생하는 값입니다. `Betacab` 및 `Canutility`에 대해 가장 일반적으로 발생하는 값의 인스턴스가 없으므로 해당 고객에 대해 `NULL`이 반환됩니다.

* 두 번째 측정값(`Mode(Customer)`)에서는 각 고객 이름이 결과로 반환됩니다. 그러나 `Totals` 셀은 전체 데이터 집합에서 가장 일반적으로 발생하는 고객 값 `Astrida`를 반환합니다.

* 세 번째 측정값(`Mode(TOTAL UnitSales)`)은 값 4를 반환합니다. `Customer`가 선택되지 않은 경우 이 열의 모든 셀에 값 4가 표시됩니다. `Betacab`과 같은 고객을 선택하면 `Betacab`에 대해 일반적으로 발생하는 값이 없으므로 이 열은 `NULL`을 반환합니다.

* 네 번째 측정값(`Mode({1} TOTAL UnitSales)`)은 집합 분석 표현식 `{1}`이 평가할 레코드 집합을 `ALL`로 정의하므로 `Customer` 필드의 선택 항목에 관계없이 `4`를 반환합니다. 예를 들어, `Betacab`을 선택하면 이 열은 계속해서 `4` 값을 반환합니다.

## 예 - Mode 시나리오(판매 데이터의 이상 확인)

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/mode.htm)

#### 차트 표현식

개요

데이터 집합에는 월별 판매 수치가 포함되어 있습니다. 회사에서는 각 제품과 전체 데이터 집합에서 가장 일반적으로 발생하는 판매량 값을 보려고 합니다. 또한 데이터에서 비정상적인 이상을 식별하기 위해 제품별 판매량을 전체 데이터 집합과 비교하려고 합니다.

데이터 로드 편집기를 열고 새 섹션에 아래 로드 스크립트를 추가합니다.

로드 스크립트에는 다음이 포함됩니다.

* `Example`이라는 데이터 테이블에 로드되는 데이터 집합입니다.

* 데이터 테이블의 필드는 다음과 같습니다.

  * `Date`

  * `Product`

  * `Category`

  * `Sales`

로드 스크립트

```
Example:
Load * inline [
Date, Product, Category, Sales
2024-01-01, Apple, Fruit, 100
2024-01-15, Banana, Fruit, 80
2024-01-30, Carrot, Vegetable, 50
2024-02-05, Apple, Fruit, 100
2024-02-20, Banana, Fruit, 90
2024-02-28, Carrot, Vegetable, 60
2024-03-10, Apple, Fruit, 110
2024-03-22, Banana, Fruit, 80
2024-03-31, Carrot, Vegetable, 50
2024-04-10, Apple, Fruit, 125
2024-04-22, Banana, Fruit, 60
2024-04-31, Carrot, Vegetable, 80
];
```

결과

데이터를 로드하고 시트를 엽니다. 새 테이블을 만들고 다음 필드를 차원으로 추가합니다.

* `Category`

* `Product`

다음 측정값을 만듭니다.

* `=Mode(Sales)`: 각 제품에 대해 가장 일반적으로 발생하는 값을 계산합니다.

* `=Mode(TOTAL Sales)`: 전체 데이터 집합에서 가장 일반적으로 발생하는 값을 계산합니다.

* `If(Mode(Sales) = Mode(TOTAL Sales), 'Typical', 'Atypical')`: 전체 데이터 집합의 결과와 비교했을 때 각 제품의 가장 일반적으로 발생하는 값이 정형적인지 계산합니다.

Results table

| Category | Product | Mode(Sales) | Mode(TOTAL Sales) | If(Mode(Sales) = Mode(TOTAL Sales), 'Typical', 'Atypical') |
| --- | --- | --- | --- | --- |
| Fruit | Apple | 100 | 80 | Atypical |
| Fruit | Banana | 80 | 80 | Typical |
| Vegetable | Carrot | 50 | 80 | Atypical |

`Mode` 함수의 출력은 제품별로 가장 일반적으로 발생하는 판매량 값인 `Mode(Sales)`와 모든 제품별 판매량 값인 `Mode(TOTAL Sales)`를 반환합니다. 그런 다음 이 두 값을 비교하여 어떤 판매량 결과가 정형적인지, 어떤 판매량 결과가 비정형적인지 판별합니다.

## 자세한 정보

* [Avg - 차트 함수](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/StatisticalAggregationFunctionsinCharts/avg.htm)
* [Median - 차트 함수](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/StatisticalAggregationFunctionsinCharts/median.htm)
* [집합 분석](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-analysis-expressions.htm)
* [집계 범위 정의](https://help.qlik.com/ko-KR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm)