# Timestamp#Skript- und Diagrammfunktion
Timestamp#() evaluiert eine Formel als Daten- und Zeitwert und verwendet dafür, wenn kein Formatcode zur Verfügung steht, das vorgegebene Zeitstempelformat des Datenladeskripts oder des Betriebssystems.
Syntax:
timestamp#(text[, format])
Rückgabe Datentyp: dual
Argumente
| Argument | Beschreibung |
| --- | --- |
| text | Der zu evaluierende Textstring. |
| format | String, der das Format beschreibt, das zur Interpretation des Textzeichenstrings verwendet werden soll. Wenn nicht angegeben, werden das kurze Datumsformat, das Zeitformat und das Dezimaltrennzeichen wie im Betriebssystem festgelegt verwendet. ISO 8601 wird für Zeitstempel unterstützt.
Die Funktion `Timestamp#` unterstützt viele Formatoptionen für verschiedene Uhrzeitstrukturen, zum Beispiel:
`DD/MM/YYYY`: Konzentriert sich nur auf das Datum (zum Beispiel: `15/11/2024`).
`YYYY-MM-DD hh:mm:ss`: Zeigt den vollständigen Zeitstempel an (zum Beispiel: `2024-11-15 13:30:45`).
`MMM DD, YYYY`: Zeigt eine Kurzversion des Monats und des ganzen Jahres an (zum Beispiel: `Nov 15, 2024`).
`hh:mm:ss TT`: Zeigt nur die Uhrzeit im 12-Stunden-Format an (zum Beispiel: `01:30:45 PM`)
`HH:mm:ss`: Zeigt die Uhrzeit im 24-Stunden-Format an (zum Beispiel: `13:30:45`)
`wwww, MMM DD YYYY`: Zeigt den vollen Wochentag und das Datum an (zum Beispiel: `Friday, Nov 15 2024`)
`YYYY-MM-DD hh:mm:ss.fff`: Enthält Millisekunden (zum Beispiel: `2024-11-15 13:30:45.123`).
[Beschreibungen für Zahlen- und Uhrzeitformate](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/Introduction/conventions-number-time-formats.htm) |
Beispiel: Diagrammformeln
| Beispiel | Ergebnis |
| --- | --- |
| `Timestamp#('12-03-2023 10:25:30', 'DD-MM-YYYY hh:mm:ss')` | Liefert `12-03-2023 10:25:30` |
| `Timestamp#('2023/03/15 13:45', 'YYYY/MM/DD hh:mm')` | Liefert `2023/03/15 13:45` |
## Beispiel – Grundlegendes zu „Timestamp#“
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/InterpretationFunctions/timestamp_hash.htm)
#### Ladeskript
Übersicht
Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.
Das Ladeskript umfasst:
* Datensatz, der in eine Datentabelle namens `Example` geladen wird
* Die folgenden Felder in einer Datentabelle:
* `InputString`
* Ein vorangehender Load-Befehl, der die Funktion `Timestamp#` verwendet, um die Formel als Datums- und Uhrzeitwert zu behandeln. Wenn er ausgeführt wird, erstellt er ein zusätzliches Feld namens `TimeStamp_InputString`.
Ladeskript
```
SET DateFormat='M/D/YYYY'
Example:
Load *,
Timestamp(Timestamp#(InputString)) as TimeStamp_InputString;
LOAD * INLINE [
InputString
2015-09-15T12:13:14
1952-10-16T13:14:00+0200
1109-03-01T14:15
];
```
Ergebnisse
Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie die folgenden Felder als Dimensionen hinzu:
* ` InputString
`
* `TimeStamp_InputString`
Ergebnistabelle
| InputString | TimeStamp\_InputString |
| --- | --- |
| 1109-03-01T14:15 | 3/1/1109 2:15:00 PM |
| 1952-10-16T13:14:00+0200 | 10/16/1952 11:14:00 AM |
| 2015-09-15T12:13:14 | 9/15/2015 12:13:14 PM |
In diesem Beispiel sehen Sie, wie String-Werte mit der Funktion `Timestamp#` als Zeitstempel ausgewertet werden können.
## Beispiel – Szenario für „Timestamp#“
[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/InterpretationFunctions/timestamp_hash.htm)
#### Ladeskript
Übersicht
Die Daten aus einem Ereignisprotokoll enthalten ein Zeitstempelformat, das Sie verwenden möchten.
Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.
Das Ladeskript umfasst:
* Datensatz, der in eine Datentabelle namens `Example` geladen wird
* Die folgenden Felder in der Datentabelle:
* `Event`
* `EventDateTime`
* Ein vorangehender Load-Befehl, der die Funktion `Timestamp#` verwendet, um die Werte im Feld `EventDateTime` in ein Datums- und Uhrzeitformat zu konvertieren, das vom System verstanden werden kann. Wenn er ausgeführt wird, erstellt er ein zusätzliches Feld namens `EventTimestamp`.
Ladeskript
```
SET TimestampFormat='M/D/YYYY h:mm:ss[.fff] TT';
Example:
LOAD
Event,
EventDateTime,
Timestamp#(EventDateTime, 'DD-MM-YYYY hh:mm:ss') AS EventTimestamp
INLINE [
Event, EventDateTime
"Login", "12-03-2023 10:25:30"
"Logout", "12-03-2023 12:45:10"
"Login", "13-03-2023 09:10:15"
"Logout", "13-03-2023 17:30:20"
"Login", "14-03-2023 08:00:00"
];
```
Ergebnisse
Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie die folgenden Felder als Dimensionen hinzu:
* ` Event
`
* `EventDateTime`
* `EventTimestamp`
Erstellen Sie die folgende Kennzahl:
* `=Timestamp(EventTimestamp)`, um den Zeitstempel in dem Format anzuzeigen, das im Ladeskript als Standardeinstellung angegeben ist.
Ergebnistabelle
| Ereignis | EventDateTime | EventTimestamp | Timestamp(EventTimestamp) |
| --- | --- | --- | --- |
| Anmeldename | 12-03-2023 10:25:30 | 12-03-2023 10:25:30 | 3/12/2023 10:25:30 AM |
| Anmeldename | 13-03-2023 09:10:15 | 13-03-2023 09:10:15 | 3/13/2023 9:10:15 AM |
| Anmeldename | 14-03-2023 08:00:00 | 14-03-2023 08:00:00 | 3/14/2023 8:00:00 AM |
| Abmelden | 12-03-2023 12:45:10 | 12-03-2023 12:45:10 | 3/12/2023 12:45:10 PM |
| Abmelden | 13-03-2023 17:30:20 | 13-03-2023 17:30:20 | 3/13/2023 5:30:20 PM |
In diesem Beispiel sehen Sie, wie Werte mit der Funktion `Timestamp#` konvertiert werden können.