# Aufrufen von Variablen mit Formeln

Man kann auf das Definieren und Initialisieren einer Variable verzichten, wenn man eine Formel aufrufen will.

Der Inhalt der Klammern muss mit einem Gleichheitszeichen beginnen:

`$(=expression)`

Die Formel wird berechnet und das Ergebnis wie ein Wert einer Variablen behandelt. Beispiel:

```
// returns a string with the current year
$(=Year(Today())); 
```

```
// returns the year before the selected one
$(=Only(Year)-1);
```

## Beispiel: Wählen Sie eine Kennzahl aus, indem Sie die Kennzahl in einer Diagrammformel referenzieren.

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/dollar-sign-expansion-using-expression.htm)

#### Beispiel: Ladeskript

Ladeskript

Laden Sie die folgenden Daten als Inline-Ladevorgang in den Dateneditor:

```
// Load string “=MinString(Measure)” into variable VSelectMeasure
Let vSelectMeasure = '=MinString(Measure)';
MyTable1: // Create table and load values for Dim and Sales
Load * inline [
Dim, Sales
A, 150
A, 200
B, 240
B, 230
C, 410
C, 330 ];                      
 
 
MyTable2: // Create table and load aggregations as field values for Measure
Load * Inline [
Measure
avg(Sales)
sum(Sales)
count(distinct Dim)];
```

Weitere Informationen über Inline-Ladevorgänge finden Sie unter [Verwenden von Inline-Ladevorgängen zum Laden von Daten](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/inline-loads-qs.htm).

Erläuterung

Das Skript ermöglicht Ihnen die Auswahl einer Kennzahl, indem die Kennzahl in einer Diagrammformel referenziert wird. Die Diagrammformel enthält die Variablenerweiterung `$(=MinString(Measure))`. `MinString()` findet Stringwerte in der Formel und gibt den ersten Textwert in alphabetischer Sortierung zurück, in diesem Fall `avg(Sales)`. Damit kann interaktiv entschieden (und ausgewählt) werden, welche Formel in einer Visualisierung verwendet werden soll, ohne auf die Eigenschaften des Objekts zuzugreifen und diese zu bearbeiten.

Ausgabe

Erstellen Sie die folgende Tabelle in Qlik Sense, indem Sie folgende Elemente verwenden:

* Dimension: `Dim`

* Kennzahl:

  * `='$(vSelectMeasure)'`

  * `=$(=MinString(Measure))`

  * `Avg(Sales)`

Tabelle – Aufrufen von Variablen mit Formeln

| Dim | ='$(vSelectMeasure)' | =$(=MinString(Measure)) | Avg(Sales) |
| --- | --- | --- | --- |
| Summen | - | 260 | 260 |
| A | avg(Sales) | 175 | 175 |
| B | avg(Sales) | 235 | 235 |
| C | avg(Sales) | 370 | 370 |

## Beispiel: Kontingent zwischen zwei Dimensionen berechnen

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/dollar-sign-expansion-using-expression.htm)

#### Beispiel: Ladeskript

Ladeskript

Laden Sie die folgenden Daten als Inline-Ladevorgang in den Dateneditor:

```
Let vDivision = '=MinString(Numerator) / MinString(Denominator)';
Load recno() as Numerator autogenerate 100;
Load recno() as Denominator autogenerate 100;
```

Erläuterung

Dieses Skript generiert ein Paar von Feldern, die je 100 Werte enthalten und die als Zähler und Nenner in einer Berechnung des Kontingents zwischen den beiden fungieren. Die Diagrammkennzahl enthält die Variablenerweiterung ='$( vDivision )', die es ermöglicht, interaktiv zu entscheiden (und auszuwählen), welches Kontingent berechnet werden soll.

Ausgabe

Erstellen Sie die folgende Tabelle in Qlik Sense, indem Sie folgende Elemente verwenden:

* Dimension:

  * Numerator

  * Denominator

* Kennzahl: ='$(vDivision)'

Das sich ergebende Kontingent (Gesamtsumme) ist von den ausgewählten Werten in den Feldern betroffen. Numerator (=5) und Denominator (=3) werden mit jeder neuen Auswahl in einem der Felder neu berechnet.

Tabelle – Aufrufen von Variablen als Formel

| Zähler | Nenner | ='$(vDivision)' |
| --- | --- | --- |
| Summen | - | 1,6666666666667 |
| 5 | 3 | 1,6666666666667 |

## Skript-Dateien

Skript-Dateien lassen sich als Variablen einbinden. Die Syntax lautet:

$(include=filename)

Diese Syntax wird bei der Ausführung des Skripts durch den Text nach dem Gleichheitszeichen ersetzt. Dies ist für in Textdateien ausgelagerte Skripts oder Skriptteile sinnvoll.

Weitere Informationen finden Sie unter [Include](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Scripting/SystemVariables/Include.htm).

## Dollarzeichenerweiterungen und alternative Zustände

Eine Dollarzeichenerweiterung erkennt normalerweise keine alternativen Zustände. Wenn jedoch die Dollarzeichenerweiterung eine Formel enthält, wird diese in dem Zustand ausgewertet, der für das Objekt relevant ist, in dem die Dollarzeichenerweiterung stattfindet.

Hier ein Beispiel:

```
$(=Sum(Amount))
```

Die Berechnung gibt die Summe des Betrags basierend auf der Auswahl im Zustand des Objekts zurück.

## Interaktion zwischen Dollarzeichen-Erweiterungen und äußeren Auswahlformeln

Wenn Sie Dollarzeichen-Erweiterungen mit äußeren Auswahlformeln kombinieren, gilt eine bestimmte Auswertungsreihenfolge. Weitere Einzelheiten finden Sie unter [Äußere Auswahlformeln mit Dollarzeichen-Erweiterungen](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/outer-set-expression-dollar-sign-expansion.htm).