# Chargement de données depuis des tables inline
Saisissez des données manuellement dans un script pour définir une table inline.
Vous créez des tables inline en saisissant des données manuellement dans le script au lieu de vous connecter à des fichiers et des bases de données. Utilisez la syntaxe requise pour indiquer que le texte du script doit être interprété comme des données inline.
Un chargement inline de base crée une table et insère les champs de données et les enregistrements.
## Pourquoi utiliser des chargements inline ?
Les chargements inline peuvent s'avérer utiles dans un certain nombre de cas d'utilisation :
* Administration et édition de données sans avoir à se connecter à des sources externes.
* Enrichissement de données existantes dans le modèle de données. Par exemple, vous pourriez ajouter une table supplémentaire à un modèle de données provenant essentiellement de sources de bases de données.
* Ajout de données que vous souhaitez éviter d'avoir à charger continuellement depuis des sources externes. Cela peut vous faire gagner du temps, si vous savez qu'il se peut que la source de données change à l'avenir, mais que les valeurs des données resteront les mêmes.
* Facile à utiliser pour copier-coller du contenu dans le script à partir d'autres fichiers. Par exemple, des fichiers ou tables .csv provenant de documents de traitement de texte.
* Création de scripts test rapides à copier-coller.
## Exemple de syntaxe de base
Le script suivant contient un chargement inline simple.
```
MyTable:
Load * Inline [Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
];
```
La syntaxe suivante est utilisée pour le chargement inline ci-dessus :
* Load \* Inline indique à QlikView de charger tous les champs de la table inline qui suit.
* MyTable: définit le nom de la table.
* Les données sont encadrées par des crochets.
* La première ligne de l'instruction load définit les champs de données.
* Des virgules séparent les champs de données et les enregistrements.
* Un point-virgule ferme l'instruction load.
## Vue d'ensemble de la syntaxe
### Nommage de la table
Vous pouvez ajouter un nom à la table inline, comme vous le feriez pour d'autres tables chargées. La définition du nom de table est facultative.
Après le nom de la table, insérez deux-points.
### Instructions LOAD et inline
Une table inline est chargée avec la clause inline lorsque vous utilisez l'instruction de script LOAD. La clause inline indique que le texte qui suit dans la table contient des données saisies manuellement dans l'éditeur. Sauf indication contraire de votre part, une table inline utilise le format txt, qui suit la structure d'un fichier texte délimité.
Pour plus d'informations sur l'instruction LOAD, voir [Load](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm).
### Encadrements et saisie de données
Les données saisies via une clause inline doivent être encadrées de caractères spécifiques. Les combinaisons de caractères suivantes sont acceptées pour encadrer les données :
* Crochets : `[` et `]`
* Guillemets doubles : `"` et `"`
* Guillemets simples : `'` et `'`
* Backticks : `` ` `` et `` ` ``
Le caractère que vous sélectionnez comme encadrement peut vous aider à charger des données inline contenant des caractères conflictuels. Par exemple, si vos données contiennent des enregistrements avec des crochets, vous pouvez les encadrer de guillemets ou de backticks.
Pour un exemple d'encadrements alternatifs, voir [Exemple - Encadrements de données alternatifs](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDataEnc).
À moins de spécifier un format de table alternatif (la valeur par défaut est txt), le texte encadré est interprété de la même manière que le contenu d'un fichier. C'est pourquoi vous devez également insérer une nouvelle ligne dans la clause inline, là où vous en auriez inséré une dans un fichier texte : en appuyant sur la touche Entrée lors de la saisie du script.
### Fin de l'instruction inline load
La fin de l'instruction inline load est indiquée par un point-virgule.
### Transformation de données
Dans un chargement inline simple sans transformations, le nombre de colonnes est défini par la première ligne. Il existe trois colonnes dans la table chargée par l'exemple suivant : `Product_ID`, `Supplier_Name` et `Product_Category`.
```
Products:
Load * Inline [
Product_ID, Supplier_Name, Product_Category
1, Paracel, Home Decor
2, PageWave, Electronics
3, Talarian, Software
4, Userland, Appliances
];
```
Vous pouvez également effectuer des transformations et créer de nouvelles colonnes au sein de la même table inline. Vous pouvez utiliser preceding loads, et plusieurs instructions LOAD peuvent être utilisées pour charger la même table.
Pour des exemples spécifiques, voir [Exemples - Chargements inline avec des transformations](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExTransform).
### Configuration de la spécification de format d'un chargement inline
Comme avec les autres tables chargées, vous pouvez modifier la spécification de format de la table inline via des éléments de spécification de format. La spécification de format est ajoutée entre parenthèses. Elle doit être ajoutée après les encadrements de données, mais avant le point-virgule mettant fin à l'instruction LOAD. Voici quelques-unes des personnalisations que vous pouvez inclure :
* Remplacement du délimiteur de type virgule par un autre caractère. Pour des exemples, voir [Exemples - Délimiteurs alternatifs](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDelimiter).
Consultez : [Delimiter](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/delimiter.htm)
* Omission des en-têtes de colonne de table. Pour un exemple, voir [Exemple - Omission d'en-têtes de colonne](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOmitLabels).
Consultez : [Labels](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/labels.htm)
* Utilisation d'un autre format de données (par exemple, un format d'enregistrement fixe). Pour un exemple, voir [Exemple - Chargement d'un autre type de données](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExChangeFormat).
Consultez : [Format de table](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/table-format.htm)
Note InformationsToutes les options Table format ne sont pas supportées dans les chargements inline.
* Autorisation de contenu multiligne. Pour un exemple, voir [Exemple - Contenu multiligne](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExMultLine).
Consultez : [Quotes](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/quotes.htm)
Pour pouvoir utiliser plusieurs éléments de spécification de format dans la même table, séparez-les à l'aide de virgules. Par exemple :` (Delimiter is '|', no labels) `
Pour des informations détaillées complètes sur la spécification de format, voir [Éléments de spécification du format](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm).
### Opérateurs et autres clauses
De plus, étant donné qu'un chargement inline est une instruction LOAD, vous pouvez combiner d'autres arguments pour l'instruction LOAD dans le chargement inline. Par exemple, utilisez la clause where ou while pour définir s'il faut ou non charger une ligne spécifique, en fonction du texte qu'elle contient.
De même, vous pouvez utiliser des opérateurs en dehors du contenu de texte lui-même. Grâce à des opérateurs, vous pouvez personnaliser la manière de transformer les données inline et définir quand charger certaines données ou non.
Pour un exemple spécifique, voir [Exemple - Opérateurs de transformations et de clauses](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOpsAndClauses).
## Exemple - Encadrements de données alternatifs
Vous pouvez utiliser des crochets, des guillemets ou des backticks pour encadrer un chargement inline. Cette section le montre à l'aide d'un exemple. Pour plus d'informations, consultez [Encadrements et saisie de données](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Enclosure).
#### Script de chargement et résultats
Vue d'ensemble
Cet exemple montre comment utiliser des backticks pour encadrer des données inline. Les données de l'exemple contiennent des caractères de crochet, ce qui rend les crochets incompatibles comme caractères d'encadrement pour l'instruction LOAD.
Script de chargement
```
DataTable:
Load * inline
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;
```
Résultats
* `custom_property`
* `date`
* `amount`
Tableau de résultats
| custom\_property | date | amount |
| --- | --- | --- |
| [11402] | 1/1/2024 | 92.99 |
| [11403] | 1/2/2024 | 102.34 |
| [11404] | 1/3/2024 | 50.26 |
| [11405] | 1/4/2024 | 153.69 |
| [11406] | 1/5/2024 | 75.62 |
## Exemples - Délimiteurs alternatifs
Vous pouvez utiliser un caractère autre qu'une virgule pour délimiter les valeurs des colonnes de la table. Pour plus d'informations, consultez [Configuration de la spécification de format d'un chargement inline](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Script de chargement et résultats
Vue d'ensemble
Le remplacement du délimiteur s'avère utile lorsque les données de la table contiennent des virgules, qui, si elles étaient utilisées comme délimiteur, entraîneraient le passage à la colonne suivante de la table.
Cet exemple contient :
* quatre tables à charger. Il s'agit des suivantes :
* Table1 : le délimiteur est une barre verticale (pipe). Les données de la colonne Phrase contiennent des virgules.
* Table2 : le délimiteur est le caractère de deux-points.
* Table3 : le délimiteur est une barre oblique inversée.
* Table4 : la table est délimitée via une pression sur la touche Tab du clavier. Cette option s'avère utile lorsque vous copiez une table d'un traitement de texte et que vous la collez dans le script.
Table1 montre un cas d'utilisation pratique d'un délimiteur alternatif. Les autres tables montrent d'autres options de délimiteur.
Script de chargement
```
Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');
Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');
Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);
Table4:
LOAD * INLINE [
Num3 Chr3
1 A
2 B ] (Delimiter is '\t');
```
Résultats
Tableau de résultats : Table1Table1
| ID | Phrase |
| --- | --- |
| 1 | The transaction was complete, but the order has not yet shipped. |
| 2 | We need to confirm the following details: sales rep number, order status, and shipping priority. |
Tableau de résultats : Table2Table2
| Num1 | Chr1 |
| --- | --- |
| 1 | A |
| 2 | B |
Tableau de résultats : Table3Table3
| Num2 | Chr2 |
| --- | --- |
| 1 | A |
| 2 | B |
Tableau de résultats : Table4Table4
| Num3 | Chr3 |
| --- | --- |
| 1 | A |
| 2 | B |
## Exemple - Omission d'en-têtes de colonne
Modifiez la spécification de format de sorte à charger une table inline sans définir d'en-têtes de colonne. Cela s'effectue via la spécification de labels (en définissant cette option sur la valeur no labels). Pour plus d'informations, consultez [Configuration de la spécification de format d'un chargement inline](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
Lorsque vous chargez une table sans définir de noms de colonne, les noms de colonne définis par le système sont automatiquement utilisés.
#### Script de chargement et résultats
Vue d'ensemble
Cet exemple montre comment charger une table inline sans définir de noms de colonne.
Script de chargement
```
Expenses:
Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);
```
Résultats
Tableau de résultats
| @1 | @2 | @3 |
| --- | --- | --- |
| 1 | Category1 | 40566.49 |
| 2 | Category2 | 3504.54 |
| 3 | Category3 | 593206.30 |
## Exemple - Chargement d'un autre type de données
Cet exemple montre comment charger une table inline dans un format d'enregistrement fixe. Voir [Configuration de la spécification de format d'un chargement inline](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Script de chargement et résultats
Vue d'ensemble
Cet exemple de script contient les éléments suivants :
* Une instruction inline load définissant la table DataTable.
* L'utilisation de fix (dans le cadre de la spécification de Table format) pour indiquer que les données à charger se présentent au format d'enregistrement fixe.
Script de chargement
```
DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a b c d
1 2 3 4
x y z w
] (fix, utf8, embedded labels);
```
Résultats
Tableau de résultats
| a | b | c | d |
| --- | --- | --- | --- |
| 1 | 2 | 3 | 4 |
| x | y | z | w |
## Exemple - Contenu multiligne
Cet exemple montre comment saisir le contenu d'un champ multiligne dans une table inline. Voir [Configuration de la spécification de format d'un chargement inline](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Script de chargement et résultats
Vue d'ensemble
Cet exemple de script contient les éléments suivants :
* Un chargement inline simple pour définir la table T1.
* Utilisez le spécificateur Quotes (avec la valeur msq) pour prendre en charge le contenu multiligne.
* Valeurs de longueur spécifiées en pieds et en pouces.
* Le symbole de double guillemet (") indique la fin d'une entrée multiligne. Dans cet exemple, le même symbole est également utilisé pour indiquer les valeurs en pouces. Cela montre la syntaxe et le comportement qui s'ensuit si vous devez utiliser les deux dans la même instruction LOAD. En l'essence, le fait de saisir le symbole " pour deux caractères consécutifs ("") indique que le code doit être interprété comme une seule instance de texte du symbole.
Script de chargement
```
T1:
Load *, recno() as ID inline [
Length
"1' 2""
22' 10"""
14' 8" ] (msq);
```
Résultats
Pour afficher le contenu multiligne comme prévu, vous devez ajuster les Paramètres multilignes du graphique dans la configuration Propriétés....
Tableau de résultats
| ID | Length |
| --- | --- |
| 1 | 1' 2"
22' 10" |
| 2 | 14' 8" |
Dans le tableau ci-dessus, l'enregistrement avec une valeur ID égale à 1 contient un contenu multiligne.
## Exemples - Chargements inline avec des transformations
Ces exemples montrent comment effectuer des calculs sur des champs chargés inline pour créer de nouveaux champs dans le modèle de données.
Pour plus d'informations, consultez [Transformation de données](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Transform).
#### Exemple : Simple renommage d'un champ
Script de chargement
```
ORDERS:
Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];
```
Résultats
Tableau de résultats
| Original | Updated |
| --- | --- |
| ProductA | ProductA |
| ProductB | ProductB |
| ProductC | ProductC |
#### Exemple : Simple insertion d'un champ ID
Vue d'ensemble
Cet exemple montre comment définir un champ calculé de sorte à indiquer l'ID de chaque ligne de données, sans avoir à saisir manuellement chaque valeur d'ID.
Script de chargement
```
ORDERS:
Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];
```
Résultats
Tableau de résultats
| ID | ProductName |
| --- | --- |
| 1 | A |
| 2 | B |
| 3 | C |
| 4 | D |
| 5 | E |
#### Exemple : Configuration d'instructions LOAD pour manipuler des transformations
Vue d'ensemble
Cet exemple montre plusieurs manières d'appliquer une transformation simple à des données inline. Vous pouvez utiliser une ou plusieurs instructions LOAD et configurer la syntaxe de différentes manières afin de définir si une transformation remplace ou non le champ d'origine ou si les deux champs, celui d'origine et le nouveau, sont chargés.
En particulier, notez les variations dans ce qui suit et comment elles affectent la sortie :
* Nombre d'instructions LOAD dans la table.
* Présence ou absence de symbole \* (charge tous les champs qui suivent).
* Présence ou absence de virgules (symbole ,).
Cet exemple de script contient les éléments suivants :
* Quatre tables, toutes référençant les mêmes données. Les noms de champ sont différents.
* DerivedYears1 : utilise deux instructions LOAD pour charger une colonne inline et une colonne contenant une transformation de la colonne inline.
* DerivedYears2 : utilise deux instructions LOAD. Le script charge une colonne inline, puis un champ calculé transformé à partir de la colonne d'origine. Avec la deuxième instruction LOAD, la colonne d'origine n'est pas chargée dans la table, remplaçant efficacement le champ d'origine par le nouveau champ.
* DerivedYears3 : utilise une seule instruction LOAD pour charger la colonne inline d'origine et une colonne transformée.
* DerivedYears4 : utilise une seule instruction LOAD pour définir un champ inline et une transformation de ce champ d'origine. Seul le champ transformé est chargé dans la table.
Script de chargement
```
DerivedYears1:
Load *,
Year(initial_date1) as derived_year1
;
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears2:
Load
Year(initial_date2) as derived_year2
;
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears3:
Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears4:
Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
```
Résultats
Tableau de résultats : DerivedYears1DerivedYears1
| initial\_date1 | derived\_year1 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Tableau de résultats : DerivedYears2DerivedYears2
| derived\_year2 |
| --- |
| 2022 |
| 2023 |
| 2024 |
Tableau de résultats : DerivedYears3DerivedYears3
| initial\_date3 | derived\_year3 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Tableau de résultats : DerivedYears4DerivedYears4
| derived\_year4 |
| --- |
| 2022 |
| 2023 |
| 2024 |
#### Exemple : Modification du contenu d'un champ
Vue d'ensemble
Supposons que vous colliez dans l'éditeur de script des informations provenant d'un fichier texte volumineux, mais que vous souhaitiez effectuer un traitement supplémentaire sur les enregistrements du jeu de données. Par exemple, vous souhaitez supprimer certains caractères et préfixes et capitaliser chaque terme.
Cet exemple de script contient les éléments suivants :
* Une table inline, Transformations, dans laquelle une transformation est définie de sorte à modifier le contenu textuel d'un champ. Le texte transformé est ajouté après cela.
* Deux instructions LOAD. Avec la configuration de l'exemple, seul le champ dérivé ProductName\_Trimmed est chargé dans la table.
Script de chargement
```
Transformations:
Load
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;
Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product: {snack food}
Product: {electronics and video games}
];
```
Résultats
Tableau de résultats
| ProductName\_Trimmed |
| --- |
| Soft Drinks And Other Beverages |
| Snack Food |
| Electronics And Video Games |
## Exemple - Opérateurs de transformations et de clauses
Vous pouvez utiliser des opérateurs pour définir des transformations et des clauses spécifiques dans l'instruction LOAD. Pour plus d'informations, consultez [Opérateurs et autres clauses](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#OpsAndClauses).
[Opérateurs](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/Operators/operators.htm)
#### Script de chargement et résultats
Vue d'ensemble
Cet exemple de script contient les éléments suivants :
* Un chargement inline simple pour définir la table Purchases.
* L'insertion d'un champ calculé, OrderSize. Ce champ est une transformation du champ amount du jeu de données inline. Il catégorise les achats comme importants ou peu importants suivant que le montant dépasse ou non $2000,00.
* Une clause where qui empêche le chargement des enregistrements lorsque la valeur de amount est inférieure à $0.05.
Script de chargement
```
Purchases:
Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,
* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;
```
Résultats
Tableau de résultats
| ID | amount | OrderSize |
| --- | --- | --- |
| 1 | 2660.39 | Large Purchase |
| 2 | 100.01 | Small Purchase |
| 3 | 500.42 | Small Purchase |
| 4 | 5023.99 | Large Purchase |
| 6 | 2002.39 | Large Purchase |
| 7 | 31034.53 | Large Purchase |
| 8 | 1643.58 | Small Purchase |
| 9 | 3993.65 | Large Purchase |
| 10 | 614.34 | Small Purchase |
| 11 | 675.93 | Small Purchase |
Dans le tableau ci-dessus, la transaction avec un ID égal à 5 n'a pas été chargée dans la table. Cela est dû au fait que la valeur de amount est inférieure à $0.05.
## Exemple - Création de valeurs nulles dans une table inline
Cet exemple montre comment utiliser la variable NullInterpret pour créer des valeurs nulles dans vos données inline.
[NullInterpret](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ValueHandlingVariables/NullInterpret.htm)
#### Script de chargement et résultats
Vue d'ensemble
Cet exemple de script contient les éléments suivants :
* Un chargement inline simple pour définir la table T2.
* La variable NullInterpret définie sous la forme de deux guillemets simples. Lors du chargement du script, les enregistrements contenant cette valeur sont traités comme des valeurs nulles.
Script de chargement
```
set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];
```
Résultats
Tableau de résultats
| Test |
| --- |
| x |
Dans le tableau ci-dessus, le premier enregistrement est une valeur nulle. Par conséquent, il n'est pas inclus dans la visualisation. Les valeurs nulles existant dans les tables avec des dimensions supplémentaires seraient indiquées par un symbole -.
## Autres exemples
Pour des exemples supplémentaires, voir [Load](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm).
## En savoir plus
* [Load](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm)
* [Éléments de spécification du format](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm)
* [Assistant Données intégrées](https://help.qlik.com/fr-FR/qlikview/September2025/Subsystems/Client/Content/QV_QlikView/Inline_Data_Wizard.htm)