# Above - funzione per grafici

Above() valuta un'espressione in una riga sopra la riga attuale all'interno di un segmento di colonna in una tabella. La riga per la quale viene calcolata dipende dal valore dell'offset, se presente, e l'impostazione predefinita è la riga direttamente sopra. Per i grafici diversi dalle tabelle, Above() restituisce un valore per la riga sopra la riga attuale nell'equivalente di tabella lineare del grafico.

Sintassi:

Above([TOTAL] expr [ , offset [,count]])

Tipo di dati restituiti: duale

Argomenti

| Argomento | Descrizione |
| --- | --- |
| expr | L'espressione o il campo contenente i dati da misurare. |
| offset | Specificando un offset n, maggiore di 0, è possibile spostare la valutazione dell'espressione n righe più in alto della riga attuale.<br><br>Specificando un offset uguale a 0 verrà valutata l'espressione nella riga attuale.<br><br>Specificando un numero di offset negativo, la funzione Above diventa equivalente alla funzione Below con il numero di offset positivo corrispondente. |
| count | Specificando un terzo argomento count maggiore di 1, la funzione restituirà una scala di valori count, uno per ciascuna delle righe della tabella count contando verso l'alto a partire dalla cella originaria.<br><br>In questo modulo la funzione può essere utilizzata come argomento per una qualsiasi delle funzioni di scala speciali. [Funzioni di scala](https://help.qlik.com/it-IT/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/RangeFunctionsInCharts.htm) |
| TOTAL | Se la tabella è unidimensionale o se è utilizzato il qualificatore TOTAL come argomento, il segmento colonna attuale sarà sempre uguale all'intera colonna.<br><br>[Definizione dell'ambito di aggregazione](https://help.qlik.com/it-IT/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |

In corrispondenza della prima riga di un segmento di colonna verrà restituito un valore NULL perché non vi sono righe che la precedono.

Nota informaticaUn segmento di colonna viene definito come un sottogruppo consecutivo di celle con gli stessi valori per le dimensioni nell'ordine attuale. Le funzioni grafiche intra-record vengono calcolate nel segmento colonna escludendo la dimensione più a destra nel grafico della tabella lineare equivalente. Se nel grafico è presente una sola dimensione oppure è specificato il qualificatore TOTAL, l'espressione viene valutata nell'intera tabella.

Nota informaticaSe la tabella o l'equivalente di tabella include più dimensioni verticali, il segmento colonna attuale includerà solo righe contenenti gli stessi valori della riga attuale in tutte le colonne di dimensione, eccetto la colonna che mostra l'ultima dimensione nell'ordinamento tra campi.

Limiti:

* Le chiamate ricorrenti restituiranno NULL.

* L'ordinamento sui valori y nei grafici o l'ordinamento per colonne di espressione nelle tabelle non è consentito quando si utilizza questa funzione di grafico in una qualsiasi delle espressioni del grafico. Queste alternative di ordinamento verranno perciò disattivate automaticamente. Quando si utilizza questa funzione di grafico in una visualizzazione o in una tabella, l'ordinamento della visualizzazione torna all'ordinamento inserito in questa funzione.

Esempio: espressioni dei grafici

| Esempio | Risultato |
| --- | --- |
| `Above( Sum(Sales) )` | Restituisce il valore di `Sales` per la riga sopra la riga corrente. |

## Esempio: principi fondamentali della funzione Above

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Espressione del grafico

Panoramica

Aprire l'Editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova sezione.

Lo script di caricamento contiene:

* Un set di dati che viene caricato in una tabella dati chiamata `Example`.

* I seguenti campi nella tabella dati:

  * `Year`

  * `Sales`

Script di caricamento

```
Example:
LOAD * INLINE [
Year, Sales
2019, 1000
2020, 1500
2021, 1200
2022, 1800
2023, 1700
];
```

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere questo campo come dimensione:

* `Year`

Creare le seguenti misure:

* `=Sum(Sales)`, per individuare le vendite annuali.

* `=Above(Sum(Sales))`, per individuare il valore delle vendite dell'anno precedente.

* `=Sum(Sales) - Above(Sum(Sales))`, per calcolare la varianza tra il valore `Sales` dell'anno in corso e il valore dell'anno precedente.

* `=RangeSum(Above(Sales, 1, 2))`, per dimostrare un'aggregazione biennale dei due anni di vendita precedenti.

* `=(Sales - Above(Sales)) / Above(Sales)`, per restituire la variazione di `Sales` come rapporto/percentuale. Per mostrare questo valore come una percentuale, sotto la voce Formattazione numero, selezionare Numero &gt; Formattazione semplice &gt; 12,34%.

Tabella dei risultati

| Year | Sum(Sales) | Above(Sum(Sales)) | Sum(Sales) - Above(Sum(Sales)) | RangeSum(Above(Sales, 1, 2) | (Sales - Above(Sales)) / Above(Sales) |
| --- | --- | --- | --- | --- | --- |
| Totals | 7200 | - | - | 0 | - |
| 2019 | 1000 | - | - | 0 | - |
| 2020 | 1500 | 1000 | 500 | 1000 | 50.00% |
| 2021 | 1200 | 1500 | -300 | 2500 | -20.00% |
| 2022 | 1800 | 1200 | 600 | 2700 | 50.00% |
| 2023 | 1700 | 1800 | -100 | 3000 | -5.56% |

Osservando i risultati, è possibile confrontare i valori per `Sales` nel periodo corrente con il periodo precedente.

* La misura `Sum(Sales)- Above(Sum(Sales))` restituisce la variazione nei valori di `Sales`, confrontando il periodo corrente con quello precedente.

* La misura `RangeSum(Above(Sales, 1, 2))` restituisce la somma dei due valori di `Sales` precedenti.

* La misura `(Sales - Above(Sales)) / Above(Sales)` restituisce la variazione di `Sales` in confronto al periodo precedente come una percentuale.

Nota di suggerimentoQuesta funzione può essere utilizzata nei grafici diversi dalle tabelle, ad esempio nei grafici a barre.

Procedere come indicato di seguito:

Creare un grafico a barre, quindi aggiungere questo campo come dimensione:

* `Year`

Creare la seguente misura:

* `=Sum(Sales) - Above(Sum(Sales))`, per restituire la varianza su base annua.

Grafico a barre che mostra i risultati della funzione Above

Grafico a barre che mostra i risultati della funzione Above

Grafico a barre che mostra i risultati della funzione AboveAbove ![Grafico a barre che mostra la varianza su base annua per la somma delle vendite](https://help.qlik.com/it-IT/cloud-services/Subsystems/Hub/Content/Resources/Images/scripting-functions-above-example.png)

L'utilizzo della funzione `Above` in un grafico a barre fornisce un confronto visivo della varianza tra le vendite del periodo corrente rispetto a quelle del periodo precedente.

## Esempio: scenario per l'applicazione della funzione Above

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Espressione del grafico

Panoramica

Aprire l'Editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova sezione.

Lo script di caricamento contiene:

* Un set di dati che viene caricato in una tabella dati chiamata `Example`.

* I seguenti campi nella tabella dati:

  * `SalesYear`

  * `SalesAmount`

Script di caricamento

```
Example:
LOAD * INLINE [
SalesYear, SalesAmount
2019, 500
2020, 800
2021, 400
2022, 700
2023, 600
];
```

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere questo campo come dimensione:

* `SalesYear`

Creare le seguenti misure:

* `=Sum(SalesAmount)`, per aggregare le vendite.

* `=RangeSum(Above(SalesAmount, 0, RowNo()))`, per calcolare un totale parziale dei valori per `SalesAmount`.

Tabella dei risultati

| SalesYear | Sum(SalesAmount) | RangeSum(Above(SalesAmount, 0, RowNo())) |
| --- | --- | --- |
| Totals | 3000 | 0 |
| 2019 | 500 | 500 |
| 2020 | 800 | 1300 |
| 2021 | 400 | 1700 |
| 2022 | 700 | 2400 |
| 2023 | 600 | 3000 |

I risultati mostrano come è possibile utilizzare una combinazione della funzione `RangeSum` e della funzione `Above` per creare un totale parziale cumulativo.

Nota di suggerimentoQuesta funzione può essere utilizzata nei grafici diversi dalle tabelle, ad esempio nei grafici a barre.

Procedere come indicato di seguito:

Creare un grafico a barre, quindi aggiungere questo campo come dimensione:

* `SalesYear`

Creare la seguente misura:

* `=RangeSum(Above(SalesAmount, 0, RowNo()))`, per restituire il valore cumulativo delle vendite.

Grafico a barre che mostra il valore cumulativo delle vendite su base annua

Grafico a barre che mostra il valore cumulativo delle vendite su base annua

Grafico a barre che mostra il valore cumulativo delle vendite su base annua ![Grafico a barre che mostra il valore cumulativo delle vendite su base annua.](https://help.qlik.com/it-IT/cloud-services/Subsystems/Hub/Content/Resources/Images/scripting-functions-above-example2.png)

## Esempio: espressione del grafico che usa Above

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Espressione del grafico

Panoramica

Aprire l'Editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova sezione.

Lo script di caricamento contiene:

* Due tabelle dati chiamate `Monthnames` e `Sales2013`.

Script di caricamento

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];
Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');
```

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere questo campo come dimensione:

* `Customer`

Creare le seguenti misure:

* `=Sum(Sales)`, per calcolare la somma delle vendite.

* `=Above(Sum(Sales))`, per mostrare la somma dei valori di vendita nella riga precedente.

* `=Sum(Sales)+Above(Sum(Sales))`, per sommare il valore della somma delle vendite con la somma delle vendite per la riga del cliente sopra la riga corrente.

* `=Sum(Sales)+Above(Sum(Sales), 3)`, per sommare il valore `Sum(Sales)` per il `Customer` corrente al valore di `Customer`, tre righe sopra.

* `=IF(Sum(Sales)>Above(Sum(Sales)), 'Higher')`, per aggiungere l'etichetta "`Higher`" ai clienti i cui risultati `Sum(Sales)` sono superiori al valore di `Sum(Sales)` per il cliente nella riga precedente.

Tabella dei risultati

| Customer | Sum(Sales) | Above(Sum(Sales)) | Sum(Sales)+Above(Sum(Sales)) | Sum(Sales)+Above(Sum(Sales), 3) | IF(Sum(Sales)&gt;Above(Sum(Sales)), 'Higher') |
| --- | --- | --- | --- | --- | --- |
| Totals | 2566 | - | - | - | - |
| Astrida | 587 | - | - | - | - |
| Betacab | 539 | 587 | 1126 | - | - |
| Canutility | 683 | 539 | 1222 | - | Higher |
| Divadip | 757 | 683 | 1440 | 1344 | Higher |

La misura `Above(Sum(Sales))` restituisce NULL per il cliente `Astrida`, perché non ci sono righe che la precedono. Il risultato per il cliente `Betacab` mostra il valore di `Sum(Sales)` per `Astrida`. Il risultato per `Canutility` mostra il valore di `Sum(Sales)` per `Betacab` e così via.

Per la misura `Sum(Sales)+Above(Sum(Sales))`, la riga di `Betacab` restituisce il risultato per l'aggiunta dei valori di `Sum(Sales)` per le righe `Betacab` + `Astrida` (`539+587`). Il risultato per la riga `Canutility` mostra il risultato dell'aggiunta dei valori `Sum(Sales)` per `Canutility` + `Betacab` (`683+539`).

La misura `Sum(Sales)+Above(Sum(Sales), 3)` ha l'argomento `offset`, impostato su `3`. Prende il valore della riga che si trova 3 righe sopra la riga corrente. Aggiunge il valore `Sum(Sales)` per il valore `Customer` corrente al valore per le tre righe `Customer`precedenti. Ad esempio, il valore `Sum(Sales)` per `Divadip`, viene aggiunto a `Sum(Sales)` per `Astrida`, il cliente incluso nelle tre righe sopra `Divadip`. I valori restituiti per le prime 3 righe `Customer` sono null perché non sono disponibili dati.

La misura `IF(Sum(Sales)>Above(Sum(Sales)), 'Higher')` restituisce il valore `Higher` per i clienti `Canutility` e `Divadip` perché i loro risultati di vendita sono entrambi superiori alla somma delle vendite dei clienti nella riga precedente, rispettivamente `Betacab` e `Canutility`.

Nota di suggerimentoQuesta funzione può essere utilizzata nei grafici diversi dalle tabelle, ad esempio nei grafici a barre.

Nota di suggerimentoPer gli altri tipi di grafici, convertire il grafico nell'equivalente di tabella lineare per individuare facilmente la riga a cui si riferisce la funzione.

## Esempio: scenario per l'applicazione della funzione Above in base all'ordinamento

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Espressione del grafico

Panoramica

Aprire l'Editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova sezione.

Lo script di caricamento contiene:

* Tre tabelle dati chiamate Monthnames, Sales2013 e Product.

Script di caricamento

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];

Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');

Product:
LOAD * inline [
Customer|Product|OrderNumber|UnitSales|UnitPrice
Astrida|AA|1|4|16
Astrida|AA|7|10|15
Astrida|BB|4|9|9
Betacab|CC|6|5|10
Betacab|AA|5|2|20
Betacab|BB||| 25
Canutility|AA|||15
Canutility|CC| ||19
Divadip|CC|2|4|16
Divadip|DD|3|1|25
] (delimiter is '|');
```

```

                                
```

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere tali campi come dimensioni:

* Customer

* Product

* Month

Creare le seguenti misure:

* =Sum(Sales), per calcolare la somma delle vendite.

* =Above(Sum(Sales)), per mostrare la somma dei valori di vendita nella riga precedente.

Tabella dei risultati

| Customer | Product | Month | Sum(Sales) | Above(Sum(Sales)) |
| --- | --- | --- | --- | --- |
| Totals | - | - | 2566 | - |
| Astrida | AA | Jan | 46 | - |
| Astrida | AA | Feb | 60 | 46 |
| Astrida | AA | Mar | 70 | 60 |
| Astrida | AA | Apr | 13 | 70 |
| Astrida | AA | May | 78 | 13 |
| Astrida | AA | Jun | 20 | 78 |
| Astrida | AA | Jul | 45 | 20 |
| Astrida | AA | Aug | 65 | 45 |
| Astrida | AA | Sep | 78 | 65 |
| Astrida | AA | Oct | 12 | 78 |
| Astrida | AA | Nov | 78 | 12 |
| Astrida | AA | Dec | 22 | 78 |
| Astrida | BB | Jan | 46 | - |
| Astrida | BB | Feb | 60 | 46 |

Per i grafici con più dimensioni, i risultati delle espressioni contenenti le funzioni Above, Below, Top e Bottom dipendono dall'ordine con cui le dimensioni di colonna vengono ordinate da Qlik Sense. Qlik Sense valuta le funzioni in base ai segmenti di colonna che derivano dalla dimensione ordinata per ultima. L'ordinamento delle colonne viene controllato dal pannello delle proprietà in Ordinamento e non è necessariamente l'ordine in cui le colonne vengono visualizzate in una tabella.

Nella seguente tabella dei risultati, l'ultima dimensione di ordinamento è Month, in modo che la funzione Above completi la valutazione in base ai mesi. Esiste una serie di risultati per ciascun valore Product per ciascun mese (da Jan a Dec): un segmento colonna. Viene seguita da una serie per il segmento di colonna successivo per ogni Month per il valore Product successivo. Esisterà un segmento di colonna per ciascun valore Customer per ciascun valore Product.

## Esempio: scenario per l'applicazione della funzione Above con un ordinamento differente

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Espressione del grafico

Panoramica

Aprire l'Editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova sezione.

Lo script di caricamento contiene:

* Tre tabelle dati chiamate Monthnames, Sales2013 e Product.

Script di caricamento

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];

Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');

Product:
LOAD * inline [
Customer|Product|OrderNumber|UnitSales|UnitPrice
Astrida|AA|1|4|16
Astrida|AA|7|10|15
Astrida|BB|4|9|9
Betacab|CC|6|5|10
Betacab|AA|5|2|20
Betacab|BB||| 25
Canutility|AA|||15
Canutility|CC| ||19
Divadip|CC|2|4|16
Divadip|DD|3|1|25
] (delimiter is '|');
```

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere tali campi come dimensioni:

* Customer

* Product

* Month

Creare le seguenti misure:

* =Sum(Sales), per calcolare la somma delle vendite.

* =Above(Sum(Sales)), per mostrare la somma dei valori di vendita nella riga precedente.

Modificare il criterio di ordinamento della tabella nel pannello delle proprietà. Selezionare Ordinamento, quindi trascinare la dimensione Prodotto nella terza posizione dell'ordinamento.

Tabella dei risultati

| Customer | Product | Month | Sum(Sales) | Above(Sum(Sales)) |
| --- | --- | --- | --- | --- |
| Totals | - | - | 2566 | - |
| Astrida | AA | Jan | 46 | - |
| Astrida | BB | Jan | 46 | 46 |
| Astrida | AA | Feb | 60 | - |
| Astrida | BB | Feb | 60 | 60 |
| Astrida | AA | Mar | 70 | - |
| Astrida | BB | Mar | 70 | 70 |
| Astrida | AA | Apr | 13 | - |
| Astrida | BB | Apr | 13 | 13 |
| Astrida | AA | May | 78 | - |
| Astrida | BB | May | 78 | 78 |
| Astrida | AA | Jun | 20 | - |
| Astrida | BB | Jun | 20 | 20 |
| Astrida | AA | Jul | 45 | - |
| Astrida | BB | Jul | 45 | 45 |

Nella tabella dei risultati, l'ultima dimensione ordinata è Product. La funzione Above viene valutata per ciascun valore Product e, poiché esistono solo due prodotti, AA e BB, esiste solo un risultato non null in ciascuna serie. Nella riga BB per il mese Jan, il valore per Above(Sum(Sales)) è 46. Per la riga AA, il valore è null. Il valore in ciascuna riga AA per ciascun mese sarà sempre null perché non esiste alcun valore Product sopra AA. La seconda serie viene valutata in AA e BB per il mese Feb, per il valore Customer, Astrida. Quando tutti i mesi sono stati valutati per Astrida, la sequenza viene ripetuta per il secondo cliente Betacab e così via.

Nota informaticaI risultati nella tabella mostrano solo un elenco parziale dei dati. Per visualizzare i risultati completi, provare l'esempio in un'app.

## Esempio: utilizzo della funzione Above con RangeAvg

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Espressione del grafico

Panoramica

La funzione Above può essere utilizzata come input per le funzioni di scala. Questo esempio utilizza la funzione per RangeAvg.

Aprire l'Editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova sezione.

Lo script di caricamento contiene:

* Tre tabelle dati chiamate Monthnames, Sales2013 e Product.

Script di caricamento

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];

Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');

Product:
LOAD * inline [
Customer|Product|OrderNumber|UnitSales|UnitPrice
Astrida|AA|1|4|16
Astrida|AA|7|10|15
Astrida|BB|4|9|9
Betacab|CC|6|5|10
Betacab|AA|5|2|20
Betacab|BB||| 25
Canutility|AA|||15
Canutility|CC| ||19
Divadip|CC|2|4|16
Divadip|DD|3|1|25
] (delimiter is '|');
```

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere questo campo come dimensione:

* Customer

Creare la seguente misura:

* =RangeAvg (Above(Sum(Sales),1,3))

Tabella dei risultati\*

| Customer | RangeAvg (Above(Sum(Sales),1,3)) |
| --- | --- |
| Totals | - |
| Astrida | - |
| Betacab | 587 |
| Canutility | 563 |
| Divadip | 603 |

Negli argomenti per la funzione Above, offset viene impostato su 1, mentre count viene impostato su 3. La funzione trova i risultati dell'espressione Sum(Sales) nelle tre righe immediatamente sopra la riga attuale nel segmento di colonna (dove si trova una riga). Questi tre valori vengono utilizzati come input per la funzione RangeAvg, che individua la media dei valori nella scala di numeri fornita.

## Ulteriori informazioni

* [Below - funzione per grafici](https://help.qlik.com/it-IT/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
* [Bottom - funzione per grafici](https://help.qlik.com/it-IT/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
* [Top - funzione per grafici](https://help.qlik.com/it-IT/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/top.htm)
* [RangeAvg Funzione per script e grafici](https://help.qlik.com/it-IT/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/rangeavg.htm)