# autonumberhash256 Función de script

Esta función de script calcula un hash de 256 bits de los valores de entrada combinados de la expresión y devuelve un único entero por cada valor de resumen diferente encontrado durante la ejecución de script. Esta función se puede utilizar por ej. para crear un representación compacta de memoria de una clave compleja.

Nota informativaSolo puede conectar las claves de autonumberhash256 que se hayan generado en la misma carga de datos, ya que el entero se genera de acuerdo con el orden en que se lee la tabla. Si necesita usar claves que sean persistentes entre las cargas de datos, independientemente de la clasificación de datos de origen, debe usar el hash128, hash160 o las funciones hash256.

Sintaxis:

autonumberhash256(expression {, expression})

Ejemplo: Crear una clave compuesta

En este ejemplo, creamos una clave compuesta usando la función autonumberhash256 para conservar la memoria. El ejemplo es breve con fines de demostración, pero sería significativo en una tabla con un número elevado de filas.

Tabla de ejemplo

| Region | Year | Month | Sales |
| --- | --- | --- | --- |
| North | 2014 | May | 245 |
| North | 2014 | May | 347 |
| North | 2014 | June | 127 |
| South | 2014 | June | 645 |
| South | 2013 | May | 367 |
| South | 2013 | May | 221 |

Los datos fuente se cargan mediante Datos Inline. Luego agregamos un load precedente que crea una clave compuesta desde los campos Region, Year y Month.

```
RegionSales:
LOAD *,
AutoNumberHash256(Region, Year, Month) as RYMkey;

LOAD * INLINE
[ Region, Year, Month, Sales
North,	2014,	May,	245
North,	2014,	May,	347
North,	2014,	June,	127
South,	2014,	June,	645
South,	2013,	May, 367
South,	2013,	May,	221
];
```

La tabla resultante tiene el siguiente aspecto:

Tabla de resultados

| Region | Year | Month | Sales | RYMkey |
| --- | --- | --- | --- | --- |
| North | 2014 | May | 245 | 1 |
| North | 2014 | May | 347 | 1 |
| North | 2014 | June | 127 | 2 |
| South | 2014 | June | 645 | 3 |
| South | 2013 | May | 367 | 4 |
| South | 2013 | May | 221 | 4 |

En este ejemplo, puede hacer referencia a RYMkey, por ejemplo 1, en lugar de hacer referencia a la cadena “North2014May” si desea enlazar a otra tabla.

Ahora cargaremos una tabla de costes fuente de un modo similar. Los campos Region, Year y Month se excluyen de la carga precedente para evitar crear una clave sintética, ya estamos creando una clave compuesta con la función autonumberhash256, vinculando las tablas.

```
RegionCosts:
LOAD Costs,
AutoNumberHash256(Region, Year, Month) as RYMkey;

LOAD * INLINE
[ Region, Year, Month, Costs
South,	2013,	May,	167
North,	2014,	May,	56
North,	2014,	June,	199
South,	2014,	June,	64
South,	2013,	May, 172
South,	2013,	May,	126
];
```

Ahora podemos agregar una visualización de tabla a una hoja y agregar los campos Region, Year y Month, así como las medidas de suma para las ventas y los costes. La tabla presentará el siguiente aspecto:

Tabla de resultados

| Region | Year | Month | Sum([Sales]) | Sum([Costs]) |
| --- | --- | --- | --- | --- |
| Totals | - | - | 1952 | 784 |
| North | 2014 | June | 127 | 199 |
| North | 2014 | May | 592 | 56 |
| South | 2014 | June | 645 | 64 |
| South | 2013 | May | 588 | 465 |

## Más información

* [autonumberhash128 Función de script](https://help.qlik.com/es-ES/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/CounterFunctions/autonumberhash128.htm)
* [autonumber Función de script](https://help.qlik.com/es-ES/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/CounterFunctions/autonumber.htm)