# Above - fonction de graphique

Above() évalue une expression au niveau de la ligne située au-dessus de la ligne active dans un segment de colonne d'une table. La ligne pour laquelle elle est calculée dépend de la valeur de décalage offset (si présente), le paramètre par défaut étant la ligne située directement au-dessus. Pour les autres graphiques que les tables, l'évaluation de la fonction Above() porte sur la ligne située au-dessus de la ligne active dans l'équivalent du tableau simple du graphique.

Syntaxe :

Above([TOTAL] expr [ , offset [,count]])

Type de données renvoyé : double

Arguments

| Argument | Description |
| --- | --- |
| expr | Expression ou champ contenant les données à mesurer. |
| offset | Si vous spécifiez un décalage offset n supérieur à 0, l'évaluation de l'expression est déplacée de n lignes au-dessus de la ligne active.<br><br>Si vous spécifiez un décalage égal à 0, l'expression est évaluée sur la ligne active.<br><br>Si vous spécifiez un décalage négatif, la fonction Above aboutit au même résultat que la fonction Below avec le décalage positif correspondant. |
| count | Si vous spécifiez un troisième argument count supérieur à 1, la fonction renvoie une plage de valeurs count, une pour chacune des lignes de table count situées au-dessus de la cellule de départ.<br><br>De cette façon, la fonction peut être utilisée comme argument pour l'une des fonctions de plage spéciales. [Fonctions de plage](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/RangeFunctionsInCharts.htm) |
| TOTAL | Si la table est unidimensionnelle ou si le qualificateur TOTAL est utilisé comme argument, le segment de colonne actif est toujours égal à la colonne entière.<br><br>[Définition de l'étendue d'une agrégation](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |

Pour la première ligne d'un segment de colonne, la fonction renvoie une valeur NULL, puisqu'il n'y a pas de ligne au-dessus.

Note InformationsUn segment de colonne se définit comme un sous-ensemble de cellules consécutives dotées des mêmes valeurs de dimensions dans l'ordre de tri actif. Les fonctions graphiques d'inter-enregistrements sont calculées dans le segment de colonne excluant la dimension située le plus à droite dans l'équivalent du tableau simple du graphique. Si le graphique ne comprend qu'une seule dimension ou si le qualificateur TOTAL est spécifié, l'évaluation de l'expression porte sur la table entière.

Note InformationsSi la table ou l'équivalent en tableau comporte plusieurs dimensions verticales, le segment de colonne actif comprend uniquement les lignes contenant les mêmes valeurs que la ligne active dans toutes les colonnes de dimensions, à l'exception de la colonne affichant la dernière dimension dans l'ordre de tri inter-champs.

Limitations :

* Les appels récursifs renvoient la valeur NULL.

* Le tri sur les valeurs des ordonnées dans les graphiques ou le tri par colonnes d'expressions dans les tableaux n'est pas autorisé lors de l'utilisation de cette fonction de graphique dans l'une des expressions du graphique. Ces options de tri sont donc automatiquement désactivées. Lorsque vous utilisez cette fonction de graphique dans une visualisation ou un tableau, le tri de la visualisation revient à l'entrée triée via cette fonction.

Exemple : Expressions de graphique

| Exemple | Résultat |
| --- | --- |
| `Above( Sum(Sales) )` | Renvoie la valeur de `Sales` pour la ligne située au-dessus de la ligne active. |

## Exemple - Les bases de Above

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Expression de graphique

Vue d'ensemble

Ouvrez l'éditeur de chargement de données et ajoutez le script de chargement ci-dessous à une nouvelle section.

Le script de chargement contient :

* Jeu de données chargé dans une table de données appelée `Example`.

* Champs suivants dans la table de données :

  * `Year`

  * `Sales`

Script de chargement

```
Example:
LOAD * INLINE [
Year, Sales
2019, 1000
2020, 1500
2021, 1200
2022, 1800
2023, 1700
];
```

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ce champ comme dimension :

* `Year`

Créez les mesures suivantes :

* `=Sum(Sales)`, pour trouver les ventes annuelles.

* `=Above(Sum(Sales))`, pour trouver la valeur des ventes de l'année précédente.

* `=Sum(Sales) - Above(Sum(Sales))`, pour calculer la variance entre la valeur `Sales` de l'année en cours et la valeur de l'année précédente.

* `=RangeSum(Above(Sales, 1, 2))`, pour démontrer une agrégation mobile sur deux ans des deux années de ventes précédentes.

* `=(Sales - Above(Sales)) / Above(Sales)`, pour renvoyer la variation de `Sales` sous forme de ratio/pourcentage. Pour afficher cette valeur sous forme de pourcentage, sous Formatage des nombres, sélectionnez Nombre &gt; Formatage simple &gt; 12,34 %.

Tableau de résultats

| Year | Sum(Sales) | Above(Sum(Sales)) | Sum(Sales) - Above(Sum(Sales)) | RangeSum(Above(Sales, 1, 2) | (Sales - Above(Sales)) / Above(Sales) |
| --- | --- | --- | --- | --- | --- |
| Totals | 7200 | - | - | 0 | - |
| 2019 | 1000 | - | - | 0 | - |
| 2020 | 1500 | 1000 | 500 | 1000 | 50.00% |
| 2021 | 1200 | 1500 | -300 | 2500 | -20.00% |
| 2022 | 1800 | 1200 | 600 | 2700 | 50.00% |
| 2023 | 1700 | 1800 | -100 | 3000 | -5.56% |

En examinant les résultats, vous pouvez comparer les valeurs de `Sales` de la période en cours à celles de la période précédente.

* La mesure `Sum(Sales)- Above(Sum(Sales))` renvoie la variation des valeurs `Sales` en comparant la période en cours à la période précédente.

* La mesure `RangeSum(Above(Sales, 1, 2))` renvoie la somme des deux valeurs `Sales` précédentes.

* La mesure `(Sales - Above(Sales)) / Above(Sales)` renvoie la variation de `Sales` par rapport à la période précédente sous forme de pourcentage.

Note ConseilCette fonction peut également s'utiliser dans d'autres graphiques que les tables, dans les histogrammes par exemple.

Procédez comme suit :

Créez un graphique à barres et ajoutez ce champ comme dimension :

* `Year`

Créez la mesure suivante :

* `=Sum(Sales) - Above(Sum(Sales))`, pour renvoyer la variance d'une année sur l'autre.

Graphique à barres montrant les résultats de la fonction Above

Graphique à barres montrant les résultats de la fonction Above

Graphique à barres montrant les résultats de la fonction AboveAbove ![Graphique à barres montrant la variance d'une année sur l'autre de la somme des ventes](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Resources/Images/scripting-functions-above-example.png)

L'utilisation de la fonction `Above` dans un graphique à barres fournit une comparaison visuelle de la variance entre les ventes de la période en cours et celles de la période précédente.

## Exemple - Scénario Above

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Expression de graphique

Vue d'ensemble

Ouvrez l'éditeur de chargement de données et ajoutez le script de chargement ci-dessous à une nouvelle section.

Le script de chargement contient :

* Jeu de données chargé dans une table de données appelée `Example`.

* Champs suivants dans la table de données :

  * `SalesYear`

  * `SalesAmount`

Script de chargement

```
Example:
LOAD * INLINE [
SalesYear, SalesAmount
2019, 500
2020, 800
2021, 400
2022, 700
2023, 600
];
```

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ce champ comme dimension :

* `SalesYear`

Créez les mesures suivantes :

* `=Sum(SalesAmount)`, pour agréger les ventes.

* `=RangeSum(Above(SalesAmount, 0, RowNo()))`, pour calculer le total cumulé des valeurs de `SalesAmount`.

Tableau de résultats

| SalesYear | Sum(SalesAmount) | RangeSum(Above(SalesAmount, 0, RowNo())) |
| --- | --- | --- |
| Totals | 3000 | 0 |
| 2019 | 500 | 500 |
| 2020 | 800 | 1300 |
| 2021 | 400 | 1700 |
| 2022 | 700 | 2400 |
| 2023 | 600 | 3000 |

Les résultats montrent comment utiliser une combinaison des fonctions `RangeSum` et `Above` pour créer un total cumulé.

Note ConseilCette fonction peut également s'utiliser dans d'autres graphiques que les tables, dans les histogrammes par exemple.

Procédez comme suit :

Créez un graphique à barres et ajoutez ce champ comme dimension :

* `SalesYear`

Créez la mesure suivante :

* `=RangeSum(Above(SalesAmount, 0, RowNo()))`, pour renvoyer la valeur cumulée des ventes.

Graphique à barres indiquant la valeur cumulée des ventes par an

Graphique à barres indiquant la valeur cumulée des ventes par an

Graphique à barres indiquant la valeur cumulée des ventes par an ![Graphique à barres indiquant la valeur cumulée des ventes par année de ventes.](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Resources/Images/scripting-functions-above-example2.png)

## Exemple : Expression de graphique utilisant Above

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Expression de graphique

Vue d'ensemble

Ouvrez l'éditeur de chargement de données et ajoutez le script de chargement ci-dessous à une nouvelle section.

Le script de chargement contient :

* Deux tables de données appelées `Monthnames` et `Sales2013`.

Script de chargement

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];
Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');
```

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ce champ comme dimension :

* `Customer`

Créez les mesures suivantes :

* `=Sum(Sales)`, pour calculer la somme des ventes.

* `=Above(Sum(Sales))`, pour indiquer la somme des ventes de la ligne précédente.

* `=Sum(Sales)+Above(Sum(Sales))`, pour additionner la somme de la valeur des ventes et la somme des ventes de la ligne du client au-dessus de la ligne active.

* `=Sum(Sales)+Above(Sum(Sales), 3)`, pour additionner la valeur de `Sum(Sales)` pour le client `Customer` actuel et la valeur du client `Customer` qui se trouve trois lignes au-dessus.

* `=IF(Sum(Sales)>Above(Sum(Sales)), 'Higher')`, pour ajouter l'étiquette `Higher` aux clients dont les résultats `Sum(Sales)` sont supérieurs à la valeur `Sum(Sales)` du client de la ligne au-dessus.

Tableau de résultats

| Customer | Sum(Sales) | Above(Sum(Sales)) | Sum(Sales)+Above(Sum(Sales)) | Sum(Sales)+Above(Sum(Sales), 3) | IF(Sum(Sales)&gt;Above(Sum(Sales)), 'Higher') |
| --- | --- | --- | --- | --- | --- |
| Totals | 2566 | - | - | - | - |
| Astrida | 587 | - | - | - | - |
| Betacab | 539 | 587 | 1126 | - | - |
| Canutility | 683 | 539 | 1222 | - | Higher |
| Divadip | 757 | 683 | 1440 | 1344 | Higher |

La mesure `Above(Sum(Sales))` renvoie NULL pour le client `Astrida`, car il n'existe pas de ligne au-dessus. Le résultat pour le client `Betacab` indique la valeur de `Sum(Sales)` pour `Astrida`. Le résultat de `Canutility` indique la valeur de `Sum(Sales)` pour `Betacab`, et ainsi de suite.

Pour la mesure `Sum(Sales)+Above(Sum(Sales))`, la ligne de `Betacab` renvoie le résultat de l'addition des valeurs `Sum(Sales)` des lignes `Betacab` + `Astrida` (`539+587`). Le résultat de la ligne `Canutility` affiche le résultat de l'addition des valeurs `Sum(Sales)` de `Canutility` + `Betacab` (`683+539`).

La mesure `Sum(Sales)+Above(Sum(Sales), 3)` a pour argument `offset`, défini sur `3`. Cela prend la valeur de la ligne qui se trouve 3 lignes au-dessus de la ligne actuelle. Cela ajoute la valeur `Sum(Sales)` du client `Customer` actuel à la valeur du client `Customer` qui se trouve trois lignes au-dessus. Par exemple, la valeur `Sum(Sales)` de `Divadip`, est ajoutée à la valeur `Sum(Sales)` de `Astrida`, le client qui se trouve trois lignes au-dessus de `Divadip`. Les valeurs renvoyées pour les 3 premières lignes `Customer` sont nulles, car il n'existe pas de données.

La mesure `IF(Sum(Sales)>Above(Sum(Sales)), 'Higher')` renvoie la valeur `Higher` pour les clients `Canutility` et `Divadip`, car leurs résultats de ventes sont tous les deux supérieurs à la somme des ventes du client de la ligne au-dessus, respectivement `Betacab` et `Canutility`.

Note ConseilCette fonction peut également s'utiliser dans d'autres graphiques que les tables, dans les histogrammes par exemple.

Note ConseilPour les autres types de graphique, convertissez le graphique en équivalent de tableau simple afin de pouvoir facilement interpréter la ligne à laquelle la fonction est liée.

## Exemple - Scénario Above basé sur l'ordre de tri

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Expression de graphique

Vue d'ensemble

Ouvrez l'éditeur de chargement de données et ajoutez le script de chargement ci-dessous à une nouvelle section.

Le script de chargement contient :

* Trois tables de données appelées Monthnames, Sales2013 et Product.

Script de chargement

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];

Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');

Product:
LOAD * inline [
Customer|Product|OrderNumber|UnitSales|UnitPrice
Astrida|AA|1|4|16
Astrida|AA|7|10|15
Astrida|BB|4|9|9
Betacab|CC|6|5|10
Betacab|AA|5|2|20
Betacab|BB||| 25
Canutility|AA|||15
Canutility|CC| ||19
Divadip|CC|2|4|16
Divadip|DD|3|1|25
] (delimiter is '|');
```

```

                                
```

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ces champs comme dimensions :

* Customer

* Product

* Month

Créez les mesures suivantes :

* =Sum(Sales), pour calculer la somme des ventes.

* =Above(Sum(Sales)), pour indiquer la somme des ventes de la ligne précédente.

Tableau de résultats

| Customer | Product | Month | Sum(Sales) | Above(Sum(Sales)) |
| --- | --- | --- | --- | --- |
| Totals | - | - | 2566 | - |
| Astrida | AA | Jan | 46 | - |
| Astrida | AA | Feb | 60 | 46 |
| Astrida | AA | Mar | 70 | 60 |
| Astrida | AA | Apr | 13 | 70 |
| Astrida | AA | May | 78 | 13 |
| Astrida | AA | Jun | 20 | 78 |
| Astrida | AA | Jul | 45 | 20 |
| Astrida | AA | Aug | 65 | 45 |
| Astrida | AA | Sep | 78 | 65 |
| Astrida | AA | Oct | 12 | 78 |
| Astrida | AA | Nov | 78 | 12 |
| Astrida | AA | Dec | 22 | 78 |
| Astrida | BB | Jan | 46 | - |
| Astrida | BB | Feb | 60 | 46 |

Pour les graphiques comportant plus d'une dimension, les résultats d'expressions contenant les fonctions Above, Below, Top et Bottom dépendent de l'ordre dans lequel les dimensions de colonne sont triées par Qlik Sense. Qlik Sense évalue les fonctions d'après les segments de colonne résultant de la dernière dimension qui a été triée. L'ordre de tri des colonnes est déterminé dans le panneau des propriétés, sous l'option Tri. Il ne correspond pas nécessairement à l'ordre d'affichage des colonnes dans une table.

Dans le tableau de résultats, la dernière dimension triée est Month, si bien que la fonction Above effectue les évaluations en se basant sur les mois. Une série de résultats est présentée pour chaque valeur Product associée à chaque mois (Jan à Dec) - un segment de colonne. Vient ensuite une série correspondant au segment de colonne suivant : chaque élément Month associé à l'élément Product suivant. Un segment de colonne est prévu pour chaque valeur Customer associée à chaque élément Product.

## Exemple - Scénario Above utilisant un ordre de tri différent

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Expression de graphique

Vue d'ensemble

Ouvrez l'éditeur de chargement de données et ajoutez le script de chargement ci-dessous à une nouvelle section.

Le script de chargement contient :

* Trois tables de données appelées Monthnames, Sales2013 et Product.

Script de chargement

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];

Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');

Product:
LOAD * inline [
Customer|Product|OrderNumber|UnitSales|UnitPrice
Astrida|AA|1|4|16
Astrida|AA|7|10|15
Astrida|BB|4|9|9
Betacab|CC|6|5|10
Betacab|AA|5|2|20
Betacab|BB||| 25
Canutility|AA|||15
Canutility|CC| ||19
Divadip|CC|2|4|16
Divadip|DD|3|1|25
] (delimiter is '|');
```

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ces champs comme dimensions :

* Customer

* Product

* Month

Créez les mesures suivantes :

* =Sum(Sales), pour calculer la somme des ventes.

* =Above(Sum(Sales)), pour indiquer la somme des ventes de la ligne précédente.

Modifiez l'ordre de tri du tableau dans le panneau des propriétés. Sélectionnez Tri, puis faites glisser la dimension Product jusqu'à la troisième position dans l'ordre de tri.

Tableau de résultats

| Customer | Product | Month | Sum(Sales) | Above(Sum(Sales)) |
| --- | --- | --- | --- | --- |
| Totals | - | - | 2566 | - |
| Astrida | AA | Jan | 46 | - |
| Astrida | BB | Jan | 46 | 46 |
| Astrida | AA | Feb | 60 | - |
| Astrida | BB | Feb | 60 | 60 |
| Astrida | AA | Mar | 70 | - |
| Astrida | BB | Mar | 70 | 70 |
| Astrida | AA | Apr | 13 | - |
| Astrida | BB | Apr | 13 | 13 |
| Astrida | AA | May | 78 | - |
| Astrida | BB | May | 78 | 78 |
| Astrida | AA | Jun | 20 | - |
| Astrida | BB | Jun | 20 | 20 |
| Astrida | AA | Jul | 45 | - |
| Astrida | BB | Jul | 45 | 45 |

Dans le tableau de résultats, la dernière dimension triée est Product. La fonction Above est évaluée pour chaque ligne Product. Étant donné qu'il n'y a que deux produits, AA et BB, chaque série ne comporte qu'un seul résultat différent de null. Sur la ligne BB du mois Jan, la valeur de Above(Sum(Sales)) est 46. Pour la ligne AA, la valeur est nulle. La valeur de chaque ligne AA de chaque mois sera toujours nulle, car il n'existe pas de valeur de Product au-dessus de AA. La seconde série est évaluée d'après AA et BB pour le mois Feb, pour la valeur Customer, Astrida. Dès lors que tous les mois ont été évalués pour Astrida, la séquence est répétée pour le deuxième client Betacab, et ainsi de suite.

Note InformationsLes résultats du tableau ne représentent qu'une liste partielle des données. Pour afficher les résultats complets, essayez l'exemple dans une application.

## Exemple - Utilisation de la fonction Above avec RangeAvg

[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)

#### Expression de graphique

Vue d'ensemble

La fonction Above peut s'utiliser comme donnée d'entrée dans les fonctions de plage. Cet exemple utilise la fonction dans RangeAvg.

Ouvrez l'éditeur de chargement de données et ajoutez le script de chargement ci-dessous à une nouvelle section.

Le script de chargement contient :

* Trois tables de données appelées Monthnames, Sales2013 et Product.

Script de chargement

```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];

Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');

Product:
LOAD * inline [
Customer|Product|OrderNumber|UnitSales|UnitPrice
Astrida|AA|1|4|16
Astrida|AA|7|10|15
Astrida|BB|4|9|9
Betacab|CC|6|5|10
Betacab|AA|5|2|20
Betacab|BB||| 25
Canutility|AA|||15
Canutility|CC| ||19
Divadip|CC|2|4|16
Divadip|DD|3|1|25
] (delimiter is '|');
```

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ce champ comme dimension :

* Customer

Créez la mesure suivante :

* =RangeAvg (Above(Sum(Sales),1,3))

Tableau de résultats\*

| Customer | RangeAvg (Above(Sum(Sales),1,3)) |
| --- | --- |
| Totals | - |
| Astrida | - |
| Betacab | 587 |
| Canutility | 563 |
| Divadip | 603 |

Dans les arguments de la fonction Above, offset est défini sur 1 et count est défini sur 3. La fonction recherche les résultats de l'expression Sum(Sales) sur les trois lignes situées immédiatement au-dessus de la ligne active dans le segment de colonne (lorsqu'il y a une ligne). Ces trois valeurs sont utilisées comme données d'entrée dans la fonction RangeAvg, qui calcule la moyenne des valeurs de la plage de nombres fournie.

## En savoir plus

* [Below - fonction de graphique](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
* [Bottom - fonction de graphique](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
* [Top - fonction de graphique](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/top.htm)
* [RangeAvg Fonction de script et de graphique](https://help.qlik.com/fr-FR/cloud-services/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/rangeavg.htm)