# inquartertodate Skript- und Diagrammfunktion

Diese Funktion liefert True, wenn timestamp in dem Teil des Quartals liegt, der base\_date enthält, und zwar bis einschließlich der letzten Millisekunde von base\_date.

Syntax:

InQuarterToDate (timestamp, base\_date, period\_no [, first\_month\_of\_year])

Rückgabe Datentyp: Boolesch

Informationshinweis

In Qlik Sense wird der boolesche Wert „wahr“ durch -1 dargestellt, der Wert „falsch“ durch 0.

Diagramm der Funktion „inquartertodate“

Diagramm der Funktion „inquartertodate“

Diagramm der Funktion „inquartertodate“ ![Beispieldiagramm für den Datumsbereich, innerhalb dessen die Funktion „inquartertodate“ einen Wert von TRUE zurückgibt.](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Resources/Images/scripting-functions-inquartertodate-general.png)

Die Funktion `inquartertodate()` unterteilt das Jahr in vier gleiche Quartale zwischen dem 1. Januar und dem 31. Dezember (bzw. dem benutzerdefinierten Jahresbeginn und dem entsprechenden Enddatum). Unter Verwendung des `base_date` unterteilt die Funktion dann ein bestimmtes Quartal, wobei das `base_date` sowohl das Quartal als auch das maximal zulässige Datum für dieses Quartalssegment definiert. Abschließend gibt die Funktion ein boolesches Ergebnis zurück, wenn die vordefinierten Datumswerte mit diesem Segment verglichen werden.

Argumente

| Argument | Beschreibung |
| --- | --- |
| timestamp | Das Datum, das mit base\_date verglichen werden soll. |
| base\_date | Datum, das für die Interpretation des Quartals verwendet wird. |
| period\_no | Mit period\_no kann der Beginn für das Quartal festgelegt werden. period\_no ist eine ganze Zahl, wobei 0 für das Quartal steht, das base\_date enthält. Negative Werte von period\_no stehen für vorangehende, positive Werte für nachfolgende Quartale. |
| first\_month\_of\_year | Wenn Sie mit abweichenden Geschäftsjahren arbeiten möchten, definieren Sie mit einer Zahl zwischen 2 und 12 für first\_month\_of\_year einen anderen Startmonat. |

## Verwendung

Die Funktion `inquartertodate()` gibt einen booleschen Wert zurück. In der Regel wird dieser Funktionstyp als Bedingung in einem `if`-Ausdruck verwendet. Die Funktion `inquartertodate()` gibt eine Aggregierung oder Berechnung zurück, abhängig davon, ob ein ausgewertetes Datum in das Quartal bis einschließlich zum betreffenden Datum fällt.

Beispielsweise kann die Funktion `inquartertodate()` verwendet werden, um alle in einem Quartal bis zu einem bestimmten Datum gefertigten Geräte zu identifizieren.

Funktionsbeispiele

| Beispiel | Ergebnis |
| --- | --- |
| `inquartertodate('01/25/2013', '03/25/2013', 0)` | Gibt `TRUE` zurück, da der Wert von `timestamp`, 01/25/2013, innerhalb des Dreimonatszeitraums vom 01/01/2013 bis zum 03/25/2013 liegt, in den der Wert von `base_date`, 03/25/2013, fällt. |
| `inquartertodate('04/26/2013', '03/25/2013', 0)` | Gibt `FALSE` zurück, da 04/26/2013 außerhalb des Zeitraums aus dem vorigen Beispiel liegt. |
| `inquartertodate('02/25/2013', '06/09/2013', -1)` | Gibt `TRUE` zurück, da der Wert von `period_no`, -1, den Suchzeitraum um einen Dreimonatszeitraum zurück verschiebt (ein Quartal des Jahres). Dadurch ist der Suchzeitraum 01/01/2013 bis 03/09/2013. |
| `inquartertodate('03/25/2006', '04/15/2006', 0, 2)` | Gibt `TRUE` zurück, da der Wert von `first_month_of_year` auf 2 festgelegt ist, wodurch der Suchzeitraum 02/01/2006 bis 04/15/2006 anstelle von 04/01/2006 bis 04/15/2006 ist. |

## Regionaleinstellungen

Sofern nicht anders angegeben, verwenden die Beispiele in diesem Thema das folgende Datumsformat: MM/TT/JJJJ. Das Datumsformat wird in der Anweisung `SET DateFormat` in Ihrem Datenladeskript angegeben. Das Standarddatumsformat in Ihrem System kann aufgrund Ihrer regionalen Einstellungen und anderer Faktoren abweichen. Sie können die Formate in den Beispielen unten Ihren Anforderungen entsprechend ändern. Sie können auch die Formate in Ihrem Ladeskript entsprechend den Beispielen ändern.

Standardmäßige regionale Einstellungen in Anwendungen basieren auf den regionalen Systemeinstellungen des Computers oder Servers, auf dem Qlik Sense installiert ist. Wenn der Qlik Sense-Server, auf den Sie zugreifen, auf Schweden festgelegt ist, verwendet der Dateneditor die schwedischen regionalen Einstellungen für Datums-, Zeit- und Währungsangaben. Diese regionalen Formateinstellungen hängen nicht mit der Sprache zusammen, die in der Qlik Sense Benutzeroberfläche angezeigt wird. Qlik Sense wird in derselben Sprache angezeigt wie der von Ihnen verwendete Browser.

## Beispiel 1 – keine zusätzlichen Argumente

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/DateAndTimeFunctions/inquartertodate.htm)

#### Ladeskript und Ergebnisse

Übersicht

Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.

Das Ladeskript umfasst:

* Ein Datensatz enthält eine Reihe von Transaktionen für 2022 und wird in eine Tabelle namens `Transactions` geladen.

* Das Datumsfeld wird im Format der Systemvariablen `DateFormat` (MM/TT/JJJJ) bereitgestellt.

* Die Erstellung eines Felds `  in_quarter_to_date `, das bestimmt, welche Transaktionen im Quartal bis zum 15. Mai 2022 stattgefunden haben.

Ladeskript

```
SET DateFormat='MM/DD/YYYY';
						
Transactions:
    Load
        *,
        inquartertodate(date,'05/15/2022', 0) as in_quarter_to_date
        ;
Load
*
Inline
[
id,date,amount
8188,'1/19/2022',37.23
8189,'1/7/2022',17.17
8190,'2/28/2022',88.27
8191,'2/5/2022',57.42
8192,'3/16/2022',53.80
8193,'4/1/2022',82.06
8194,'5/7/2022',40.39
8195,'5/16/2022',87.21
8196,'6/15/2022',95.93
8197,'6/26/2022',45.89
8198,'7/9/2022',36.23
8199,'7/22/2022',25.66
8200,'7/23/2022',82.77
8201,'7/27/2022',69.98
8202,'8/2/2022',76.11
8203,'8/8/2022',25.12
8204,'8/19/2022',46.23
8205,'9/26/2022',84.21
8206,'10/14/2022',96.24
8207,'10/29/2022',67.67
];
```

Ergebnisse

Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie die folgenden Felder als Dimensionen hinzu:

* `date`

* `in_quarter_to_date`

Ergebnistabelle

| Datum | in\_quarter\_to\_date |
| --- | --- |
| 1/7/2022 | 0 |
| 1/19/2022 | 0 |
| 2/5/2022 | 0 |
| 2/28/2022 | 0 |
| 3/16/2022 | 0 |
| 4/1/2022 | -1 |
| 5/7/2022 | -1 |
| 5/16/2022 | 0 |
| 6/15/2022 | 0 |
| 6/26/2022 | 0 |
| 7/9/2022 | 0 |
| 7/22/2022 | 0 |
| 7/23/2022 | 0 |
| 7/27/2022 | 0 |
| 8/2/2022 | 0 |
| 8/8/2022 | 0 |
| 8/19/2022 | 0 |
| 9/26/2022 | 0 |
| 10/14/2022 | 0 |
| 10/29/2022 | 0 |

Das Feld „`in_quarter_to_date`“ wird im vorangehenden load-Befehl mithilfe der Funktion `inquartertodate()` erstellt. Das erste angegebene Argument identifiziert, welches Feld ausgewertet wird. Das zweite Argument ist ein hardcodiertes Datum für den 15. Mai. Dies ist das `base_date`, das identifiziert, welches Quartal segmentiert wird, und die Endbegrenzung dieses Segments definiert. Eine `period_no` von 0 ist das abschließende Argument, was bedeutet, dass die Funktion keine Quartale vor oder nach dem segmentierten Quartal vergleicht.

Diagramm der Funktion „inquartertodate“, keine zusätzlichen Argumente

Diagramm der Funktion „inquartertodate“, keine zusätzlichen Argumente

Diagramm der Funktion „inquartertodate“, keine zusätzlichen Argumente ![Diagramm mit dem Datumsbereich, für den die Funktion „inquartertodate“ einen Wert von TRUE zurückgibt.](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Resources/Images/scripting-functions-inquartertodate-example-no-additional-arguments.png)

Jede Transaktion, die zwischen dem 1. April und dem 15. Mai stattfindet, gibt ein boolesches Ergebnis von `TRUE` zurück. Transaktionen mit einem Datum am oder nach dem 16. Mai geben `FALSE` zurück, ebenso wie alle Transaktionen vor dem 1. April.

## Beispiel 2 – period\_no

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/DateAndTimeFunctions/inquartertodate.htm)

#### Ladeskript und Ergebnisse

Übersicht

Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.

Das Ladeskript umfasst:

* Derselbe Datensatz und dasselbe Szenario wie im ersten Beispiel.

* Die Erstellung eines Felds `previous_qtr_to_date`, das bestimmt, welche Transaktionen ein ganzes Quartal vor dem Quartalssegment stattfanden, das am 15. Mai 2022 endet.

Ladeskript

```
SET DateFormat='MM/DD/YYYY';

Transactions:
    Load
        *,
        inquartertodate(date,'05/15/2022', -1) as previous_qtr_to_date
        ;
Load
*
Inline
[
id,date,amount
8188,'1/19/2022',37.23
8189,'1/7/2022',17.17
8190,'2/28/2022',88.27
8191,'2/5/2022',57.42
8192,'3/16/2022',53.80
8193,'4/1/2022',82.06
8194,'5/7/2022',40.39
8195,'5/16/2022',87.21
8196,'6/15/2022',95.93
8197,'6/26/2022',45.89
8198,'7/9/2022',36.23
8199,'7/22/2022',25.66
8200,'7/23/2022',82.77
8201,'7/27/2022',69.98
8202,'8/2/2022',76.11
8203,'8/8/2022',25.12
8204,'8/19/2022',46.23
8205,'9/26/2022',84.21
8206,'10/14/2022',96.24
8207,'10/29/2022',67.67
];
```

Ergebnisse

Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie die folgenden Felder als Dimensionen hinzu:

* `date`

* `previous_qtr_to_date`

Ergebnistabelle

| Datum | previous\_qtr\_to\_date |
| --- | --- |
| 1/7/2022 | -1 |
| 1/19/2022 | -1 |
| 2/5/2022 | -1 |
| 2/28/2022 | 0 |
| 3/16/2022 | 0 |
| 4/1/2022 | 0 |
| 5/7/2022 | 0 |
| 5/16/2022 | 0 |
| 6/15/2022 | 0 |
| 6/26/2022 | 0 |
| 7/9/2022 | 0 |
| 7/22/2022 | 0 |
| 7/23/2022 | 0 |
| 7/27/2022 | 0 |
| 8/2/2022 | 0 |
| 8/8/2022 | 0 |
| 8/19/2022 | 0 |
| 9/26/2022 | 0 |
| 10/14/2022 | 0 |
| 10/29/2022 | 0 |

Ein `period_no`-Wert von -1 gibt an, dass die Funktion `inquartertodate ()` das Eingabequartalssegment mit dem vorherigen Quartal vergleicht. Der 15. Mai fällt in das zweite Quartal des Jahres, sodass das Segment anfänglich dem Zeitraum vom 1. April bis zum 15. Mai entspricht. Die `period_no` verschiebt dann dieses Segment um drei Monate zurück, sodass die Datumsgrenzen der 1. Januar bis zum 15. Februar werden.

Diagramm der Funktion „inquartertodate“, Beispiel „period\_no“

Diagramm der Funktion „inquartertodate“, Beispiel „period\_no“

Diagramm der Funktion „inquartertodate“, Beispiel „period\_no“ ![Diagramm mit dem Datumsbereich, für den die Funktion „inquartertodate“ einen Wert von TRUE zurückgibt.](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Resources/Images/scripting-functions-inquartertodate-example-period-no.png)

Daher gibt jede Transaktion, die zwischen dem 1. Januar und 15. Februar stattfindet, ein boolesches Ergebnis von `TRUE` zurück.

## Beispiel 3 – first\_month\_of\_year

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/DateAndTimeFunctions/inquartertodate.htm)

#### Ladeskript und Ergebnisse

Übersicht

Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.

Das Ladeskript umfasst:

* Derselbe Datensatz und dasselbe Szenario wie im ersten Beispiel.

* Die Erstellung eines Felds `in_quarter_to_date`, das bestimmt, welche Transaktionen im gleichen Quartal bis zum 15. Mai 2022 stattgefunden haben.

In diesem Beispiel wird März als erster Monat des Geschäftsjahrs festgelegt.

Ladeskript

```
SET DateFormat='MM/DD/YYYY';

Transactions:
    Load
        *,
        inquartertodate(date,'05/15/2022', 0,3) as in_quarter_to_date
        ;
Load
*
Inline
[
id,date,amount
8188,'1/19/2022',37.23
8189,'1/7/2022',17.17
8190,'2/28/2022',88.27
8191,'2/5/2022',57.42
8192,'3/16/2022',53.80
8193,'4/1/2022',82.06
8194,'5/7/2022',40.39
8195,'5/16/2022',87.21
8196,'6/15/2022',95.93
8197,'6/26/2022',45.89
8198,'7/9/2022',36.23
8199,'7/22/2022',25.66
8200,'7/23/2022',82.77
8201,'7/27/2022',69.98
8202,'8/2/2022',76.11
8203,'8/8/2022',25.12
8204,'8/19/2022',46.23
8205,'9/26/2022',84.21
8206,'10/14/2022',96.24
8207,'10/29/2022',67.67
];
```

Ergebnisse

Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie die folgenden Felder als Dimensionen hinzu:

* `date`

* `in_quarter_to_date`

Ergebnistabelle

| Datum | in\_quarter\_to\_date |
| --- | --- |
| 1/7/2022 | 0 |
| 1/19/2022 | 0 |
| 2/5/2022 | 0 |
| 2/28/2022 | 0 |
| 3/16/2022 | -1 |
| 4/1/2022 | -1 |
| 5/7/2022 | -1 |
| 5/16/2022 | 0 |
| 6/15/2022 | 0 |
| 6/26/2022 | 0 |
| 7/9/2022 | 0 |
| 7/22/2022 | 0 |
| 7/23/2022 | 0 |
| 7/27/2022 | 0 |
| 8/2/2022 | 0 |
| 8/8/2022 | 0 |
| 8/19/2022 | 0 |
| 9/26/2022 | 0 |
| 10/14/2022 | 0 |
| 10/29/2022 | 0 |

Indem 3 als Argument `first_month_of_year` in der Funktion `inquartertodate()` verwendet wird, beginnt die Funktion das Jahr am 1. März und unterteilt dann das Jahr in Quartale. Daher lauten die Quartalssegmente wie folgt:

* März bis Mai

* Juni bis August

* September bis November

* Dezember bis Februar

Das `base_date` vom 15. Mai segmentiert dann das Quartal März bis Mai, indem seine Endgrenze als 15. Mai festgelegt wird.

Diagramm der Funktion „inquartertodate“, Beispiel „first\_month\_of\_year“

Diagramm der Funktion „inquartertodate“, Beispiel „first\_month\_of\_year“

Diagramm der Funktion „inquartertodate“, Beispiel „first\_month\_of\_year“ ![Diagramm mit dem Datumsbereich, für den die Funktion „inquartertodate“ einen Wert von TRUE zurückgibt.](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Resources/Images/scripting-functions-inquartertodate-example-first-mth-yr.png)

Daher gibt jede Transaktion, die zwischen dem 1. März und dem 15. Mai stattfindet, ein boolesches Ergebnis von `TRUE` zurück, während Transaktionen mit Datum außerhalb dieser Grenzen einen Wert von `FALSE` zurückgeben.

## Beispiel 4 – Diagrammobjektbeispiel

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/DateAndTimeFunctions/inquartertodate.htm)

#### Ladeskript und Diagrammformel

Übersicht

Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in eine neue Registerkarte ein.

Das Ladeskript verwendet den gleichen Datensatz und das gleiche Szenario wie das erste Beispiel. In diesem Beispiel wird jedoch der unveränderte Datensatz in die Anwendung geladen. Die Berechnung, die bestimmt, ob Transaktionen im gleichen Quartal wie der 15. Mai stattfanden, wird als Kennzahl in einem Diagrammobjekt erstellt.

Ladeskript

```
SET DateFormat='MM/DD/YYYY';

Transactions:
Load
*
Inline
[
id,date,amount
8188,'1/19/2022',37.23
8189,'1/7/2022',17.17
8190,'2/28/2022',88.27
8191,'2/5/2022',57.42
8192,'3/16/2022',53.80
8193,'4/1/2022',82.06
8194,'5/7/2022',40.39
8195,'5/16/2022',87.21
8196,'6/15/2022',95.93
8197,'6/26/2022',45.89
8198,'7/9/2022',36.23
8199,'7/22/2022',25.66
8200,'7/23/2022',82.77
8201,'7/27/2022',69.98
8202,'8/2/2022',76.11
8203,'8/8/2022',25.12
8204,'8/19/2022',46.23
8205,'9/26/2022',84.21
8206,'10/14/2022',96.24
8207,'10/29/2022',67.67
];
```

Ergebnisse

Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie dieses Feld als Dimension hinzu:date.

Erstellen Sie die folgende Kennzahl:

=inquartertodate(date,'05/15/2022', 0)

Ergebnistabelle

| Datum | =inquartertodate(date,'05/15/2022', 0) |
| --- | --- |
| 1/7/2022 | 0 |
| 1/19/2022 | 0 |
| 2/5/2022 | 0 |
| 2/28/2022 | 0 |
| 3/16/2022 | 0 |
| 4/1/2022 | -1 |
| 5/7/2022 | -1 |
| 5/16/2022 | 0 |
| 6/15/2022 | 0 |
| 6/26/2022 | 0 |
| 7/9/2022 | 0 |
| 7/22/2022 | 0 |
| 7/23/2022 | 0 |
| 7/27/2022 | 0 |
| 8/2/2022 | 0 |
| 8/8/2022 | 0 |
| 8/19/2022 | 0 |
| 9/26/2022 | 0 |
| 10/14/2022 | 0 |
| 10/29/2022 | 0 |

Die Kennzahl in\_quarter\_to\_date wird in einem Diagrammobjekt anhand der Funktion inquartertodate() erstellt. Das erste Argument ist das Datumsfeld, das ausgewertet wird. Das zweite Argument ist ein hardcodiertes Datum für den 15. Mai. Dies ist das base\_date, das identifiziert, welches Quartal segmentiert wird, und definiert die Endbegrenzung dieses Segments. Eine period\_no von 0 ist das abschließende Argument, was bedeutet, dass die Funktion keine Quartale vor oder nach dem segmentierten Quartal vergleicht.

Diagramm der Funktion „inquartertodate“, Diagrammobjektbeispiel

Diagramm der Funktion „inquartertodate“, Diagrammobjektbeispiel

Diagramm der Funktion „inquartertodate“, Diagrammobjektbeispiel ![Diagramm mit dem Datumsbereich, für den die Funktion „inquartertodate“ einen Wert von TRUE zurückgibt.](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Resources/Images/scripting-functions-inquartertodate-example-chart-object.png)

Jede Transaktion, die zwischen dem 1. April und dem 15. Mai stattfindet, gibt ein boolesches Ergebnis von TRUE zurück. Transaktionen mit einem Datum am oder nach dem 16. Mai geben FALSE zurück, ebenso wie alle Transaktionen vor dem 1. April.

## Beispiel 5 – Szenario

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/Scripting/DateAndTimeFunctions/inquartertodate.htm)

#### Ladeskript und Diagrammformel

Übersicht

Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.

Das Ladeskript umfasst:

* Datensatz, der in eine Tabelle namens Products geladen wird

* Informationen bezüglich Produkt-ID, Herstellungsdatum und Selbstkosten.

Am 15. Mai 2022 wurde ein Maschinenfehler im Herstellungsprozess identifiziert und behoben. Produkte, die in diesem Quartal bis zu diesem Datum hergestellt wurden, sind mangelhaft. Der Endbenutzer möchte ein Diagrammobjekt haben, das nach Quartalsnamen den Status der Produkte als „mangelhaft“ und als „einwandfrei“ und die Kosten der in diesem Quartal bisher gefertigten Produkte angibt.

Ladeskript

```
Products:
Load
*
Inline 
[
product_id,manufacture_date,cost_price
8188,'1/19/2022',37.23
8189,'1/7/2022',17.17
8190,'2/28/2022',88.27
8191,'2/5/2022',57.42
8192,'3/16/2022',53.80
8193,'4/1/2022',82.06
8194,'5/7/2022',40.39
8195,'5/16/2022',87.21
8196,'6/15/2022',95.93
8197,'6/26/2022',45.89
8198,'7/9/2022',36.23
8199,'7/22/2022',25.66
8200,'7/23/2022',82.77
8201,'7/27/2022',69.98
8202,'8/2/2022',76.11
8203,'8/8/2022',25.12
8204,'8/19/2022',46.23
8205,'9/26/2022',84.21
8206,'10/14/2022',96.24
8207,'10/29/2022',67.67
];
```

Ergebnisse

Gehen Sie folgendermaßen vor:

1. Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle. Erstellen Sie eine Dimension, um die Quartalsnamen anzuzeigen:

   =quartername(manufacture\_date)

2. Erstellen Sie dann eine Dimension, um zu identifizieren, welche Produkte mangelhaft und welche einwandfrei sind:

   =if(inquartertodate(manufacture\_date,makedate(2022,05,15),0),'Defective','Faultless')

3. Erstellen Sie eine Kennzahl zum Summieren des cost\_price der Produkte:

   =sum(cost\_price)

4. Legen Sie das Zahlenformat der Kennzahl auf Währung fest.

Ergebnistabelle

| quartername(manufacture\_date) | if(inquartertodate(manufacture\_date,makedate(2022,05,15),0),'Defective','Faultless') | Sum(cost\_price) |
| --- | --- | --- |
| Jan–Mär 2022 | Einwandfrei | $253.89 |
| Apr–Jun 2022 | Einwandfrei | $229.03 |
| Apr–Jun 2022 | Defekt | $122.45 |
| Jul–Sep 2022 | Einwandfrei | $446.31 |
| Okt–Dez 2022 | Einwandfrei | $163.91 |

Die Funktion inquartertodate() gibt einen booleschen Wert zurück, wenn sie das Herstellungsdatum der einzelnen Produkte auswertet. Für diejenigen, die einen booleschen Wert von TRUE zurückgeben, markiert sie die Produkte als ‘Defective’. Für jedes Produkt, das einen Wert von FALSE zurückgibt und somit nicht im Quartal bis einschließlich 15. Mai hergestellt wurde, werden die Produkte als ‘Faultless’ markiert.