# Timestamp#Funzione per script e grafici
Timestamp#() valuta un'espressione come valore data e ora nel formato dell'indicatore temporale impostato nello script di caricamento dei dati o nel sistema operativo, a meno che non venga fornita una stringa di formattazione.
Sintassi:
timestamp#(text[, format])
Tipo di dati restituiti: duale
Argomenti
| Argomento | Descrizione |
| --- | --- |
| text | La stringa di testo da valutare. |
| format | Stringa che descrive il formato da utilizzare per interpretare la stringa di testo. Se viene omessa, si utilizzerà il formato della data breve, il formato dell'ora e il separatore decimale impostati nel sistema operativo. ISO 8601 è supportato per gli indicatori temporali.
La funzione `Timestamp#` supporta molte opzioni di formato per diverse strutture per l'ora, ad esempio:
`DD/MM/YYYY`: si concentra solo sulla data (ad esempio: `15/11/2024`).
`YYYY-MM-DD hh:mm:ss`: visualizza il timestamp completo (ad esempio: `2024-11-15 13:30:45`).
`MMM DD, YYYY`: visualizza una versione breve del mese e l'anno completo (ad esempio: `Nov 15, 2024`).
`hh:mm:ss TT`: mostra solo l'ora nel formato di 12 ore (per esempio: `01:30:45 PM`)
`HH:mm:ss`: visualizza l'ora nel formato a 24 ore (ad esempio: `13:30:45`).
`wwww, MMM DD YYYY`: mostra il giorno completo della settimana e la data (ad esempio: `Friday, Nov 15 2024`).
`YYYY-MM-DD hh:mm:ss.fff`: include i millisecondi (ad esempio: `2024-11-15 13:30:45.123`).
[Descrizioni per i formati di numeri e ora](https://help.qlik.com/it-IT/cloud-services/Subsystems/Hub/Content/Sense_Hub/Introduction/conventions-number-time-formats.htm) |
Esempio: espressioni dei grafici
| Esempio | Risultato |
| --- | --- |
| `Timestamp#('12-03-2023 10:25:30', 'DD-MM-YYYY hh:mm:ss')` | Restituisce `12-03-2023 10:25:30` |
| `Timestamp#('2023/03/15 13:45', 'YYYY/MM/DD hh:mm')` | Restituisce `2023/03/15 13:45` |
## Esempio: principi fondamentali della funzione Timestamp\#
[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/InterpretationFunctions/timestamp_hash.htm)
#### Script di caricamento
Panoramica
Aprire l'Editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova sezione.
Lo script di caricamento contiene:
* Un set di dati che viene caricato in una tabella dati chiamata `Example`.
* Il seguente campo in una tabella dati:
* `InputString`
* Un caricamento precedente che utilizza la funzione `Timestamp#` per trattare l'espressione come un valore di data e ora. Quando viene eseguito, crea un campo aggiuntivo denominato `TimeStamp_InputString`.
Script di caricamento
```
SET DateFormat='M/D/YYYY'
Example:
Load *,
Timestamp(Timestamp#(InputString)) as TimeStamp_InputString;
LOAD * INLINE [
InputString
2015-09-15T12:13:14
1952-10-16T13:14:00+0200
1109-03-01T14:15
];
```
Risultati
Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere tali campi come dimensioni:
* ` InputString
`
* `TimeStamp_InputString`
Tabella dei risultati
| Stringa di input | TimeStamp\_InputString |
| --- | --- |
| 1109-03-01T14:15 | 3/1/1109 2:15:00 PM |
| 1952-10-16T13:14:00+0200 | 10/16/1952 11:14:00 AM |
| 2015-09-15T12:13:14 | 9/15/2015 12:13:14 PM |
In questo esempio, è possibile vedere come i valori delle stringhe possono essere valutati come timestamp utilizzando la funzione `Timestamp#`.
## Esempio: scenario per l'applicazione della funzione Timestamp\#
[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/InterpretationFunctions/timestamp_hash.htm)
#### Script di caricamento
Panoramica
I dati di un registro degli eventi contengono un formato di timestamp che si desidera utilizzare.
Aprire l'Editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova sezione.
Lo script di caricamento contiene:
* Un set di dati che viene caricato in una tabella dati chiamata `Example`.
* I seguenti campi nella tabella dati:
* `Event`
* `EventDateTime`
* Un caricamento precedente che utilizza la funzione `Timestamp#` per convertire i valori del campo `EventDateTime` in formato data e ora che il sistema può comprendere. Quando viene eseguito, crea un campo aggiuntivo denominato `EventTimestamp`.
Script di caricamento
```
SET TimestampFormat='M/D/YYYY h:mm:ss[.fff] TT';
Example:
LOAD
Event,
EventDateTime,
Timestamp#(EventDateTime, 'DD-MM-YYYY hh:mm:ss') AS EventTimestamp
INLINE [
Event, EventDateTime
"Login", "12-03-2023 10:25:30"
"Logout", "12-03-2023 12:45:10"
"Login", "13-03-2023 09:10:15"
"Logout", "13-03-2023 17:30:20"
"Login", "14-03-2023 08:00:00"
];
```
Risultati
Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere tali campi come dimensioni:
* ` Event
`
* `EventDateTime`
* `EventTimestamp`
Creare la seguente misura:
* `=Timestamp(EventTimestamp)`, per visualizzare il valore timestamp utilizzando il formato fornito nello script di caricamento come impostazione predefinita.
Tabella dei risultati
| Evento | EventDateTime | EventTimestamp | Timestamp(EventTimestamp) |
| --- | --- | --- | --- |
| Accedi | 12-03-2023 10:25:30 | 12-03-2023 10:25:30 | 3/12/2023 10:25:30 AM |
| Accedi | 13-03-2023 09:10:15 | 13-03-2023 09:10:15 | 3/13/2023 9:10:15 AM |
| Accedi | 14-03-2023 08:00:00 | 14-03-2023 08:00:00 | 3/14/2023 8:00:00 AM |
| Disconnetti | 12-03-2023 12:45:10 | 12-03-2023 12:45:10 | 3/12/2023 12:45:10 PM |
| Disconnetti | 13-03-2023 17:30:20 | 13-03-2023 17:30:20 | 3/13/2023 5:30:20 PM |
In questo esempio, è possibile vedere come i valori possono essere convertiti utilizzando la funzione `Timestamp#`.