# set 修飾子

set 数式は計算の範囲を定義するために使用されます。set 数式の中心部分は、選択を指定する set 修飾子です。これは、ユーザーの選択、または set 識別子の選択を変更するために使用され、結果は計算の新しいスコープを定義します。

set 修飾子は、1 つまたは複数の項目名で構成されます。各項目名の後には、項目で実行する必要がある選択が続きます。修飾子は山括弧 (&lt; &gt;)でくくります: `< >`

例:

* `Sum ( {$<Year = {2015}>} Sales )`

* `Count ( {1<Country = {Germany}>} distinct OrderID )`

* `Sum ( {$<Year = {2015}, Country = {Germany}>} Sales )`

## 要素セット

要素セットは、以下を使用して定義できます。

* 値のリスト

* 検索

* 別の項目への参照

* set 関数

要素セットの定義を省略した場合、set 修飾子はこの項目の選択をすべてクリアします。例:

`Sum( {$<Year = >} Sales )`

## 例: 要素セットに基づく set 修飾子のチャートの数式

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers.htm)

#### 例 - チャートの数式

ロード スクリプト

以下のデータをインライン データとしてデータロードエディタにロードして、以下のチャートの数式の例を作成します。

```
MyTable:
Load * Inline [
Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
Belgium, 2014, 182766.87
Belgium, 2015, 178042.33
Brazil, 2014, 174492.67
Brazil, 2015, 2104.22
Canada, 2014, 101801.33
Canada, 2015, 40288.25
Denmark, 2014, 45273.25
Denmark, 2015, 106938.41
Finland, 2014, 107565.55
Finland, 2015, 30583.44
France, 2014, 115644.26
France, 2015, 30696.98
Germany, 2014, 8775.18
Germany, 2015, 77185.68
];
```

インライン ロードの使用の詳細については、「[インライン ロードを使用したデータのロード](https://help.qlik.com/ja-JP/sense/November2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm)」を参照してください。

チャートの数式

次のチャートの数を使用して、Qlik Sense シートにテーブルを作成します。

テーブル - 要素セットに基づく set 修飾子

| 国 | Sum(Sales) | Sum({1&lt;Country={Belgium}&gt;} Sales) | Sum({1&lt;Country={"\*A\*"}&gt;} Sales) | Sum({1&lt;Country={"A\*"}&gt;} Sales) | Sum({1&lt;Year={$(=Max(Year))}&gt;} Sales) |
| --- | --- | --- | --- | --- | --- |
| 合計 | 1645397.3 | 360809.2 | 1284588.1 | 443238.88 | 788617.07 |
| アルゼンチン | 206332.92 | 0 | 206332.92 | 206332.92 | 140037.89 |
| オーストリア | 236905.96 | 0 | 236905.96 | 236905.96 | 182739.87 |
| ベルギー | 360809.2 | 360809.2 | 0 | 0 | 178042.33 |
| ブラジル | 176596.89 | 0 | 176596.89 | 0 | 2104.22 |
| カナダ | 142089.58 | 0 | 142089.58 | 0 | 40288.25 |
| デンマーク | 152211.66 | 0 | 152211.66 | 0 | 106938.41 |
| フィンランド | 138148.99 | 0 | 138148.99 | 0 | 30583.44 |
| フランス | 146341.24 | 0 | 146341.24 | 0 | 30696.98 |
| ドイツ | 85960.86 | 0 | 85960.86 | 0 | 77185.68 |

説明

* 軸：

  * `Country`

* 数式：

  * `Sum(Sales)`

    式が設定されていない `Sales` を合計します。

  * `Sum({1<Country={Belgium}>}Sales)`

    `Belgium` を選択し、対応する `Sales` を合計します。

  * `Sum({1<Country={"*A*"}>}Sales)`

    `A` を持つすべての国を選択し、対応する `Sales` を合計します。

  * `Sum({1<Country={"A*"}>}Sales)`

    `A` で始まるすべての国を選択し、対応する `Sales` を合計します。

  * `Sum({1<Year={$(=Max(Year))}>}Sales)`

    `2015` である `Max(Year)` を計算し、対応する `Sales` を合計します。

要素セットに基づく set 修飾子

要素セットに基づく set 修飾子

要素セットに基づく set 修飾子 ![要素セットに基づく set 修飾子。](https://help.qlik.com/ja-JP/sense/November2025/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_set_modifiers_element_sets.png)

## リストされた値

要素セットの最も一般的な例は、中括弧で囲まれた項目値のリストに基づく数式です。例:

* `{$<Country = {Canada, Germany, Singapore}>}`

* `{$<Year = {2015, 2016}>}`

内側の中括弧は要素セットを定義します。個々の値はコンマで区切られます。

## 引用符と大文字と小文字の区別

値にブランクまたは特殊文字が含まれている場合は、値を引用符で囲む必要があります。一重引用符は、単一の項目値と文字通りの大文字と小文字を区別して一致します。二重引用符は、1 つまたは複数の項目値と大文字と小文字を区別しない一致を意味します。例:

* `<Country = {'New Zealand'}>`

  `New Zealand` のみに一致します。

* `<Country = {"New Zealand"}>`

  `New Zealand`、`NEW ZEALAND`、`new zealand` に一致します。

日付は引用符で囲み、問題の項目の日付形式を使用する必要があります。例:

* `<ISO_Date = {'2021-12-31'}>`

* `<US_Date = {'12/31/2021'}>`

* `<UK_Date = {'31/12/2021'}>`

二重引用符は角括弧またはアクサン グラーブで置き換えることができます。

## 検索

要素セットは検索によって作成することもできます。例:

* `<Country = {"C*"}>`
* `<Ingredient = {"*garlic*"}>`
* `<Year = {">2015"}>`
* `<Date = {">12/31/2015"}>`

ワイルドカードはテキスト検索で使用できます。アスタリスク (`*`) は任意の数の文字を表し、疑問符 (`?`) は単一の文字を表します。関係演算子を使用して、数値検索を定義できます。

検索には常に二重引用符を使用する必要があります。検索値では、大文字と小文字が区別されます。

詳細については、「[検索を使った set 修飾子](https://help.qlik.com/ja-JP/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-advanced-searches.htm)」を参照してください。

## ドル展開

要素セット内で計算を使用する場合は、ドル展開が必要です。例えば、可能性のある最後の年のみを確認する場合は、次を使用できます:

`<Year = {$(=Max(Year))}>`

詳細については、「[ドル記号展開を使った set 修飾子](https://help.qlik.com/ja-JP/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-dollar-sign-expansions.htm)」を参照してください。

## 他の項目で選択された値

修飾子は、別の項目の選択された値に基づく場合もあります。例:

`<OrderDate = DeliveryDate>`

この修飾子は、`DeliveryDate` から選択値を取得し、`OrderDate` に適用します。200 以上の多くの固有値がある場合、この操作は CPU を集中して使用するため、行わないでください。

## 要素セット関数

要素集合は、集合関数 `P()` (取り得る値) と`E()` (除外値) に基づくこともできます。

例えば、製品 `Cap` が販売されている国を選択したい場合、次を使用できます。

`<Country = P({1<Product={Cap}>} Country)>`

同様に、製品 `Cap` が販売されていない国を選択したい場合、次を使用できます。

`<Country = E({1<Product={Cap}>} Country)>`

詳細については、「[set 関数を使用した set 修飾子](https://help.qlik.com/ja-JP/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-implicit-field-value-definitions.htm)」を参照してください。

## 詳細を見る

* [set 分析](https://help.qlik.com/ja-JP/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-analysis-expressions.htm)

* [set 識別子](https://help.qlik.com/ja-JP/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-identifiers.htm)

* [set 演算子](https://help.qlik.com/ja-JP/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-operators.htm)