# 인라인 테이블에서 데이터 로드
인라인 테이블을 정의하려면 스크립트에 데이터를 수동으로 입력합니다.
파일과 데이터베이스에 연결하는 대신 스크립트에 데이터를 수동으로 입력하여 인라인 테이블을 만듭니다. 필수 구문을 사용하여 스크립트 텍스트가 인라인 데이터로 해석됨을 나타냅니다.
기본 인라인 로드는 테이블을 만들고 데이터 필드와 레코드를 삽입합니다.
## 인라인 로드를 사용하는 이유는 무엇입니까?
인라인 로드는 다양한 사용 사례에서 도움이 될 수 있습니다.
* 외부 소스에 연결할 필요 없이 데이터를 관리하고 편집합니다.
* 데이터 모델에서 기존 데이터를 보완합니다. 예를 들어, 대부분 데이터베이스 소스에서 가져오는 데이터 모델에 추가 테이블을 추가할 수 있습니다.
* 외부 소스에서 지속적으로 로드되지 않도록 하려는 데이터를 추가합니다. 데이터 소스가 나중에 변경될 수 있지만 데이터 값은 동일하게 유지되는 경우 시간을 절약할 수 있습니다.
* 다른 파일의 콘텐츠를 스크립트에 복사하고 붙여넣는 데 사용하기 쉽습니다. 예를 들어, 워드 프로세서 문서의 .csv 파일 또는 테이블입니다.
* 빠르게 복사하고 붙여넣을 수 있는 테스트 스크립트를 만듭니다.
## 기본 구문 예
다음 스크립트에는 간단한 인라인 로드가 포함되어 있습니다.
```
MyTable:
Load * Inline [Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
];
```
위의 인라인 로드에는 다음 구문이 사용됩니다.
* Load \* Inline을 사용하면 QlikView가 다음에 나오는 인라인 테이블의 모든 필드를 로드합니다.
* MyTable:은 테이블 이름을 정의합니다.
* 대괄호는 데이터를 묶습니다.
* LOAD 문의 첫 번째 줄은 데이터 필드를 정의합니다.
* 쉼표는 데이터 필드와 레코드를 구분합니다.
* 세미콜론은 LOAD 문을 닫습니다.
## 구문 개요
### 테이블 명명
로드된 다른 테이블과 마찬가지로 인라인 테이블의 이름을 추가할 수 있습니다. 테이블 이름 정의는 선택 사항입니다.
테이블 이름 뒤에 콜론을 삽입합니다.
### LOAD 및 inline 문
LOAD 스크립트 문을 사용하면 인라인 테이블이 inline 절과 함께 로드됩니다. inline 절은 테이블의 후속 텍스트에 편집기에 수동으로 입력된 데이터가 포함됨을 나타냅니다. 달리 지정하지 않는 한 인라인 테이블은 구분된 텍스트 파일의 구조를 따르는 txt 형식을 사용합니다.
LOAD 문에 대한 자세한 내용은 [Load](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm)를 참조하십시오.
### 엔클로저 및 데이터 입력
inline 절을 통해 입력된 데이터는 특정 문자로 묶어야 합니다. 다음은 데이터를 묶는 데 허용되는 문자 조합입니다.
* 대괄호: `[` 그리고 `]`
* 큰따옴표: `"` 그리고 `"`
* 작은따옴표: `'` 그리고 `'`
* 역따옴표: `` ` `` 그리고 `` ` ``
엔클로저로 선택한 문자는 충돌하는 문자가 포함된 인라인 데이터를 로드하는 데 도움이 될 수 있습니다. 예를 들어, 데이터에 대괄호가 포함된 레코드가 있는 경우 대신 따옴표나 역따옴표를 사용하여 묶을 수 있습니다.
대체 가능한 엔클로저의 예는 [예 - 대체 가능한 데이터 엔클로저](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDataEnc)을 참조하십시오.
대체 가능한 테이블 형식(기본값은 txt)을 지정하지 않는 한 엔클로저 사이의 텍스트는 파일 콘텐츠와 동일한 방식으로 해석됩니다. 따라서 텍스트 파일에 새 줄을 삽입하려면 스크립트를 입력할 때 Enter 키를 눌러 inline 절의 텍스트에도 삽입해야 합니다.
### 인라인 로드 종료
인라인 LOAD 문의 끝은 세미콜론으로 표시됩니다.
### 데이터 변환
변환이 없는 단순 인라인 로드에서는 열 수는 첫 번째 줄로 정의됩니다. 다음 예에서 로드된 테이블에는 세 개의 열이 있습니다. `Product_ID`, `Supplier_Name`, `Product_Category`.
```
Products:
Load * Inline [
Product_ID, Supplier_Name, Product_Category
1, Paracel, Home Decor
2, PageWave, Electronics
3, Talarian, Software
4, Userland, Appliances
];
```
동일한 인라인 테이블 내에서 변환을 수행하고 새 열을 만들 수도 있습니다. 선행 LOAD를 사용할 수 있으며 두 개 이상의 LOAD 문을 사용하여 동일한 테이블을 로드할 수 있습니다.
구체적인 예는 [예 - 변환이 포함된 인라인 로드](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExTransform)을 참조하십시오.
### 인라인 로드에서 형식 사양 구성
로드된 다른 테이블과 마찬가지로 형식 지정 항목을 사용하여 인라인 테이블의 형식 지정을 수정할 수 있습니다. 형식 사양은 괄호 안에 추가됩니다. 데이터 엔클로저 뒤에 추가해야 하지만 LOAD 문을 끝내는 세미콜론 앞에 추가해야 합니다. 추가할 수 있는 사용자 지정에는 다음이 포함됩니다.
* 구분 기호를 쉼표에서 다른 문자로 변경합니다. 예를 보려면 [예 - 대체 가능한 구분 기호](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDelimiter)를 참조하십시오.
자세한 내용은 [Delimiter](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/delimiter.htm)
* 테이블 열 헤더를 생략합니다. 예를 보려면 [예 - 열 헤더 생략](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOmitLabels)를 참조하십시오.
자세한 내용은 [Labels](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/labels.htm)
* 다른 데이터 형식(예: 고정 레코드 형식)을 사용합니다. 예를 보려면 [예 - 다른 데이터 유형 로드](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExChangeFormat)를 참조하십시오.
자세한 내용은 [테이블 형식](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/table-format.htm)
정보 메모인라인 로드에 모든 Table format 옵션이 지원되는 것은 아닙니다.
* 다중 행 콘텐츠를 허용합니다. 예를 보려면 [예 - 다중 행 콘텐츠](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExMultLine)를 참조하십시오.
자세한 내용은 [Quotes](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/quotes.htm)
동일한 테이블에서 여러 형식 사양 항목을 사용하려면 해당 항목을 쉼표로 구분합니다. 예:` (Delimiter is '|', no labels) `
형식 사양에 대한 자세한 내용은 [서식 사양 항목](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm)을 참조하십시오.
### 연산자 및 기타 조항
또한 인라인 로드는 LOAD 문이므로 LOAD 문에 대한 다른 인수를 인라인 로드에 결합할 수 있습니다. 예를 들어, where 또는 while 절을 사용하여 해당 행 내의 텍스트를 기반으로 특정 행을 로드할지 여부를 정의합니다.
마찬가지로 텍스트 콘텐츠 자체 외부에서 연산자를 사용할 수도 있습니다. 연산자를 사용하면 인라인 데이터를 변환하는 방법을 사용자 지정하고 특정 데이터를 로드할지 여부를 정의할 수도 있습니다.
구체적인 예는 [예 - 변환 및 절에 대한 연산자](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOpsAndClauses)을 참조하십시오.
## 예 - 대체 가능한 데이터 엔클로저
대괄호, 따옴표 또는 역따옴표를 사용하여 인라인 로드를 묶을 수 있습니다. 이 섹션에서는 이를 예로 설명합니다. 자세한 내용은 [엔클로저 및 데이터 입력](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Enclosure)을 참조하십시오.
#### 로드 스크립트 및 결과
개요
이 예에서는 역따옴표를 사용하여 인라인 데이터를 묶는 방법을 보여 줍니다. 이 예의 데이터에는 대괄호 문자가 포함되어 있어 대괄호가 LOAD 문의 엔클로저와 호환되지 않습니다.
로드 스크립트
```
DataTable:
Load * inline
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;
```
결과
* `custom_property`
* `date`
* `amount`
결과 테이블
| custom\_property | date | amount |
| --- | --- | --- |
| [11402] | 1/1/2024 | 92.99 |
| [11403] | 1/2/2024 | 102.34 |
| [11404] | 1/3/2024 | 50.26 |
| [11405] | 1/4/2024 | 153.69 |
| [11406] | 1/5/2024 | 75.62 |
## 예 - 대체 가능한 구분 기호
쉼표 이외의 문자를 사용하여 테이블의 열 값을 구분할 수 있습니다. 자세한 내용은 [인라인 로드에서 형식 사양 구성](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec)을 참조하십시오.
#### 로드 스크립트 및 결과
개요
구분 기호를 교환하는 것은 테이블의 데이터에 쉼표가 포함되어 있을 때 유용합니다. 그렇지 않으면 테이블의 다음 열로 전환하라는 신호가 됩니다.
이 예에는 다음이 포함되어 있습니다.
* 로드할 4개의 테이블입니다. 다음과 같습니다.
* Table1: 구분 기호는 세로 막대(파이프)입니다. Phrase 열의 데이터에 쉼표가 포함되어 있습니다.
* Table2: 구분 기호는 콜론입니다.
* Table3: 구분 기호는 백슬래시입니다.
* Table4: 키보드의 Tab 키를 누르면 표가 구분됩니다. 이 옵션은 워드 프로세서에서 테이블을 복사하여 스크립트에 붙여넣을 때 유용합니다.
Table1은 대체 가능한 구분 기호를 사용하는 실제 사용 사례를 보여 줍니다. 다른 테이블에는 더 많은 구분 기호 옵션이 표시됩니다.
로드 스크립트
```
Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');
Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');
Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);
Table4:
LOAD * INLINE [
Num3 Chr3
1 A
2 B ] (Delimiter is '\t');
```
결과
결과 테이블: Table1Table1
| ID | Phrase |
| --- | --- |
| 1 | The transaction was complete, but the order has not yet shipped. |
| 2 | We need to confirm the following details: sales rep number, order status, and shipping priority. |
결과 테이블: Table2Table2
| Num1 | Chr1 |
| --- | --- |
| 1 | A |
| 2 | B |
결과 테이블: Table3Table3
| Num2 | Chr2 |
| --- | --- |
| 1 | A |
| 2 | B |
결과 테이블: Table4Table4
| Num3 | Chr3 |
| --- | --- |
| 1 | A |
| 2 | B |
## 예 - 열 헤더 생략
열 헤더를 정의하지 않고 인라인 테이블을 로드하려면 형식 사양을 편집합니다. 이는 labels 사양(no labels 값으로 설정)을 통해 수행됩니다. 자세한 내용은 [인라인 로드에서 형식 사양 구성](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec)을 참조하십시오.
열 이름을 정의하지 않고 테이블을 로드하면 시스템 정의 열 이름이 자동으로 사용됩니다.
#### 로드 스크립트 및 결과
개요
이 예에서는 열 이름을 정의하지 않고 인라인 테이블을 로드하는 방법을 보여 줍니다.
로드 스크립트
```
Expenses:
Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);
```
결과
결과 테이블
| @1 | @2 | @3 |
| --- | --- | --- |
| 1 | Category1 | 40566.49 |
| 2 | Category2 | 3504.54 |
| 3 | Category3 | 593206.30 |
## 예 - 다른 데이터 유형 로드
이 예에서는 고정 레코드 형식으로 인라인 테이블을 로드하는 방법을 보여 줍니다. [인라인 로드에서 형식 사양 구성](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec)를 참조하십시오.
#### 로드 스크립트 및 결과
개요
이 스크립트 예에는 다음이 포함되어 있습니다.
* DataTable 테이블을 정의하는 인라인 LOAD 문입니다.
* 로드할 데이터가 고정 레코드 형식임을 나타내기 위해 fix(Table format 사양의 일부)를 사용합니다.
로드 스크립트
```
DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a b c d
1 2 3 4
x y z w
] (fix, utf8, embedded labels);
```
결과
결과 테이블
| a | b | c | d |
| --- | --- | --- | --- |
| 1 | 2 | 3 | 4 |
| x | y | z | w |
## 예 - 다중 행 콘텐츠
이 예에서는 인라인 테이블에 다중 행 필드 콘텐츠를 입력하는 방법을 보여 줍니다. [인라인 로드에서 형식 사양 구성](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec)를 참조하십시오.
#### 로드 스크립트 및 결과
개요
이 스크립트 예에는 다음이 포함되어 있습니다.
* T1 테이블을 정의하기 위한 간단한 인라인 로드.
* 다중 행 콘텐츠를 지원하려면 Quotes 지정자(값 msq 포함)를 사용합니다.
* 피트와 인치로 지정된 길이 값입니다.
* 큰따옴표 기호(")는 다중 행 항목의 끝을 나타냅니다. 이 예에서는 인치 값을 나타내는 데에도 동일한 기호가 사용됩니다. 이는 동일한 LOAD 문에서 두 가지를 모두 사용해야 하는 경우 구문과 결과 동작을 표시하기 위해 수행됩니다. 기본적으로 두 개의 연속 문자("")에 대해 " 기호를 입력하면 코드가 기호의 단일 텍스트 인스턴스로 해석된다는 의미입니다.
로드 스크립트
```
T1:
Load *, recno() as ID inline [
Length
"1' 2""
22' 10"""
14' 8" ] (msq);
```
결과
다중 행으로 구성된 콘텐츠를 의도한 대로 보려면 속성... 구성에서 차트의 다중 행 설정을 조정해야 합니다.
결과 테이블
| ID | Length |
| --- | --- |
| 1 | 1' 2"
22' 10" |
| 2 | 14' 8" |
위 표에서 ID 값이 1인 레코드에는 다중 행 콘텐츠가 포함되어 있습니다.
## 예 - 변환이 포함된 인라인 로드
이 예에서는 인라인으로 로드된 필드에 대해 계산을 수행하여 데이터 모델에 새 필드를 만드는 방법을 보여 줍니다.
자세한 내용은 [데이터 변환](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Transform)을 참조하십시오.
#### 예: 필드의 간단한 이름 바꾸기
로드 스크립트
```
ORDERS:
Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];
```
결과
결과 테이블
| Original | Updated |
| --- | --- |
| ProductA | ProductA |
| ProductB | ProductB |
| ProductC | ProductC |
#### 예: ID 필드의 단순 삽입
개요
이 예에서는 각 ID 값을 수동으로 입력하지 않고도 각 데이터 행의 ID를 나타내도록 계산 필드를 정의할 수 있는 방법을 보여 줍니다.
로드 스크립트
```
ORDERS:
Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];
```
결과
결과 테이블
| ID | ProductName |
| --- | --- |
| 1 | A |
| 2 | B |
| 3 | C |
| 4 | D |
| 5 | E |
#### 예: 변환을 처리하도록 LOAD 문 구성
개요
이 예에서는 인라인 데이터에 단순 변환을 적용할 수 있는 여러 가지 방법을 보여 줍니다. 하나 이상의 LOAD 문을 사용하고 다양한 방식으로 구문을 구성하여 변환이 원래 필드를 바꿀지 여부 또는 원래 필드와 새 필드를 모두 로드할지 정의할 수 있습니다.
특히 다음의 변형과 이것이 출력에 어떤 영향을 미치는지 확인합니다.
* 테이블 내의 LOAD 문의 수.
* \* 기호의 유무(모든 후속 필드 로드)
* 쉼표(, 기호)의 유무.
이 스크립트 예에는 다음이 포함되어 있습니다.
* 4개의 테이블은 모두 동일한 데이터를 참조하십시오. 필드 이름이 다릅니다.
* DerivedYears1: 두 개의 LOAD 문을 사용하여 인라인 열과 인라인 열의 변환이 포함된 열을 로드합니다.
* DerivedYears2: 두 개의 LOAD 문을 사용합니다. 스크립트는 인라인 열을 로드한 다음 원래 열에서 변환된 계산 필드를 로드합니다. 두 번째 LOAD 문을 사용하면 원래 열이 테이블에 로드되지 않아 새 필드가 원래 필드를 바꾸게 됩니다.
* DerivedYears3: 단일 LOAD 문을 사용하여 원래 인라인 열과 변환된 열을 모두 로드합니다.
* DerivedYears4: 단일 LOAD 문을 사용하여 인라인 필드와 원래 필드의 변환을 정의합니다. 변환된 필드만 테이블에 로드됩니다.
로드 스크립트
```
DerivedYears1:
Load *,
Year(initial_date1) as derived_year1
;
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears2:
Load
Year(initial_date2) as derived_year2
;
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears3:
Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears4:
Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
```
결과
결과 테이블: DerivedYears1DerivedYears1
| initial\_date1 | derived\_year1 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
결과 테이블: DerivedYears2DerivedYears2
| derived\_year2 |
| --- |
| 2022 |
| 2023 |
| 2024 |
결과 테이블: DerivedYears3DerivedYears3
| initial\_date3 | derived\_year3 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
결과 테이블: DerivedYears4DerivedYears4
| derived\_year4 |
| --- |
| 2022 |
| 2023 |
| 2024 |
#### 예: 필드 콘텐츠 수정
개요
큰 텍스트 파일의 정보를 스크립트 편집기에 붙여넣고 데이터 집합의 레코드에 대해 추가 처리를 수행한다고 가정해 보겠습니다. 예를 들어, 특정 문자와 접두사를 제거하고 각 단어를 대문자로 표시하려고 합니다.
이 스크립트 예에는 다음이 포함되어 있습니다.
* 필드의 텍스트 콘텐츠를 변경하기 위해 변환이 정의된 인라인 테이블 Transformations. 변환되는 텍스트는 이후에 추가됩니다.
* 두 개의 LOAD 문. 이 예의 구성을 사용하면 파생 필드 ProductName\_Trimmed만 테이블에 로드됩니다.
로드 스크립트
```
Transformations:
Load
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;
Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product: {snack food}
Product: {electronics and video games}
];
```
결과
결과 테이블
| ProductName\_Trimmed |
| --- |
| Soft Drinks And Other Beverages |
| Snack Food |
| Electronics And Video Games |
## 예 - 변환 및 절에 대한 연산자
연산자를 사용하여 LOAD 문에서 변환 및 특정 절을 정의할 수 있습니다. 자세한 내용은 [연산자 및 기타 조항](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#OpsAndClauses)을 참조하십시오.
[연산자](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/Operators/operators.htm)
#### 로드 스크립트 및 결과
개요
이 스크립트 예에는 다음이 포함되어 있습니다.
* Purchases 테이블을 정의하기 위한 간단한 인라인 로드.
* 계산 필드 OrderSize 삽입. 이 필드는 인라인 데이터 집합의 amount 필드를 변환한 것입니다. 금액이 $2000.00을 초과하는지 여부에 따라 구매를 소규모 또는 대규모로 분류합니다.
* amount가 $0.05 미만일 때 레코드가 로드되지 않도록 하는 where 절입니다.
로드 스크립트
```
Purchases:
Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,
* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;
```
결과
결과 테이블
| ID | amount | OrderSize |
| --- | --- | --- |
| 1 | 2660.39 | Large Purchase |
| 2 | 100.01 | Small Purchase |
| 3 | 500.42 | Small Purchase |
| 4 | 5023.99 | Large Purchase |
| 6 | 2002.39 | Large Purchase |
| 7 | 31034.53 | Large Purchase |
| 8 | 1643.58 | Small Purchase |
| 9 | 3993.65 | Large Purchase |
| 10 | 614.34 | Small Purchase |
| 11 | 675.93 | Small Purchase |
위 표에서는 ID가 5인 트랜잭션이 테이블에 로드되지 않았습니다. 이는 amount 값이 $0.05보다 작기 때문입니다.
## 예 - 인라인 테이블에 null 값 만들기
이 예에서는 NullInterpret 변수를 사용하여 인라인 데이터에 null 값을 만드는 방법을 보여 줍니다.
[NullInterpret](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ValueHandlingVariables/NullInterpret.htm)
#### 로드 스크립트 및 결과
개요
이 스크립트 예에는 다음이 포함되어 있습니다.
* T2 테이블을 정의하기 위한 간단한 인라인 로드.
* 두 개의 작은따옴표로 정의된 NullInterpret 변수. 스크립트가 로드되면 이 값이 포함된 레코드는 null 값으로 처리됩니다.
로드 스크립트
```
set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];
```
결과
결과 테이블
| Test |
| --- |
| x |
위 표에서 첫 번째 레코드는 null 값입니다. 따라서 시각화에 포함되지 않습니다. 추가 차원이 있는 테이블에 존재하는 null 값은 - 기호로 표시됩니다.
## 더 많은 예
추가 예는 [Load](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm)를 참조하십시오.
## 자세한 정보
* [Load](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm)
* [서식 사양 항목](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm)
* [인라인 데이터 마법사](https://help.qlik.com/ko-KR/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Inline_Data_Wizard.htm)