# Caricamento dei dati da tabelle inline
Digitare manualmente i dati in uno script per definire una tabella inline.
È possibile creare tabelle inline digitando manualmente i dati nello script, anziché collegarsi a file e database. Utilizzare la sintassi richiesta per indicare che il testo dello script deve essere interpretato come dati inline.
Un caricamento inline di base crea una tabella e inserisce i campi dati e i record.
## Perché utilizzare i carichi inline?
I carichi inline possono essere utili in diversi casi d'uso:
* Amministrare e modificare i dati senza doversi collegare a fonti esterne.
* Integrare i dati esistenti nel modello di dati. Ad esempio, è possibile aggiungere una tabella supplementare a un modello di dati che proviene principalmente da fonti di database.
* Aggiungere dati che si desidera evitare di caricare continuamente da fonti esterne. Questo può far risparmiare tempo se si sa che la sorgente dati potrebbe cambiare in futuro, ma i valori dei dati rimarranno gli stessi.
* Facilità di utilizzo per copiare e incollare contenuti nello script da altri file. Ad esempio, file o tabelle .csv da documenti di elaborazione testi.
* Creare script di test che possono essere copiati e incollati rapidamente.
## Esempio di sintassi di base
Il seguente script contiene un semplice caricamento inline.
```
MyTable:
Load * Inline [Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
];
```
La sintassi utilizzata per il caricamento inline è la seguente:
* Load \* Inline istruisce QlikView a caricare tutti i campi dalla tabella inline che segue.
* MyTable: definisce il nome della tabella.
* Le parentesi quadre racchiudono i dati.
* La prima riga dell'istruzione LOAD definisce i campi dati.
* Le virgole separano i campi di dati e i record.
* Il punto e virgola chiude l'istruzione LOAD.
## Panoramica della sintassi
### Denominazione della tabella
È possibile aggiungere un nome alla tabella inline, come per le altre tabelle caricate. La definizione del nome della tabella è facoltativa.
Dopo il nome della tabella, inserire i due punti.
### Istruzioni LOAD e inline
Una tabella inline viene caricata con la clausola inline quando si utilizza l'istruzione script LOAD. La clausola inline indica che il testo successivo della tabella conterrà i dati digitati manualmente nell'editor. A meno che non si indichi diversamente, una tabella inline utilizza il formato txt, che segue la struttura di un file di testo delimitato.
Per ulteriori informazioni sull'istruzione LOAD, vedere [Load](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm).
### Contenitori e inserimento dati
I dati inseriti mediante una clausola inline devono essere racchiusi da caratteri specifici. Le combinazioni di caratteri accettate per racchiudere i dati sono le seguenti:
* Parentesi quadre: `[` e `]`
* Virgolette doppie: `"` e `"`
* Virgolette singole: `'` e `'`
* Apici rovesciati: `` ` `` e `` ` ``
Il carattere scelto per fungere da contenitore può aiutare a caricare dati inline che contengono caratteri in conflitto. Ad esempio, se i dati contengono record con parentesi quadre, è possibile racchiuderli con virgolette o con apici rovesciati.
Per un esempio di contenitori alternativi, vedere [Esempio - Contenitori di dati alternativi](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDataEnc).
A meno che non si specifichi un formato di tabella alternativo (il formato predefinito è txt), il testo tra gli allegati viene interpretato come il contenuto di un file. Pertanto, quando si desidera modificare o immettere una nuova riga in un file di testo, è necessario eseguire questa operazione anche nel testo di una clausola inline: ad esempio premendo il tasto INVIO mentre si digita lo script.
### Terminare il caricamento inline
La fine dell'istruzione di caricamento inline è indicata con un punto e virgola.
### Trasformazioni dati
In un semplice caricamento inline senza trasformazioni, il numero di colonne è definito dalla prima riga. Nella tabella caricata dall'esempio seguente sono riportate tre colonne: `Product_ID`, `Supplier_Name` e `Product_Category`.
```
Products:
Load * Inline [
Product_ID, Supplier_Name, Product_Category
1, Paracel, Home Decor
2, PageWave, Electronics
3, Talarian, Software
4, Userland, Appliances
];
```
È inoltre possibile eseguire trasformazioni e creare nuove colonne all'interno della stessa tabella inline. È possibile utilizzare i caricamenti precedenti, inoltre più di un'istruzione LOAD può essere impiegata per caricare la stessa tabella.
Per esempi specifici, vedere [Esempi - Carichi inline con trasformazioni](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExTransform).
### Configurazione della specifica di formato in un carico inline
Come per le altre tabelle caricate, è possibile modificare le specifiche di formato della tabella inline utilizzando le voci di specifica del formato. La specifica del formato viene aggiunta tra parentesi. Deve essere aggiunta dopo i contenitori di dati, ma prima del punto e virgola al termine dell'istruzione LOAD. Alcune delle personalizzazioni che è possibile aggiungere includono:
* Cambiare il delimitatore da una virgola a un altro carattere. Ad esempio, vedere [Esempi - Delimitatori alternativi](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDelimiter).
Vedere: [Delimiter](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/delimiter.htm)
* Omettere le intestazioni delle colonne della tabella. Per un esempio, vedere [Esempio - Omissione delle intestazioni di colonna](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOmitLabels).
Vedere: [Labels](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/labels.htm)
* Utilizzare un altro formato di dati (ad esempio, il formato record fisso). Per un esempio, vedere [Esempio - Caricamento di un altro tipo di dati](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExChangeFormat).
Vedere: [Formato delle tabelle](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/table-format.htm)
Nota informaticaNon tutte le opzioni Table format sono supportate per i caricamenti inline.
* Consentire il contenuto multilinea. Per un esempio, vedere [Esempio - Contenuto multilinea](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExMultLine).
Vedere: [Quotes](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/quotes.htm)
Per utilizzare più voci di specifica del formato nella stessa tabella, separarle con delle virgole. Ad esempio:` (Delimiter is '|', no labels) `
Per tutti i dettagli sulle specifiche del formato, vedere [Voci per la specifica del formato](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm).
### Operatori e altre clausole
In aggiunta, dato che un caricamento inline è un'istruzione LOAD, è possibile combinare altri argomenti per l'istruzione LOAD nel caricamento inline. Ad esempio, utilizzare la clausola where o while per definire se caricare una riga specifica o meno, in base al testo al suo interno.
Allo stesso modo, è possibile utilizzare gli operatori anche al di fuori del contenuto del testo. Con gli operatori, è possibile personalizzare la trasformazione dei dati inline e definire quando caricare o meno determinati dati.
Per un esempio specifico, vedere [Esempio - Operatori per trasformazioni e clausole](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOpsAndClauses).
## Esempio - Contenitori di dati alternativi
È possibile utilizzare parentesi quadre, virgolette o apici rovesciati per racchiudere un caricamento inline. Questa sezione illustra questo aspetto con un esempio. Per ulteriori informazioni, vedere [Contenitori e inserimento dati](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Enclosure).
#### Script di caricamento e risultati
Panoramica
Questo esempio dimostra come sia possibile utilizzare gli apici rovesciati per racchiudere i dati inline. I dati dell'esempio contengono caratteri di parentesi quadra, il che rende le parentesi quadre incompatibili come contenitori per l'istruzione LOAD.
Script di caricamento
```
DataTable:
Load * inline
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;
```
Risultati
* `custom_property`
* `date`
* `amount`
Tabella dei risultati
| custom\_property | date | amount |
| --- | --- | --- |
| [11402] | 1/1/2024 | 92.99 |
| [11403] | 1/2/2024 | 102.34 |
| [11404] | 1/3/2024 | 50.26 |
| [11405] | 1/4/2024 | 153.69 |
| [11406] | 1/5/2024 | 75.62 |
## Esempi - Delimitatori alternativi
È possibile utilizzare un carattere diverso dalla virgola per delimitare i valori delle colonne nella tabella. Per ulteriori informazioni, vedere [Configurazione della specifica di formato in un carico inline](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Script di caricamento e risultati
Panoramica
Lo scambio del delimitatore è utile quando i dati della tabella contengono virgole, che altrimenti segnalerebbero il passaggio alla colonna successiva della tabella.
Questo esempio contiene:
* Quattro tabelle da caricare. Sono le seguenti:
* Table1: Il delimitatore è una barra verticale (pipe). I dati nella colonna Phrase contengono virgole.
* Table2: il delimitatore è un segno dei due punti.
* Table3: il delimitatore è una barra rovesciata.
* Table4: la tabella viene delimitata premendo il tasto Tab sulla tastiera. Questa opzione è utile quando si copia una tabella da un elaboratore di testi e la si incolla nello script.
Table1 mostra un caso pratico di utilizzo di un delimitatore alternativo. Le altre tabelle mostrano altre opzioni di delimitatori.
Script di caricamento
```
Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');
Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');
Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);
Table4:
LOAD * INLINE [
Num3 Chr3
1 A
2 B ] (Delimiter is '\t');
```
Risultati
Tabella dei risultati: Table1Table1
| ID | Phrase |
| --- | --- |
| 1 | The transaction was complete, but the order has not yet shipped. |
| 2 | We need to confirm the following details: sales rep number, order status, and shipping priority. |
Tabella dei risultati: Table2Table2
| Num1 | Chr1 |
| --- | --- |
| 1 | A |
| 2 | B |
Tabella dei risultati: Table3Table3
| Num2 | Chr2 |
| --- | --- |
| 1 | A |
| 2 | B |
Tabella dei risultati: Table4Table4
| Num3 | Chr3 |
| --- | --- |
| 1 | A |
| 2 | B |
## Esempio - Omissione delle intestazioni di colonna
Modificare le specifiche di formato per caricare una tabella inline senza definire le intestazioni delle colonne. Ciò avviene con la specifica labels (impostandola a un valore di no labels). Per ulteriori informazioni, vedere [Configurazione della specifica di formato in un carico inline](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
Quando si carica una tabella senza definire i nomi delle colonne, vengono utilizzati automaticamente i nomi delle colonne definiti dal sistema.
#### Script di caricamento e risultati
Panoramica
Questo esempio dimostra come sia possibile caricare una tabella inline senza definire i nomi delle colonne.
Script di caricamento
```
Expenses:
Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);
```
Risultati
Tabella dei risultati
| @1 | @2 | @3 |
| --- | --- | --- |
| 1 | Category1 | 40566.49 |
| 2 | Category2 | 3504.54 |
| 3 | Category3 | 593206.30 |
## Esempio - Caricamento di un altro tipo di dati
Questo esempio mostra come caricare una tabella inline in formato record fisso. Vedere [Configurazione della specifica di formato in un carico inline](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Script di caricamento e risultati
Panoramica
Questo esempio di script contiene quanto segue:
* Un'istruzione di caricamento in linea che definisce la tabella DataTable.
* L'uso di fix (all'interno della specifica Table format) per indicare che i dati da caricare sono in formato record fisso.
Script di caricamento
```
DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a b c d
1 2 3 4
x y z w
] (fix, utf8, embedded labels);
```
Risultati
Tabella dei risultati
| a | b | c | d |
| --- | --- | --- | --- |
| 1 | 2 | 3 | 4 |
| x | y | z | w |
## Esempio - Contenuto multilinea
Questo esempio mostra come inserire il contenuto di un campo multilinea in una tabella inline. Vedere [Configurazione della specifica di formato in un carico inline](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Script di caricamento e risultati
Panoramica
Questo esempio di script contiene quanto segue:
* Un semplice caricamento inline per definire la tabella T1.
* Uso dello specificatore Quotes (con il valore msq) per supportare il contenuto multilinea.
* Valori di lunghezza specificati in piedi e pollici.
* Il simbolo delle doppie virgolette (") indica la fine di una voce multilinea. In questo esempio, lo stesso simbolo viene utilizzato anche per indicare i valori in pollici. Ciò avviene per mostrare la sintassi e il comportamento risultante nel caso in cui si debbano usare entrambi nella stessa istruzione LOAD. In sostanza, l'inserimento del simbolo " per due caratteri consecutivi ("") indica che il codice deve essere interpretato come un'unica istanza testuale del simbolo.
Script di caricamento
```
T1:
Load *, recno() as ID inline [
Length
"1' 2""
22' 10"""
14' 8" ] (msq);
```
Risultati
Per visualizzare il contenuto multilinea come previsto, è necessario regolare le impostazioni multilinea per il grafico nella configurazione Proprietà....
Tabella dei risultati
| ID | Length |
| --- | --- |
| 1 | 1' 2"
22' 10" |
| 2 | 14' 8" |
Nella tabella precedente, il record con un valore ID di 1 contiene contenuto multilinea.
## Esempi - Carichi inline con trasformazioni
Questi esempi mostrano come sia possibile eseguire calcoli sui campi caricati inline per creare nuovi campi nel modello dati.
Per ulteriori informazioni, vedere [Trasformazioni dati](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Transform).
#### Esempio: semplice rinominazione di un campo
Script di caricamento
```
ORDERS:
Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];
```
Risultati
Tabella dei risultati
| Original | Updated |
| --- | --- |
| ProductA | ProductA |
| ProductB | ProductB |
| ProductC | ProductC |
#### Esempio: semplice inserimento di un campo ID
Panoramica
Questo esempio mostra come sia possibile definire un campo calcolato per indicare l'ID di ogni riga di dati, senza dover digitare manualmente ogni valore ID.
Script di caricamento
```
ORDERS:
Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];
```
Risultati
Tabella dei risultati
| ID | ProductName |
| --- | --- |
| 1 | A |
| 2 | B |
| 3 | C |
| 4 | D |
| 5 | E |
#### Esempio: configurazione di istruzioni LOAD per gestire le trasformazioni
Panoramica
Questo esempio mostra diversi modi in cui una semplice trasformazione può essere applicata ai dati inline. È possibile utilizzare una o più istruzioni LOAD e configurare la sintassi in modi diversi, per definire se una trasformazione sostituisce o meno il campo originale o se vengono caricati sia il campo originale che quello nuovo.
In particolare, si notino le variazioni di seguito elencate e il loro effetto sull'output:
* Numero di istruzioni LOAD all'interno della tabella.
* Presenza o assenza del simbolo \* (carica tutti i campi successivi).
* Presenza o assenza delle virgole (simbolo ,).
Questo esempio di script contiene quanto segue:
* Quattro tabelle, che fanno tutte riferimento agli stessi dati. I nomi dei campi sono diversi.
* DerivedYears1: usa due istruzioni LOAD per caricare una colonna inline e una colonna contenente una trasformazione della colonna inline.
* DerivedYears2: usa due istruzioni LOAD. Lo script carica una colonna inline, quindi carica un campo calcolato trasformato dalla colonna originale. Con la seconda istruzione LOAD, la colonna originale non viene caricata nella tabella, rendendo di fatto il nuovo campo una sostituzione del campo originale.
* DerivedYears3: usa una singola istruzione LOAD per caricare sia la colonna originale inline che una colonna trasformata.
* DerivedYears4: usa una singola istruzione LOAD per definire un campo in linea e una trasformazione del campo originale. Nella tabella viene caricato solo il campo trasformato.
Script di caricamento
```
DerivedYears1:
Load *,
Year(initial_date1) as derived_year1
;
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears2:
Load
Year(initial_date2) as derived_year2
;
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears3:
Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears4:
Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
```
Risultati
Tabella dei risultati: DerivedYears1DerivedYears1
| initial\_date1 | derived\_year1 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Tabella dei risultati: DerivedYears2DerivedYears2
| derived\_year2 |
| --- |
| 2022 |
| 2023 |
| 2024 |
Tabella dei risultati: DerivedYears3DerivedYears3
| initial\_date3 | derived\_year3 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Tabella dei risultati: DerivedYears4DerivedYears4
| derived\_year4 |
| --- |
| 2022 |
| 2023 |
| 2024 |
#### Esempio: modifica del contenuto del campo
Panoramica
Si supponga di incollare le informazioni da un file di testo di grandi dimensioni nell'editor script, ma di voler eseguire un'elaborazione aggiuntiva sui record del set di dati. Ad esempio, si desidera rimuovere alcuni caratteri e prefissi e scrivere in maiuscolo ogni parola.
Questo esempio di script contiene quanto segue:
* Una tabella inline, Transformations, in cui si definisce una trasformazione per cambiare il contenuto del testo di un campo. Il testo da trasformare viene aggiunto dopo.
* Due istruzioni LOAD. Con la configurazione dell'esempio, solo il campo derivato ProductName\_Trimmed viene caricato nella tabella.
Script di caricamento
```
Transformations:
Load
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;
Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product: {snack food}
Product: {electronics and video games}
];
```
Risultati
Tabella dei risultati
| ProductName\_Trimmed |
| --- |
| Soft Drinks And Other Beverages |
| Snack Food |
| Electronics And Video Games |
## Esempio - Operatori per trasformazioni e clausole
È possibile utilizzare gli operatori per definire trasformazioni e clausole specifiche nell'istruzione LOAD. Per ulteriori informazioni, vedere [Operatori e altre clausole](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#OpsAndClauses).
[Operatori](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/Operators/operators.htm)
#### Script di caricamento e risultati
Panoramica
Questo esempio di script contiene quanto segue:
* Un semplice caricamento inline per definire la tabella Purchases.
* L'inserimento di un campo calcolato, OrderSize. Questo campo è una trasformazione del campo amount dal set di dati inline. Il sistema classifica gli acquisti come piccoli o grandi, a seconda che l'importo superi o meno i 2.000 dollari.
* Una clausola where che impedisce di caricare i record quando amount è inferiore a 0,05 dollari.
Script di caricamento
```
Purchases:
Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,
* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;
```
Risultati
Tabella dei risultati
| ID | amount | OrderSize |
| --- | --- | --- |
| 1 | 2660.39 | Large Purchase |
| 2 | 100.01 | Small Purchase |
| 3 | 500.42 | Small Purchase |
| 4 | 5023.99 | Large Purchase |
| 6 | 2002.39 | Large Purchase |
| 7 | 31034.53 | Large Purchase |
| 8 | 1643.58 | Small Purchase |
| 9 | 3993.65 | Large Purchase |
| 10 | 614.34 | Small Purchase |
| 11 | 675.93 | Small Purchase |
Nella tabella sopra, la transazione con un ID di 5 non è stata caricata nella tabella. Questo perché il valore amount è inferiore a 0,05 dollari.
## Esempio - Creazione di valori nulli in una tabella inline
Questo esempio dimostra come sia possibile utilizzare la variabile NullInterpret per creare valori nulli nei dati inline.
[NullInterpret](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ValueHandlingVariables/NullInterpret.htm)
#### Script di caricamento e risultati
Panoramica
Questo esempio di script contiene quanto segue:
* Un semplice caricamento inline per definire la tabella T2.
* La variabile NullInterpret definita come due virgolette singole. Quando lo script viene caricato, i record contenenti questo valore vengono elaborati come valori nulli.
Script di caricamento
```
set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];
```
Risultati
Tabella dei risultati
| Test |
| --- |
| x |
Nella tabella precedente, il primo record è un valore nullo. Pertanto, non è incluso nella visualizzazione. I valori nulli presenti nelle tabelle con dimensioni aggiuntive saranno indicati con un simbolo -.
## Ulteriori esempi
Per esempi aggiuntivi, vedere [Load](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm).
## Ulteriori informazioni
* [Load](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm)
* [Voci per la specifica del formato](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm)
* [Wizard immissione dati](https://help.qlik.com/it-IT/qlikview/September2026/Subsystems/Client/Content/QV_QlikView/Inline_Data_Wizard.htm)