# wildmatch - スクリプトおよびチャート関数

wildmatch 関数は、最初のパラメーターとそれに続くすべてのパラメーターを比較し、一致した数式の数を返します。比較文字列でワイルドカード文字 ( \* および ?) を使用できます。 \* は任意の文字のシーケンスと一致します。? は任意の 1 文字と一致します。比較では大文字と小文字は区別されず、日本語のひらがなとカタカナも区別されません。

構文:

wildmatch( str, expr1 [ , expr2,...exprN ])

ワイルドカードを使用せずに比較を行う場合は、match 関数または mixmatch 関数を使用します。

このトピックの例のいくつかは、インライン ロードを使用しています。詳細については、「[インライン ロードを使用したデータのロード](https://help.qlik.com/ja-JP/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm)」を参照してください。

## 例: wildmatch を使用したロード スクリプト

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/wildmatch.htm)

#### 例: ロード スクリプト

ロード スクリプト

wildmatch を使用してデータのサブセットをロードできます。たとえば、関数内の数式の数値を返すことができます。次に、その数値に基づいて、ロードされるデータを制限できます。一致がない場合、Wildmatch は 0 を返します。よって、この例に適合しないすべての数式は 0 を返し、WHERE ステートメントによるデータ ロードから除外されます。

データ ロード エディタで新しいタブを作成し、次のデータをインライン ロードとしてロードします。結果を確認するには、以下の Qlik Sense のテーブルを作成します。

```
Transactions:
Load * Inline [
transaction_id, transaction_date, transaction_amount, transaction_quantity, customer_id, size, color_code
3750, 20180830, 23.56, 2, 2038593, L, Red
3751, 20180907, 556.31, 6, 203521, m, orange
3752, 20180916, 5.75, 1, 5646471, S, blue
3753, 20180922, 125.00, 7, 3036491, l, Black
3754, 20180922, 484.21, 13, 049681, xs, Red
3756, 20180922, 59.18, 2, 2038593, M, Blue
3757, 20180923, 177.42, 21, 203521, XL, Black
];
 
/*
Create new table called Transaction_Buckets
Create new fields called Customer, and Color code - Black, Blue, blue, red
Load Transactions table.
Wildmatch returns 1 for 'Black', 'Blue', and 'blue', and 2 for 'Red'. 
Only values that returned numeric value greater than 0 
are loaded by WHERE statement into Transactions_Buckets table.
*/
 
Transaction_Buckets:
Load
   customer_id,
   customer_id as [Customer],
   color_code as [Color Code Black, Blue, blue, Red]
Resident Transactions
Where wildmatch(color_code,'Bl*','R??') > 0;
```

結果

ロード スクリプトで wildmatchwildmatch 関数を使用した結果の出力を示す Qlik SenseQlik Sense テーブル

| Color Code Black, Blue, blue, Red | 顧客 |
| --- | --- |
| Black | 203521 |
| Black | 3036491 |
| Blue | 2038593 |
| blue | 5646471 |
| Red | 049681 |
| Red | 2038593 |

## 例: wildmatch を使用したチャートの数式

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/wildmatch.htm)

#### 例: チャートの数式

チャートの数式 1

データ ロード エディタで新しいタブを作成し、次のデータをインライン ロードとしてロードします。データをロードした後、以下のチャートの数式の例を Qlik Sense テーブルに作成します。

```
MyTable:
Load * inline [Cities, Count
Toronto, 123
Toronto, 234
Toronto, 231
Boston, 32
Boston, 23
Boston, 1341
Beijing, 234
Beijing, 45
Beijing, 235
Stockholm, 938
Stockholm, 39
Stockholm, 189
zurich, 2342
zurich, 9033
zurich, 0039];
```

以下のテーブルの最初の数式は Stockholm の場合に 0 を返します。これは、wildmatch 関数の数式のリストに「Stockholm」が含まれていないからです。また、? は 1 つの文字のみに一致するため、「Boston」に対しても 0 を返します。

Qlik SenseQlik Sense のテーブルは、チャートの数式における wildmatchwildmatch 関数の例を示しています

| Cities | wildmatch( Cities,'Tor\*','?ton','Beijing','\*urich') | wildmatch( Cities,'Tor\*','???ton','Beijing','Stockholm','\*urich') |
| --- | --- | --- |
| Beijing | 3 | 3 |
| Boston | 0 | 2 |
| Stockholm | 0 | 4 |
| Toronto | 1 | 1 |
| zurich | 4 | 5 |

チャートの数式 2

wildmatch を使用して、1 つの数式のカスタム ソートを実行できます。

既定では、データに応じて、列が数値またはアルファベット順にソートされます。

既定のソート順の例を示した Qlik SenseQlik Sense テーブル

| Cities |
| --- |
| Beijing |
| Boston |
| Stockholm |
| Toronto |
| zurich |

順序を変更するには、以下のステップを実行します。

1. プロパティ パネルで、グラフの [ソート] セクションを開きます。

2. カスタム ソートを適用する列の自動ソートをオフにします。

3. [数値によるソート] と [アルファベット順でソート] の選択を解除します。

4. [数式によるソート] を選択し、次に似た数式を入力します。

   `=wildmatch( Cities, 'Tor*','???ton','Beijing','Stockholm','*urich')`

   Cities 列のソート順序が変更されます。

wildmatchwildmatch 関数を使用したソート順の変更例を示した Qlik SenseQlik Sense テーブル。

| Cities |
| --- |
| トロント |
| Boston |
| Beijing |
| Stockholm |
| zurich |

返される数値を表示することもできます。

wildmatchwildmatch 関数から返される数値の例を示した Qlik SenseQlik Sense テーブル

| 都市 | Cities & ' - ' & wildmatch ( Cities, 'Tor\*','???ton','Beijing','Stockholm','\*urich') |
| --- | --- |
| Toronto | Toronto - 1 |
| Boston | Boston - 2 |
| Beijing | Beijing - 3 |
| Stockholm | Stockholm - 4 |
| zurich | zurich - 5 |

## 詳細を見る

* [match - スクリプトおよびチャート関数](https://help.qlik.com/ja-JP/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/match.htm)
* [mixmatch - スクリプトおよびチャート関数](https://help.qlik.com/ja-JP/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/mixmatch.htm)