# wildmatch - funzione dello script e del grafico

La funzione wildmatch confronta il primo parametro con quelli seguenti e restituisce il numero di espressioni corrispondenti. Consente l'utilizzo di caratteri jolly ( \* e ?) per il confronto delle stringhe. \* corrisponde a qualsiasi sequenza di caratteri. ? corrisponde a qualsiasi carattere singolo. Il confronto non distingue tra caratteri maiuscoli o minuscoli né i sistemi di caratteri del giapponese hiragana e katakana.

Sintassi:

wildmatch( str, expr1 [ , expr2,...exprN ])

Se si desidera utilizzare il confronto senza caratteri speciali, usare le funzioni match o mixmatch.

Alcuni degli esempi in questo argomento utilizzano caricamenti inline. [Utilizzo dei caricamenti inline per caricare i dati](https://help.qlik.com/it-IT/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm)

## Esempio: script di caricamento che usa wildmatch

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/wildmatch.htm)

#### Esempio: script di caricamento

Script di caricamento

È possibile utilizzare wildmatch per caricare un sottogruppo dei dati. Ad esempio, è possibile restituire un valore numerico per un'espressione nella funzione. È quindi possibile limitare i dati caricati in base al valore numerico. Wildmatch restituisce 0 se non vi sono corrispondenze. Tutte le espressioni senza corrispondenze in questo esempio restituiranno quindi 0 e saranno escluse dal caricamento dei dati dall'istruzione WHERE.

Creare una nuova scheda nell'editor caricamento dati, quindi caricare i seguenti dati come caricamento inline. Creare la tabella in basso in Qlik Sense per visualizzare i risultati.

```
Transactions:
Load * Inline [
transaction_id, transaction_date, transaction_amount, transaction_quantity, customer_id, size, color_code
3750, 20180830, 23.56, 2, 2038593, L, Red
3751, 20180907, 556.31, 6, 203521, m, orange
3752, 20180916, 5.75, 1, 5646471, S, blue
3753, 20180922, 125.00, 7, 3036491, l, Black
3754, 20180922, 484.21, 13, 049681, xs, Red
3756, 20180922, 59.18, 2, 2038593, M, Blue
3757, 20180923, 177.42, 21, 203521, XL, Black
];
 
/*
Create new table called Transaction_Buckets
Create new fields called Customer, and Color code - Black, Blue, blue, red
Load Transactions table.
Wildmatch returns 1 for 'Black', 'Blue', and 'blue', and 2 for 'Red'. 
Only values that returned numeric value greater than 0 
are loaded by WHERE statement into Transactions_Buckets table.
*/
 
Transaction_Buckets:
Load
   customer_id,
   customer_id as [Customer],
   color_code as [Color Code Black, Blue, blue, Red]
Resident Transactions
Where wildmatch(color_code,'Bl*','R??') > 0;
```

Risultati

Tabella Qlik SenseQlik Sense che mostra l'output derivante dall'utilizzo della funzione wildmatchwildmatch nello script di caricamento

| Codice colore Nero, Blu, blu, Rosso | Cliente |
| --- | --- |
| Nero | 203521 |
| Nero | 3036491 |
| Blu | 2038593 |
| blu | 5646471 |
| Red | 049681 |
| Red | 2038593 |

## Esempi - Espressioni dei grafici che usano wildmatch

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/wildmatch.htm)

#### Esempio: espressione del grafico

Espressione del grafico 1

Creare una nuova scheda nell'editor caricamento dati, quindi caricare i seguenti dati come caricamento inline. Dopo aver caricato i dati, creare gli esempi di espressione del grafico in basso in una tabella Qlik Sense.

```
MyTable:
Load * inline [Cities, Count
Toronto, 123
Toronto, 234
Toronto, 231
Boston, 32
Boston, 23
Boston, 1341
Beijing, 234
Beijing, 45
Beijing, 235
Stockholm, 938
Stockholm, 39
Stockholm, 189
zurich, 2342
zurich, 9033
zurich, 0039];
```

La prima espressione nella tabella sottostante restituisce 0 per Stockholm perché "Stockholm" non è inclusa nell'elenco di espressioni nella funzione wildmatch. Restituisce anche 0 "Boston", perché ? corrisponde solo a un singolo carattere.

Tabella Qlik SenseQlik Sense che mostra esempi della funzione wildmatchwildmatch in un'espressione del grafico

| Cities | wildmatch( Cities,'Tor\*','?ton','Beijing','\*urich') | wildmatch( Cities,'Tor\*','???ton','Beijing','Stockholm','\*urich') |
| --- | --- | --- |
| Beijing | 3 | 3 |
| Boston | 0 | 2 |
| Stockholm | 0 | 4 |
| Toronto | 1 | 1 |
| zurich | 4 | 5 |

Espressione del grafico 2

È possibile utilizzare wildmatch per eseguire un ordinamento personalizzato per un'espressione.

Per impostazione predefinita, le colonne vengono ordinate numericamente o alfabeticamente, a seconda dei dati.

Tabella Qlik SenseQlik Sense che mostra un esempio dell'impostazione di ordinamento predefinita

| Cities |
| --- |
| Beijing |
| Boston |
| Stockholm |
| Toronto |
| zurich |

Per modificare l'ordine, procedere come segue:

1. Aprire la sezione Ordinamento del grafico nel pannello Proprietà.

2. Disattivare l'ordinamento automatico per la colonna su cui si desidera eseguire un ordinamento personalizzato.

3. Deselezionare Ordina per numero ​​e Ordina per lettera.

4. Selezionare Ordina per espressione e quindi inserire un'espressione simile alla seguente:

   `=wildmatch( Cities, 'Tor*','???ton','Beijing','Stockholm','*urich')`

   L'ordinamento della colonna Cities verrà modificato.

Tabella Qlik SenseQlik Sense che mostra un esempio di modifica dell'ordinamento mediante la funzione wildmatchwildmatch.

| Cities |
| --- |
| Toronto |
| Boston |
| Beijing |
| Stockholm |
| zurich |

È inoltre possibile visualizzare il valore numerico restituito.

Tabella Qlik SenseQlik Sense che mostra un esempio dei valori numerici restituiti dalla funzione wildmatchwildmatch

| Città | Cities & ' - ' & wildmatch ( Cities, 'Tor\*','???ton','Beijing','Stockholm','\*urich') |
| --- | --- |
| Toronto | Toronto - 1 |
| Boston | Boston - 2 |
| Beijing | Beijing - 3 |
| Stockholm | Stockholm - 4 |
| zurich | zurich - 5 |

## Ulteriori informazioni

* [match - funzione dello script e del grafico](https://help.qlik.com/it-IT/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/match.htm)
* [mixmatch - funzione dello script e del grafico](https://help.qlik.com/it-IT/sense/May2025/Subsystems/Hub/Content/Sense_Hub/Scripting/ConditionalFunctions/mixmatch.htm)