# Bottom - Diagrammfunktion
Bottom() interpretiert eine Formel in der letzten (untersten) Zeile eines Spaltenabschnitts in einer Tabelle. Die Zeile, für welche die Berechnung erfolgt, hängt vom Wert von offset ab; ist dieser vorhanden, wird standardmäßig die unterste Zeile verwendet. In Diagrammen erfolgt anders als in Tabellen die Berechnung für die letzte Zeile der aktuellen Spalte im entsprechenden Tabellendiagramm.
Syntax:
Bottom([TOTAL] expr [ , offset [,count ]])
Rückgabe Datentyp: dual
Argumente
| Argument | Beschreibung |
| --- | --- |
| expr | Die Formel oder das Feld mit den Daten, die gemessen werden sollen. |
| offset | Ist ein offset n größer als 1 angegeben, wird die Formel anhand der Werte von n Zeilen berechnet, die über der letzten Zeile liegen.
Bei einem negativen Startwert verhält sich die Funktion Bottom wie die Funktion Top mit dem entsprechenden positiven Startwert. |
| count | Ist ein dritter Parameter count größer als 1 angegeben, liefert die Funktion nicht einen einzelnen Wert, sondern eine Menge von count-Werten, berechnet anhand der letzten count-Zeilen des Spaltenabschnitts. In diesem Formular kann die Funktion als Argument für eine der speziellen Abschnittsfunktionen dienen. [Bereichsfunktionen](https://help.qlik.com/de-DE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/RangeFunctionsInCharts.htm) |
| TOTAL | Wenn das Diagramm nur eine Dimension hat oder die Formel mit dem Zusatz TOTAL als Argument versehen ist, entspricht der Spaltenabschnitt der gesamten Spalte.
[Definieren des Aggregierungsbereichs](https://help.qlik.com/de-DE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |
InformationshinweisEin Spaltenabschnitt ist als aufeinanderfolgende Teilmenge an Zellen definiert, welche dieselben Werte für die Dimensionen in der aktuellen Sortierreihenfolge besitzen. Inter-Record-Diagrammfunktionen werden im Spaltenabschnitt berechnet, wobei die rechts außen stehende Dimension im entsprechenden Tabellendiagramm ausgeschlossen wird. Befindet sich nur eine Dimension im Diagramm oder wird der Zusatz TOTAL angegeben, erfolgt die Berechnung über die gesamte Tabelle.
InformationshinweisHat das Diagramm dagegen mehrere vertikale Dimensionen, so umfasst der Spaltenabschnitt nur Zeilen, deren Werte in allen Dimensionen mit Ausnahme der in der Priorität der Sortierfolgen letzten Dimension übereinstimmen.
Beschränkungen:
* Die Rekursion liefert NULL.
* Das Sortieren nach y-Werten in Diagrammen oder nach Formelspalten in Tabellen ist nicht zulässig, wenn diese Diagrammfunktion in einer der Diagrammformeln verwendet wird. Diese Sortierungsoptionen werden daher automatisch deaktiviert. Wenn Sie diese Diagrammfunktion in einer Visualisierung oder Tabelle verwenden, wird die Sortierung der Visualisierung auf die sortierte Eingabe dieser Funktion zurückgesetzt.
Beispiel: Diagrammformeln
| Beispiel | Ergebnis |
| --- | --- |
| `Bottom( Sum(Sales) )` | Gibt den Wert von `Sales` für die letzte (unterste) Zeile eines Spaltensegments in einer Tabelle zurück. |
## Beispiel – Grundlegendes zu Bottom
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
#### Diagrammformel
Übersicht
Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.
Das Ladeskript umfasst:
* Datensatz, der in eine Datentabelle namens `Example` geladen wird
* Die folgenden Felder in der Datentabelle:
* `Year`
* `Sales`
Ladeskript
```
Example:
LOAD * INLINE [
Year, Sales
2019, 1000
2020, 1500
2021, 1200
2022, 1800
2023, 1700
];
```
Ergebnisse
Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie dieses Feld als Dimension hinzu:
* `Year`
Erstellen Sie die folgenden Kennzahlen:
* `=Sum(Sales)`, um den jährlichen Umsatz zu erhalten.
* `=Bottom(Sum(Sales))`, um die Umsatzwerte für das letzte Jahr zu ermitteln.
* `=Sum(Sales) - Bottom(Sum(Sales))`, um die Varianz zwischen dem `Sales`-Wert des aktuellen Jahres und dem Wert des letzten Jahres zu berechnen.
* `=Sum(Sales)+Bottom(Sum(Sales), 3)`, um die Summe der Umsatzwerte des aktuellen Jahres und des Werts des drittletzten Jahres zu berechnen.
* `=(Sales - Bottom(Sales)) / Bottom(Sales)`, um die Änderung an `Sales` als Verhältnis/Prozentsatz im Vergleich zum letzten Jahr zurückzugeben. Um diesen Wert als Prozentsatz anzuzeigen, wählen Sie unter Zahlenformat die Option Zahl > Standardformatierung > 12.34% aus.
Sortieren Sie die Tabelle nach der Dimension `Year` in aufsteigender Reihenfolge.
Ergebnistabelle
| Year | Sum(Sales) | Bottom(Sum(Sales)) | Sum(Sales) - Bottom(Sum(Sales)) | Sum(Sales)+Bottom(Sum(Sales), 3) | (Sales - Bottom(Sales)) / Bottom(Sales) |
| --- | --- | --- | --- | --- | --- |
| Totals | 7200 | 1700 | 5500 | 8400 | - |
| 2019 | 1000 | 1700 | -700 | 2200 | -41.18% |
| 2020 | 1500 | 1700 | -200 | 2700 | -11.76% |
| 2021 | 1200 | 1700 | -500 | 2400 | -29.41% |
| 2022 | 1800 | 1700 | 100 | 3000 | 5.88% |
| 2023 | 1700 | 1700 | 0 | 2900 | 0.00% |
Wenn Sie sich die Ergebnisse ansehen, können Sie die Werte von `Sales` im aktuellen Zeitraum mit dem letzten bzw. jüngsten Zeitraum vergleichen.
* Die Kennzahl `Sum(Sales) - Bottom(Sum(Sales))` gibt die Änderung an `Sales`-Werten bei Vergleich des aktuellen Zeitraums mit dem jüngsten Zeitraum zurück.
* Die Kennzahl `Sum(Sales)+Bottom(Sum(Sales), 3)` gibt die Summe von `Sales` für die aktuelle Zeile und den drittjüngsten Zeitraum an.
* Die Kennzahl `(Sales - Bottom(Sales)) / Bottom(Sales)` gibt die Änderung an `Sales` bei Vergleich mit dem jüngsten Zeitraum in Prozent zurück.
TipphinweisDiese Funktion kann auch in anderen Diagrammen als Tabellen wie zum Beispiel in Balkendiagrammen verwendet werden.
Gehen Sie folgendermaßen vor:
Erstellen Sie ein Balkendiagramm und fügen Sie das folgende Feld als Dimension hinzu:
* `Year`
Erstellen Sie die folgende Kennzahl:
* `=Sum(Sales) - Bottom(Sum(Sales))`, um die Umsatzvarianz zwischen dem aktuellen Zeitraum und dem jüngsten Zeitraum zu ermitteln.
Balkendiagramm mit Ergebnissen für die Funktion Bottom
Balkendiagramm mit Ergebnissen für die Funktion Bottom
Balkendiagramm mit Ergebnissen für die Funktion BottomBottom 
Die Verwendung der Funktion `Bottom` in einem Balkendiagramm bietet einen visuellen Vergleich der Varianz zwischen den Umsätzen des aktuellen Zeitraums und des jüngsten Zeitraums.
## Beispiel – Szenario für „Bottom“
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
#### Diagrammformel
Übersicht
Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.
Das Ladeskript umfasst:
* Datensatz, der in eine Datentabelle namens `Example` geladen wird
* Die folgenden Felder in der Datentabelle:
* `OrderID`
* `Product`
* `SalesValue`
* `OrderDate`
Ladeskript
```
Example:
LOAD * INLINE [
OrderID, Product, SalesValue, OrderDate
1, "Product A", 500, '2023-01-10'
2, "Product B", 300, '2023-01-15'
3, "Product C", 450, '2023-02-01'
4, "Product D", 700, '2023-02-20'
5, "Product E", 350, '2023-03-05'
];
```
Ergebnisse
Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie dieses Feld als Dimension hinzu:
* `Product`
Erstellen Sie die folgenden Kennzahlen:
* `=RangeAvg (Bottom(Sum(SalesValue),1,3))`, um den Durchschnitt der 3 jüngsten Zeilen zurückzugeben.
* `=Sum(SalesValue) - RangeAvg (Bottom(Sum(SalesValue),1,3))`, um die Varianz zwischen der aktuellen Zeile und dem Durchschnitt der jüngsten 3 Zeilen zu berechnen.
* `=Sum(SalesValue)` um den Gesamtwert von `SalesValue` für die aktuelle Zeile zu berechnen.
Ergebnistabelle
| Product | RangeAvg (Bottom(Sum(SalesValue),1,3)) | Sum(SalesValue) - RangeAvg (Bottom(Sum(SalesValue),1,3)) | Sum(SalesValue) |
| --- | --- | --- | --- |
| Totals | 500 | 1800 | 2300 |
| 2019 | 500 | 0 | 500 |
| 2020 | 500 | -200 | 300 |
| 2021 | 500 | -50 | 450 |
| 2022 | 500 | 200 | 700 |
| 2023 | 500 | -150 | 350 |
Die Ergebnisse zeigen, wie Sie eine Kombination aus der Funktion `RangeSum` und der Funktion `Bottom` verwenden können, um Umsatzwerte zu analysieren und zu vergleichen.
## Beispiel – Diagrammformel, die Bottom verwendet
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
#### Diagrammformel
Übersicht
Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.
Das Ladeskript umfasst:
* Zwei Datentabellen namens `Monthnames` und `Sales2013`.
Ladeskript
```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];
Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');
```
Ergebnisse
Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie dieses Feld als Dimension hinzu:
* `Customer`
Erstellen Sie die folgenden Kennzahlen:
* `=Sum(Sales)`, um die Summe der Umsätze zu berechnen.
* `=Bottom(Sum(Sales))`, um die Summe der Umsätze für den `Customer` in der untersten Zeile anzuzeigen.
* `=Sum(Sales)+Bottom(Sum(Sales))`, um den Wert `Sum(Sales)` des aktuellen `Customer` zum Wert des `Customer` in der unteren Zeile zu addieren.
* `=Sum(Sales)+Bottom(Sum(Sales), 3)`, um den Wert `Sum(Sales)` des aktuellen `Customer` zum Wert des `Customer` in der drittuntersten Zeile zu addieren.
Ergebnistabelle
| Customer | Sum(Sales) | Bottom(Sum(Sales)) | Sum(Sales)+Bottom(Sum(Sales)) | Sum(Sales)+Bottom(Sum(Sales), 3) |
| --- | --- | --- | --- | --- |
| Totals | 2566 | 757 | 3323 | 3105 |
| Astrida | 587 | 757 | 1344 | 1126 |
| Betacab | 539 | 757 | 1296 | 1078 |
| Canutilty | 683 | 757 | 1440 | 1222 |
| Divadip | 757 | 757 | 1514 | 1296 |
Die Kennzahl `Bottom(Sum(Sales))` gibt `757` für alle Zeilen zurück, weil dies der Wert für die untere Zeile ist: `Divadip`.
Für die Kennzahl `Sum(Sales)+Bottom(Sum(Sales))` gibt die Zeile `Astrida` den Wert `1344` zurück, der das Ergebnis der Addition des Werts von `Sum(Sales)` für `Astrida` und `Divadip`, des `Customer` in der untersten Zeile, ist.
Für die Kennzahl `Sum(Sales)+Bottom(Sum(Sales), 3)` ist das Argument `offset` auf `3` festgelegt. Die Formel addiert den Wert `Sum(Sales)` für die aktuelle Zeile und die dritte Zeile von unten, `Betacab`. Für den Kunden `Astrida` wird zum Beispiel der Wert `1126` zurückgegeben. Dies ist das Ergebnis der Addition des Werts `Sum(Sales)` für `Astrida` und des Werts `SumSales` für `Betacab` (`587`+`539`).
## Weitere Informationen
* [Top - Diagrammfunktion](https://help.qlik.com/de-DE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/top.htm)