# Drop table
Se pueden desechar del modelo de datos (y, por tanto, de la memoria) una o varias tablas internas de Qlik Sense, en cualquier momento durante la ejecución del script mediante el uso de una sentencia drop table.Opcionalmente, utilice la variante drop mapping table para eliminar tablas de correspondencias —aquellas creadas con el prefijo Mapping—antes del final de la ejecución del script.
Sintaxis:
drop [mapping] table tablename {, tablename2 ...}
drop [mapping] tables tablename {, tablename2 ...}
Nota informativaLas formas drop table y drop tables se aceptan ambas.
Los elementos siguientes se perderán como resultado de esto:
* Las tabla(s) en sí.
* Todos los campos que no formen parte de las restantes tablas.
* Los valores de campo en los campos, los cuales vienen exclusivamente desde las tablas eliminadas.
[](https://help.qlik.com/en-US/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/drop-table.htm)
#### Ejemplos y resultados:
| Ejemplo | Resultado |
| --- | --- |
| ```
drop table Orders, Salesmen, T456a;
``` | Esta línea da como resultado que las tres tablas sean eliminadas de la memoria. |
| ```
Tab1:
Load * Inline [
Customer, Items, UnitPrice
Bob, 5, 1.50
];
Tab2:
LOAD Customer, Sum( Items * UnitPrice ) as Sales
resident Tab1
group by Customer;
drop table Tab1;
``` | Una vez creada la tabla Tab2, se elimina la tabla Tab1. |
| ```
// Load mapping table of country codes:
map1:
mapping LOAD *
Inline [
CCode, Country
Sw, Sweden
Dk, Denmark
No, Norway
] ;
// Load list of salesmen, mapping country code to country
// If the country code is not in the mapping table, put Rest of the world
Salespersons:
LOAD *,
ApplyMap('map1', CCode,'Rest of the world') As Country
Inline [
CCode, Salesperson
Sw, John
Sw, Mary
Sw, Per
Dk, Preben
Dk, Olle
No, Ole
Sf, Risttu] ;
// We don't need the CCode anymore
Drop Field 'CCode';
Drop Mapping Table map1;
Metrics:
Load * Inline [
Transaction ID, Sales Amount, Sales Cost, City, Customer ID
1000012, 4509.33, 1234.22, Oslo, 250v9849
1000013, 1043.21, 180.23, Gothenburg, 195d5930
1000014, 6038.35, 1400.10, Copenhagen, 195d5930
];
``` | Este ejemplo muestra cómo se puede usar la variante Drop mapping table. Se crea una tabla de correspondencia map1 y luego se usa en una sentencia LOAD posterior con la función ApplyMap. Después de usar la tabla de correspondencia, se elimina de la memoria, optimizando el uso de RAM para los datos que se cargarán en tablas posteriores de la ejecución del script.
En este caso, con solo unas pocas filas en la tabla de correspondencia, la optimización de RAM sería mínima. Sin embargo, para tablas de correspondencia grandes o al crear tablas de correspondencia dentro de bucles, el rendimiento se puede mejorar significativamente. |
## Más información
* [Rename table](https://help.qlik.com/es-ES/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/rename-table.htm)
* [Drop field](https://help.qlik.com/es-ES/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/drop-field.htm)
* [Drop](https://help.qlik.com/es-ES/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/Drop.htm)
* [Table/Tables](https://help.qlik.com/es-ES/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptRegularStatements/Table.htm)
* [Correspondencias](https://help.qlik.com/es-ES/cloud-services/Subsystems/Hub/Content/Sense_Hub/Scripting/ScriptPrefixes/Mapping.htm)