# Modificateurs d'ensemble associés à des expansions de $

Les expansions de signe dollar sont des constructions qui sont calculées avant l'analyse et l'évaluation de l'expression. Le résultat est ensuite injecté dans l'expression au lieu de `$(…)`. Le calcul de l'expression est alors effectué via le résultat de l'expansion dollar.

L'éditeur d'expression affiche un aperçu de l'expansion dollar afin de vous permettre de vérifier par rapport à quoi votre expansion de signe dollar est évaluée.

Aperçu de l'expansion de signe dollar dans l'éditeur d'expression

Aperçu de l'expansion de signe dollar dans l'éditeur d'expression

Aperçu de l'expansion de signe dollar dans l'éditeur d'expression ![Aperçu de l'expansion de signe dollar dans l'éditeur d'expression.](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Resources/Images/ui_gen_dollar_expansion_preview.png)

Utilisez des expansions de signe dollar si vous souhaitez utiliser un calcul à l'intérieur de votre ensemble d'éléments.

Par exemple, si vous souhaitez examiner uniquement la dernière année possible, vous pouvez utiliser la construction suivante :

`<Year = {$(=Max(Year))}>`

`Max(Year)` est calculé en premier, et le résultat est injecté dans l'expression au lieu de `$(…)`.

Le résultat après l'expansion dollar sera une expression telle que la suivante :

`<Year = {2021}>`

L'expression à l'intérieur de l'expansion dollar est calculée en fonction de la sélection active. Cela signifie que si vous avez une sélection dans un autre champ, le résultat de l'expression en sera affecté.

Si vous souhaitez que le calcul soit indépendant de la sélection, utilisez set analysis (analyse d'ensembles) à l'intérieur de l'expansion dollar. Par exemple :

`<Year = {$(=Max({1} Year))}>`

## Chaînes de caractères

Pour que l'expansion dollar aboutisse à une chaîne, vous devez appliquer les règles normales en matière de guillemets. Par exemple :

`<Country = {'$(=FirstSortedValue(Country,Date)'}>`

Le résultat après l'expansion dollar sera une expression telle que la suivante :

`<Country = {'New Zealand'}>`

Si vous n'utilisez pas les guillemets, vous obtiendrez une erreur de syntaxe.

## Nombres

Si vous souhaitez que l'expansion dollar aboutisse à un nombre, assurez-vous que l'expansion a le même format que le champ. Cela signifie que vous devez parfois encadrer l'expression par une fonction de formatage.

Par exemple :

`<Amount = {$(=Num(Max(Amount), '###0.00'))}>`

Le résultat après l'expansion dollar sera une expression telle que la suivante :

`<Amount = {12362.00}>`

Utilisez un dièse pour forcer l'expansion à toujours utiliser un point décimal et aucun séparateur de milliers. Par exemple :

`<Amount = {$(#=Max(Amount))}>`

## Dates

Si vous souhaitez que l'expansion dollar aboutisse à une date, assurez-vous que le format de l'expansion est correct. Cela signifie que vous devez parfois encadrer l'expression par une fonction de formatage.

Par exemple :

`<Date = {'$(=Date(Max(Date)))'}>`

Le résultat après l'expansion dollar sera une expression telle que la suivante :

`<Date = {'12/31/2015'}>`

Tout comme avec les chaînes, vous devez utiliser les guillemets corrects.

Un cas d'utilisation courant consiste à vouloir limiter le calcul au dernier mois (ou à la dernière année). Dans ce cas, vous pouvez utiliser une recherche numérique en combinaison avec la fonction `AddMonths()`.

Par exemple :

`<Date = {">=$(=AddMonths(Today(),-1))"}>`

Le résultat après l'expansion dollar sera une expression telle que la suivante :

`<Date = {">=9/31/2021"}>`

Cela sélectionnera tous les événements qui se sont produits le dernier mois.

## Exemple : Expressions de graphique pour modificateurs d'ensemble associés à des expansions de signe dollar

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-modifiers-dollar-sign-expansions.htm)

#### Exemple - expressions de graphique

Script de chargement

Chargez les données suivantes sous forme de chargement inline dans l'éditeur de chargement de données pour créer les exemples d'expression de graphique ci-dessous.

```
Let vToday = Today();
MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2021-10-15, France, Washer, 1];	
```

Pour plus d'informations sur l'utilisation de chargements inline, consultez [Utilisation de chargements inline pour charger des données](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm).

Expressions de graphique associées à des expansions de signe dollar

Créez une table dans une feuille Qlik Sense avec les expressions de graphique suivantes.

Tableau - modificateurs d'ensemble associés à des expansions $

| Country | Sum (Amount) | Sum({&lt;US\_Date={'$(vToday)'}&gt;} Amount) | Sum({&lt;ISO\_Date={"$(=Date(Min(ISO\_Date),'YYYY-MM-DD'))"}&gt;} Amount) | Sum({&lt;US\_Date={"&gt;=$(=AddYears(Max(US\_Date),-1))"}&gt;} Amount) |
| --- | --- | --- | --- | --- |
| Totals | 41 | 1 | 6 | 1 |
| Canada | 14 | 0 | 6 | 0 |
| Czech Republic | 10 | 0 | 0 | 0 |
| France | 4 | 1 | 0 | 1 |
| Germany | 13 | 0 | 0 | 0 |

Explication

* Dimensions :

  * `Country`

* Mesures :

  * `Sum(Amount)`

    Somme `Amount` sans expression d'ensemble.

  * `Sum({<US_Date={'$(vToday)'}>}Amount)`

    Somme `Amount` de tous les enregistrements dans lesquels la date `US_Date` est la même que dans la variable `vToday`.

  * `Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>}Amount)`

    Somme `Amount` de tous les enregistrements dans lesquels la date `ISO_Date` est la même que la première valeur `ISO_Date` possible (la plus antérieure). La fonction `Date()` est nécessaire pour garantir que le format de la date correspond à celui du champ.

  * `Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>}Amount)`

    Somme `Amount` de tous les enregistrements qui contiennent une valeur `US_Date` après ou à la date une année avant la dernière date `US_Date` possible (la plus récente). La fonction `AddYears()` renverra une date au format spécifié par la variable `DateFormat`, et ce format doit correspondre au format du champ `US_Date`.

Modificateurs d'ensemble associés à des expansions de $

Modificateurs d'ensemble associés à des expansions de $

Modificateurs d'ensemble associés à des expansions de $ ![Modificateurs d'ensemble associés à des expansions de $.](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Resources/Images/ui_gen_setanalysis_dollar_expansion.png)

Pour plus d'informations sur les expressions, voir [Utilisation d'expressions dans les visualisations](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/use-expressions-in-visualizations.htm).

| Exemples | Résultats |
| --- | --- |
| sum( {$&lt;Year = {$(#vLastYear)}&gt;} Sales ) | Renvoie les ventes pour l'année précédente par rapport à la sélection active. Dans cet exemple, une variable vLastYear contenant l'année en question est utilisée dans une expansion de $. |
| sum( {$&lt;Year = {$(#=Only(Year)-1)}&gt;} Sales ) | Renvoie les ventes pour l'année précédente par rapport à la sélection active. Dans cet exemple, l'expansion de dollar sert à calculer l'année précédente. |