# Below - Diagrammfunktion
Below() interpretiert eine Formel in einer Zeile unter der aktuellen Zeile innerhalb eines Spaltenabschnitts in einer Tabelle. Die Zeile, für welche die Berechnung erfolgt, hängt vom Wert von offset ab; ist dieser vorhanden, wird standardmäßig die Zeile direkt darunter verwendet. In Diagrammen wird anders als in Tabellen mit Below() die Zeile unter der aktuellen Spalte im entsprechenden Tabellendiagramm interpretiert.
Syntax:
Below([TOTAL] expr [ , offset [,count ]])
Rückgabe Datentyp: dual
Argumente
| Argument | Beschreibung |
| --- | --- |
| expr | Die Formel oder das Feld mit den Daten, die gemessen werden sollen. |
| offset | Ist ein offset n größer als 1 angegeben, wird die Formel anhand der Werte von n Zeilen unter der aktuellen Zeile ausgewertet.
Bei einem Startwert von "0" wird die Formel anhand der Werte der aktuellen Zeile berechnet.
Bei einem negativen Startwert verhält sich die Funktion Below wie die Funktion Above mit dem entsprechenden positiven Startwert. |
| count | Ist ein dritter Parameter count größer als 1 angegeben, liefert die Funktion eine Menge von count-Werten, berechnet anhand der count-Zeilen unterhalb bis einschließlich der aktuellen Zeile. In diesem Formular kann die Funktion als Argument für eine der speziellen Abschnittsfunktionen dienen. [Bereichsfunktionen](https://help.qlik.com/de-DE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/RangeFunctionsInCharts.htm) |
| TOTAL | Wenn das Diagramm nur eine Dimension hat oder die Formel mit dem Zusatz TOTAL als Argument versehen ist, entspricht der Spaltenabschnitt der gesamten Spalte.
[Definieren des Aggregierungsbereichs](https://help.qlik.com/de-DE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |
In der letzten Zeile eines Spaltenabschnitts ist das Ergebnis NULL, da keine darauffolgende Zeile existiert.
InformationshinweisEin Spaltenabschnitt ist als aufeinanderfolgende Teilmenge an Zellen definiert, welche dieselben Werte für die Dimensionen in der aktuellen Sortierreihenfolge besitzen. Inter-Record-Diagrammfunktionen werden im Spaltenabschnitt berechnet, wobei die rechts außen stehende Dimension im entsprechenden Tabellendiagramm ausgeschlossen wird. Befindet sich nur eine Dimension im Diagramm oder wird der Zusatz TOTAL angegeben, erfolgt die Berechnung über die gesamte Tabelle.
InformationshinweisHat das Diagramm dagegen mehrere vertikale Dimensionen, so umfasst der Spaltenabschnitt nur Zeilen, deren Werte in allen Dimensionen mit Ausnahme der in der Priorität der Sortierfolgen letzten Dimension übereinstimmen.
Beschränkungen:
* Die Rekursion liefert NULL.
* Das Sortieren nach y-Werten in Diagrammen oder nach Formelspalten in Tabellen ist nicht zulässig, wenn diese Diagrammfunktion in einer der Diagrammformeln verwendet wird. Diese Sortierungsoptionen werden daher automatisch deaktiviert. Wenn Sie diese Diagrammfunktion in einer Visualisierung oder Tabelle verwenden, wird die Sortierung der Visualisierung auf die sortierte Eingabe dieser Funktion zurückgesetzt.
Beispiel: Diagrammformeln
| Beispiel | Ergebnis |
| --- | --- |
| `Below( Sum(Sales) )` | Gibt den Wert von `Sales` für die Zeile unterhalb der aktuellen Zeile zurück. |
## Beispiel – Grundlegendes zu Below
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Diagrammformel
Übersicht
Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.
Das Ladeskript umfasst:
* Datensatz, der in eine Datentabelle namens `Example` geladen wird
* Die folgenden Felder in der Datentabelle:
* `Year`
* `Sales`
Ladeskript
```
Example:
LOAD * INLINE [
Year, Sales
2019, 1000
2020, 1500
2021, 1200
2022, 1800
2023, 1700
];
```
Ergebnisse
Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie dieses Feld als Dimension hinzu:
* `Year`
Erstellen Sie die folgenden Kennzahlen:
* `=Sum(Sales)`, um den jährlichen Umsatz zu erhalten.
* `=Below(Sum(Sales))`, um den Umsatzwert für das nächste Jahr zu ermitteln.
* `=Sum(Sales) - Below(Sum(Sales))`, um die Varianz zwischen dem `Sales`-Wert des aktuellen Jahres und dem Wert des nächsten Jahres zu berechnen.
* `=RangeSum(Below(Sales, 1, 2))`, um eine rollierende Zweijahresaggregierung der Umsätze der nächsten zwei Jahre zu zeigen.
* `=(Sales - Below(Sales)) / Below(Sales)`, um die Änderung an `Sales` als Verhältnis/Prozentsatz zurückzugeben. Um diesen Wert als Prozentsatz anzuzeigen, wählen Sie unter Zahlenformat die Option Zahl > Standardformatierung > 12.34% aus.
Ergebnistabelle
| Year | Sum(Sales) | Below(Sum(Sales)) | Sum(Sales) - Below(Sum(Sales)) | RangeSum(Below(Sales, 1, 2) | (Sales - Below(Sales)) / Below(Sales) |
| --- | --- | --- | --- | --- | --- |
| Totals | 7200 | - | - | 0 | - |
| 2019 | 1000 | 1500 | -500 | 2700 | -33.33% |
| 2020 | 1500 | 1200 | 300 | 3000 | 25.00% |
| 2021 | 1200 | 1800 | -600 | 3500 | -33.00% |
| 2022 | 1800 | 1700 | 100 | 1700 | 5.88% |
| 2023 | 1700 | - | - | 0 | - |
Wenn Sie sich die Ergebnisse ansehen, können Sie die Werte von `Sales` im aktuellen Zeitraum mit dem nächsten Zeitraum vergleichen.
* Die Kennzahl `Sum(Sales) - Below(Sum(Sales))` gibt die Änderung an `Sales`-Werten bei Vergleich des aktuellen Zeitraums mit dem nächsten Zeitraum zurück.
* Die Kennzahl `RangeSum(Below(Sales, 1, 2))` gibt die Summe der beiden nächsten Werte von `Sales` zurück.
* Die Kennzahl `(Sales - Below(Sales)) / Below(Sales)` gibt die Änderung an `Sales` bei Vergleich mit dem nächsten Zeitraum in Prozent zurück.
TipphinweisDiese Funktion kann auch in anderen Diagrammen als Tabellen wie zum Beispiel in Balkendiagrammen verwendet werden.
Gehen Sie folgendermaßen vor:
Erstellen Sie ein Balkendiagramm und fügen Sie das folgende Feld als Dimension hinzu:
* `Year`
Erstellen Sie die folgende Kennzahl:
* `=Sum(Sales) - Below(Sum(Sales))`, um die Varianz von Jahr zu Jahr zu ermitteln.
Balkendiagramm mit Ergebnissen für die Funktion Below
Balkendiagramm mit Ergebnissen für die Funktion Below
Balkendiagramm mit Ergebnissen für die Funktion BelowBelow 
Die Verwendung der Funktion `Below` in einem Balkendiagramm bietet einen visuellen Vergleich der Varianz zwischen den Umsätzen des aktuellen Zeitraums und des nächsten Zeitraums.
## Beispiel – Szenario für „Below“
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Diagrammformel
Übersicht
Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.
Das Ladeskript umfasst:
* Datensatz, der in eine Datentabelle namens `Example` geladen wird
* Die folgenden Felder in der Datentabelle:
* `SalesYear`
* `SalesAmount`
Ladeskript
```
Example:
LOAD * INLINE [
SalesYear, SalesAmount
2019, 500
2020, 800
2021, 400
2022, 700
2023, 600
];
```
Ergebnisse
Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie dieses Feld als Dimension hinzu:
* `SalesYear`
Erstellen Sie die folgenden Kennzahlen:
* `=Sum(SalesAmount)`, um die Umsätze zu aggregieren.
* `=RangeSum(Below(SalesAmount, 0, NoOfRows() - RowNo()))`, um einen zusammenfassenden Gesamtwert der `SalesAmount`-Werte zu berechnen.
Ergebnistabelle
| SalesYear | Sum(SalesAmount) | RangeSum(Below(SalesAmount, 0, NoOfRows() - RowNo())) |
| --- | --- | --- |
| Totals | 3000 | 0 |
| 2019 | 500 | 2400 |
| 2020 | 800 | 1900 |
| 2021 | 400 | 1100 |
| 2022 | 700 | 700 |
| 2023 | 600 | 0 |
Die Ergebnisse zeigen, wie Sie eine Kombination aus der Funktion `RangeSum` und der Funktion `Below` verwenden können, um einen kumulierten zusammenfassenden Gesamtwert zu erstellen.
TipphinweisDiese Funktion kann auch in anderen Diagrammen als Tabellen wie zum Beispiel in Balkendiagrammen verwendet werden.
Gehen Sie folgendermaßen vor:
Erstellen Sie ein Balkendiagramm und fügen Sie das folgende Feld als Dimension hinzu:
* `SalesYear`
Erstellen Sie die folgende Kennzahl:
* `=RangeSum(Below(SalesAmount, 0, NoOfRows() - RowNo()))`, um den kumulierten zusammenfassenden Umsatzwert zurückzugeben.
Balkendiagramm mit dem kumulierten zusammenfassenden Umsatzwert nach Jahr
Balkendiagramm mit dem kumulierten zusammenfassenden Umsatzwert nach Jahr
Balkendiagramm mit dem kumulierten zusammenfassenden Umsatzwert nach Jahr 
Wenn Sie die Funktion `Below` in Kombination mit `RangeSum` in einem Balkendiagramm verwenden, erhalten Sie eine visuelle Darstellung der kumulierten zusammenfassenden Umsatzwerte.
## Beispiel – Diagrammformel, die Below verwendet
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Diagrammformel
Übersicht
Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.
Das Ladeskript umfasst:
* Zwei Datentabellen namens `Monthnames` und `Sales2013`.
Ladeskript
```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];
Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');
```
Ergebnisse
Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie dieses Feld als Dimension hinzu:
* `Customer`
Erstellen Sie die folgenden Kennzahlen:
* `=Sum(Sales)`, um die Summe der Umsätze zu berechnen.
* `=Below(Sum(Sales))`, um die Summe der Umsätze in der vorherigen Zeile anzuzeigen.
* `=Sum(Sales)+Below(Sum(Sales))`, um die Summe der Umsatzwerte mit der Summe der Umsätze für die Kundenzeile unter der aktuellen Zeile zu summieren.
* `=Sum(Sales)+Below(Sum(Sales), 3)`, um den Wert von `Sum(Sales)` für den aktuellen `Customer` zum Wert für den `Customer` drei Zeilen darunter zu summieren.
* `=If(Sum(Sales)>Below(Sum(Sales)), 'Higher')`, um die Bezeichnung „`Higher`“ für Kunden hinzuzufügen, deren `Sum(Sales)`- Ergebnisse größer als die `Sum(Sales)` des Kunden in der Zeile darunter sind.
Ergebnistabelle
| Customer | Sum(Sales) | Below(Sum(Sales)) | Sum(Sales)+Below(Sum(Sales)) | Sum(Sales)+Below(Sum(Sales), 3) | If(Sum(Sales)>Below(Sum(Sales)), 'Higher') |
| --- | --- | --- | --- | --- | --- |
| Totals | 2566 | - | - | - | - |
| Astrida | 587 | 539 | 1126 | 1334 | Higher |
| Betacab | 539 | 683 | 1222 | - | - |
| Canutility | 683 | 757 | 1440 | - | - |
| Divadip | 757 | - | - | - | - |
Bei Diagrammen mit mehr als einer Dimension hängt das Ergebnis der Formeln, welche die Funktionen `Above`, `Below`, `Top` und `Bottom` beinhalten, von der Reihenfolge ab, in der die Spaltendimensionen von Qlik Sense sortiert werden. Qlik Sense evaluiert die Funktionen auf Grundlage der Spaltensegmente, die sich aus der zuletzt sortierten Dimension ergeben haben. Die Sortierreihenfolge der Spalten kann im Eigenschaftsfenster unter Sortierung festgelegt werden und stimmt nicht zwangsläufig mit der Reihenfolge überein, in der die Spalten in der Tabelle angezeigt werden. Ein Beispiel für die Verwendung der Sortierreihenfolge finden Sie unter [Beispiel – Szenario für „Above“ basierend auf der Sortierreihenfolge](https://help.qlik.com/de-DE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm#Example).
Die Kennzahl `Below(Sum(Sales))` gibt NULL für den Kunden `Divadip` zurück, da sich keine Zeile darunter befindet. Das Ergebnis für die Zeile `Canutility` zeigt den Wert von `Sum(Sales)` für `Divadip` an. Das Ergebnis für `Betacab` zeigt den Wert für `Sum(Sales)` für `Canutility`, und so weiter.
Für die Kennzahl `Sum(Sales)+Below(Sum(Sales))` liefert die Zeile für `Astrida` das Ergebnis der Addition der Werte von `Sum(Sales)` für die Zeilen `Betacab` + `Astrida` (`539+587`). Das Ergebnis für die Zeile `Betacab` zeigt das Ergebnis der Addition von `Sum(Sales)`-Werten für `Canutility` + `Betacab` (`539+683`).
Die Kennzahl `Sum(Sales)+Below(Sum(Sales), 3)` verfügt über das Argument `offset` mit der Einstellung `3` und wählt den Wert drei Zeilen unter der aktuellen Zeile aus. Sie fügt den Wert `Sum(Sales)` für die aktuelle Auswahl von `Customer` zum Wert des Felds `Customer` drei Zeilen darunter hinzu. Die Werte der untersten drei Zeilen `Customer` sind NULL-Werte.
Die Kennzahl `IF(Sum(Sales)>Below(Sum(Sales)), 'Higher')` gibt den Wert `Higher` für den Kunden `Astrida` zurück, da seine Umsatzergebnisse höher sind als die Summe der Umsätze für den Kunden in der Zeile darunter, `Betacab`.
TipphinweisDiese Funktion kann auch in anderen Diagrammen als Tabellen wie zum Beispiel in Balkendiagrammen verwendet werden.
TipphinweisBei anderen Diagrammtypen wandeln Sie das Diagramm in ein entsprechendes Tabellendiagramm um, damit Sie einfach nachvollziehen können, auf welche Zeile sich die Funktion bezieht.
## Beispiel – Verwenden der Funktion Below mit RangeAvg
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/below.htm)
#### Diagrammformel
Übersicht
Die Funktion Below kann als Input für die Abschnittsfunktionen verwendet werden. In diesem Beispiel wird die Funktion in einem RangeAvg verwendet.
Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.
Das Ladeskript umfasst:
* Zwei Datentabellen namens Monthnames und Sales2013.
Ladeskript
```
Monthnames:
LOAD *, Dual(MonthText,MonthNumber) as Month INLINE [
MonthText, MonthNumber
Jan, 1
Feb, 2
Mar, 3
Apr, 4
May, 5
Jun, 6
Jul, 7
Aug, 8
Sep, 9
Oct, 10
Nov, 11
Dec, 12
];
Sales2013:
Crosstable (MonthText, Sales) LOAD * inline [
Customer|Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec
Astrida|46|60|70|13|78|20|45|65|78|12|78|22
Betacab|65|56|22|79|12|56|45|24|32|78|55|15
Canutility|77|68|34|91|24|68|57|36|44|90|67|27
Divadip|57|36|44|90|67|27|57|68|47|90|80|94
] (delimiter is '|');
```
Ergebnisse
Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie dieses Feld als Dimension hinzu:
* Customer
Erstellen Sie die folgende Kennzahl:
* =RangeAvg (Below(Sum(Sales),1,3))
Ergebnistabelle
| Customer | RangeAvg (Below(Sum(Sales),1,3)) |
| --- | --- |
| Totals | - |
| Astrida | 660 |
| Betacab | 720 |
| Canutility | 757 |
| Divadip | - |
In den Argumenten für die Funktion Below wird offset auf 1 und count auf 3 festgelegt. Die Funktion ermittelt die Ergebnisse der Formel Sum(Sales) für die drei Zeilen direkt unter der aktuellen Zeile im Spaltenabschnitt (sofern eine Zeile vorhanden ist). Diese drei Werte werden als Input für die Funktion RangeAvg verwendet, die den Durchschnitt der Werte in der gelieferten Menge an Zahlen ermittelt.
## Weitere Informationen
* [Above - Diagrammfunktion](https://help.qlik.com/de-DE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/above.htm)
* [Bottom - Diagrammfunktion](https://help.qlik.com/de-DE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/bottom.htm)
* [Top - Diagrammfunktion](https://help.qlik.com/de-DE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/InterRecordFunctions/top.htm)
* [RangeAvg - Skript- und Diagrammfunktion](https://help.qlik.com/de-DE/sense/November2025/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/rangeavg.htm)