# Drop table
Vous pouvez retirer une ou plusieurs tables internes Qlik Sense du modèle de données et, de ce fait, de la mémoire à tout moment au cours de l'exécution du script, au moyen d'une instruction drop table. Vous pouvez éventuellement utiliser la variante drop mapping table pour abandonner des tables de mappage (celles créées avec le préfixe Mapping) avant la fin de l'exécution du script.
drop [mapping] table tablename {, tablename2 ...}
drop [mapping] tables tablename {, tablename2 ...}
Note InformationsLes formes drop table et drop tables sont toutes deux acceptées.
Il en résulte que les éléments suivants seront perdus :
* Table(s) réelle(s).
* Tous les champs ne faisant pas partie des tables restantes.
* Valeurs de champ figurant dans les champs restants, provenant exclusivement de la ou des tables retirées.
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/drop-table.htm)
#### Exemples et résultats :
| Exemple | Résultat |
| --- | --- |
| ```
drop table Orders, Salesmen, T456a;
``` | Cette ligne a pour résultat le retrait de trois tables de la mémoire. |
| ```
Tab1:
Load * Inline [
Customer, Items, UnitPrice
Bob, 5, 1.50
];
Tab2:
LOAD Customer, Sum( Items * UnitPrice ) as Sales
resident Tab1
group by Customer;
drop table Tab1;
``` | Dès que la table Tab2 est créée, la table Tab1 est retirée. |
| ```
// Load mapping table of country codes:
map1:
mapping LOAD *
Inline [
CCode, Country
Sw, Sweden
Dk, Denmark
No, Norway
] ;
// Load list of salesmen, mapping country code to country
// If the country code is not in the mapping table, put Rest of the world
Salespersons:
LOAD *,
ApplyMap('map1', CCode,'Rest of the world') As Country
Inline [
CCode, Salesperson
Sw, John
Sw, Mary
Sw, Per
Dk, Preben
Dk, Olle
No, Ole
Sf, Risttu] ;
// We don't need the CCode anymore
Drop Field 'CCode';
Drop Mapping Table map1;
Metrics:
Load * Inline [
Transaction ID, Sales Amount, Sales Cost, City, Customer ID
1000012, 4509.33, 1234.22, Oslo, 250v9849
1000013, 1043.21, 180.23, Gothenburg, 195d5930
1000014, 6038.35, 1400.10, Copenhagen, 195d5930
];
``` | Cet exemple montre comment utiliser la variante Drop mapping table. Une table de mappage map1 est créée, puis utilisée dans une instruction LOAD ultérieure avec la fonction ApplyMap. Une fois la table de mappage utilisée, elle est abandonnée de la mémoire, optimisant ainsi l'utilisation de la RAM pour les données à charger dans les tables suivantes de l'exécution du script.
Dans ce cas, avec seulement quelques lignes dans la table de mappage, l'optimisation de la RAM serait minimale. Cependant, pour les grandes tables de mappage ou lors de la création de tables de mappage au sein de boucles, les performances peuvent être considérablement améliorées. |
## En savoir plus
* [Rename table](https://help.qlik.com/fr-FR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/rename-table.htm)
* [Drop field](https://help.qlik.com/fr-FR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/drop-field.htm)
* [Drop](https://help.qlik.com/fr-FR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/Drop.htm)
* [Table/Tables](https://help.qlik.com/fr-FR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/Table.htm)
* [Mapping](https://help.qlik.com/fr-FR/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptPrefixes/Mapping.htm)